Das Portal zum Thema Excel-Formeln

In einem Punkt(XY)-Diagramm mit zwei Datenreihen, soll der Schnittpunkt ermittelt und markiert werden.
Wenn es sich um Geraden oder Polynome handelt, könnte man den Schnittpunkt der Trend-Funktionen bestimmen.
Enthalten die Datenreihen andere Werte (z.B. Meßwerte), geht das aber nicht.




In A1:C1 steht x, y1, y2
In A2:A11 stehen die X-Werte
in B2:B11 bzw. C2:C11 die beiden Y-Datenreihen.

in A15 steht

{=VERGLEICH(WAHR;B1:B11>=C1:C11;0)} (Es wird unterstellt, daß Y1 steigend und Y2 fallend ist, andernfalls das Vorzeichen umkehren. Bei eventuell mehreren Schnittpunkten wird der erste ausgegeben.)

in B15:C15 steht

{=RGP(BEREICH.VERSCHIEBEN(B1;A15-2;;2);BEREICH.VERSCHIEBEN(A1;A15-2;;2);1)}

(Beide Zellen selektieren und Formel als Matrix eingeben.)

in B16:C16 steht

{=RGP(BEREICH.VERSCHIEBEN(C1;A15-2;;2);BEREICH.VERSCHIEBEN(A1;A15-2;;2);1)}

(Beide Zellen selektieren und Formel als Matrix eingeben.)

Der X-Wert (in E4) des Schnittpunktes ergibt sich aus

=(C16-C15)/(B15-B16)

der Y-Wert (in F4) ergibt sich dann aus

=E4*B16+C16 oder =E4*B15+C15

Schnittpunkt markieren:
E3: =E4
F3: =0
H4: =E4
I4: =F4
H3: =0
H4: =I4

E3:F4 markieren und ins Diagramm ziehen (Rubriken in erster Spalte: ankreuzen)
H3:I4 dito

Dem Diagramm somit werden die Datenreihen

=DATENREIHE(;Tabelle1!$E$3:$E$4;Tabelle1!$F$3:$F$4;3)

und

=DATENREIHE(;Tabelle1!$H$3:$H$4;Tabelle1!$I$3:$I$4;4)

zugefügt, diese markieren den Schnittpunkt.





Mit der Formel in A15 wird ermittelt, bei welchem X-Wert Y1 erstmals größer ist, als Y2.

Der Schnittpunkt muß dann im Bereich (x-1) < S < x liegen.

Von den zwei Datenpunkten x-1 und x kann dann eine lineare Trendfunktion bestimmt werden und zwar in B15:C15 für Y1
und in B16:C16 für Y2. Von diesen beiden Trendfunktionen kann dann leicht der Schnittpunkt ermittelt werden.