Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Statistik - BEITRAG: Schnittpunkte zweier Gaußkurven berechnen


Aufgabe
Die Schnittpunkte zweier sich überlagernder Gaußkurven sollen berechnet und in einem Diagramm markiert werden.


Lösung
In F2:G3 werden Mittelwert und Standardabweichung der Gaußkurven vorgegeben.

Die X-Achse wird in Spalte A geschrieben. Im Beispiel im Intervall -1 bis 4,7. In den Spalten B und C stehen die y-Werte beider Kurven
B2:=NORMVERT(A2;$F$2;$F$3;0)
C2:=NORMVERT(A2;$G$2;$G$3;0)
Jeweils nach unten kopiert.

Die x-Koordinaten der Schnittpunkte lauten dann
F6:=WENN(F3=G3;(F2+G2)/2;(-(2*(G3^2)*F2-2*(F3^2)*G2)+WURZEL((2*(G3^2)*F2-2*(F3^2)*G2)^2-4*((F3^2)-(G3^2))*(((F3^2)*G2^2-(G3^2)*F2^2)-((LN(1/(WURZEL((G3^2))*WURZEL(2*PI())))-LN(1/(WURZEL((F3^2))*WURZEL(2*PI()))))*(2*(F3^2)*(G3^2))))))/(2*((F3^2)-(G3^2))))

G6:=WENN(F3=G3;(F2+G2)/2;(-(2*(G3^2)*F2-2*(F3^2)*G2)-WURZEL((2*(G3^2)*F2-2*(F3^2)*G2)^2-4*((F3^2)-(G3^2))*(((F3^2)*G2^2-(G3^2)*F2^2)-((LN(1/(WURZEL((G3^2))*WURZEL(2*PI())))-LN(1/(WURZEL((F3^2))*WURZEL(2*PI()))))*(2*(F3^2)*(G3^2))))))/(2*((F3^2)-(G3^2))))

und die dazugehörigen y-Werte

F7:=NORMVERT(F6;$F$2;$F$3;0)
G7:=NORMVERT(G6;$F$2;$F$3;0)


Das Punkt(XY)-Diagramm enthält folgende Datenreihen
die Kurven:
=DATENREIHE(;Tabelle3!$A$2:$A$21;Tabelle3!$B$2:$B$21;1)
=DATENREIHE(;Tabelle3!$A$2:$A$21;Tabelle3!$C$2:$C$21;2)
die Schnittpunkte:
=DATENREIHE(;Tabelle3!$F$6:$G$6;Tabelle3!$F$7:$G$7;3)
Erläuterung
Sind die Standardabweichungen der beiden Gauß-Kurven unterschiedlich, so sind zwei Schnittpunkte vorhanden. Sind die Standardabweichungen jedoch identisch, so ist nur ein Schnittpunkt vorhanden - in diesem Fall liefern beide Formeln das selbe Ergebnis (dank des ersten Teils der WENN-Funktion).