Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Listen/Datensätze - BEITRAG: Spalte(n) mit Leerzellen ohne Lücken auflisten


Aufgabe
In Spalte A (und C) stehen Bezeichnungen mit Leerzellen dazwischen. Diese sollen nun lückenlos aufgelistet werden

       A               B               C               D               E       
1 Cognac        ohne Lücken  
2         Cognac  
3     Bar    Calvados  
4         Rotwein  
5 Calvados        Bier  
6         Kater  
7 Rotwein        Vollrausch  
8 Bier    Bistro    Bar  
9     Trattoria    Bistro  
10         Trattoria  
11         Kneipe  
12 Kater  Arabien       
13          
14     Kneipe     
15 Vollrausch         




Lösung
Schreibe in die Zelle, in der die Auflistung beginnen soll:

{=WENN(ZEILE(A1)>ANZAHL2(A:A);"";INDEX(A:A;KKLEINSTE(WENN(A$1:A$1000<>"";ZEILE($1:$1000));ZEILE(A1))))}
und runterkopieren

Können Fehlermeldungen vorkommen, die auch gelistet werden sollen, dann:
{=WENN(ZEILE(A1)>ANZAHL2(A:A);"";INDEX(A:A;KKLEINSTE(WENN(NICHT(ISTLEER(A$1:A$100));ZEILE($1:$100));ZEILEN($1:1))))}

2 lückenhafte Spalten - hier A und C - lückenlos in einer untereinander (die Spalten müssen also nicht nebeneinander liegen):
{=WENN(ZEILE(A1)>ANZAHL2(A:A;C:C);"";WENN(ZEILE(A1)>ANZAHL2(A:A);INDEX(C:C;KKLEINSTE(WENN(C$1:C$99<>"";ZEILE($1:$99));ZEILE(A1)-ANZAHL2(A:A)));INDEX(A:A;KKLEINSTE(WENN(A$1:A$99<>"";ZEILE($1:$99));ZEILE(A1)))))}

mit Fehlermeldungen:
{=WENN(ZEILE(A1)>ANZAHL2(A:A;C:C);"";WENN(ZEILE(A1)>ANZAHL2(A:A);INDEX(C:C;KKLEINSTE(WENN(NICHT(ISTLEER(C$1:C$99));ZEILE($1:$99));ZEILE(A1)-ANZAHL2(A:A)));INDEX(A:A;KKLEINSTE(WENN(NICHT(ISTLEER(A$1:A$99));ZEILE($1:$99));ZEILE(A1)))))}

Erläuterung
viele (allerdings nebeneinander liegende) Spalten: siehe Nr. 315 (Listen/Datensätze)