Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Zahlenformate - BEITRAG: Umrechnung cm => Zoll (inch) und cm => feet / inch


Aufgabe
Umrechnung von cm in das nordamerikanische Zollsystem in Bruchdarstellung

Beispiel:
4,36 => 1 11/16" (Genauigkeit 1/16")
4,36 => 1 23/32" (Genauigkeit 1/32")

Beispiel für die Umrechnung cm => feet/inch:
198 cm => 6' 6"

Lösung
Die metrische Angabe (cm) steht in A1.

Zollangabe mit 1/16 Genauigkeit:
=WENN(RUNDEN(REST(A1;2,54)/2,54*16;0)=0;TEXT(GANZZAHL(A1/2,54);"0");TEXT(A1/2,54;"# ?/"&INDEX({16;8;16;4;16;8;16;2;16;8;16;4;16;8;16};REST(RUNDEN(A1/2,54*16;0);16))))&ZEICHEN(34)

Zollangabe mit 1/32 Genauigkeit:
=WENN(RUNDEN(REST(A1;2,54)/2,54*32;0)=0;TEXT(GANZZAHL(A1/2,54);"0");TEXT(A1/2,54;"# ?/"&INDEX({32;16;32;8;32;16;32;4;32;16;32;8;32;16;32;2;32;16;32;8;32;16;32;4;32;16;32;8;32;16;32};REST(RUNDEN(A1/2,54*32;0);32))))&ZEICHEN(34)

Und das ganze dynamisch (mit frei wählbarer Genauigkeit); - also auch 1/8; 1/128 etc.
Der Teiler; also 128 bei 1/128 wird in B1 eingegeben.
in F1 (Hilfsspalte) steht:
=RUNDEN(REST(A1;2,54)/2,54*B1;0)
in F2:
=WENN(F1="";"";WENN(REST(F1;2)=0;F1/2;""))

bis F14 runterkopieren
das Ergebnis:
=WENN(A1<2,54;"";GANZZAHL(A1/2,54))&WENN(F1=0;ZEICHEN(34);" "&MIN(F1:F14)&"/"&B1/2^(ANZAHL(F1:F14)-1)&ZEICHEN(34))

Umrechnung cm => feet/inch
=GANZZAHL(RUNDEN((A1/2,54);0)/12)&"' "&REST(RUNDEN((A1/2,54);0);12)&""""

Erläuterung
Ergänzung von Holger Voß
wenn man die cm Angabe in A1 mit =A1/2,54 umrechnet, genügt das Zahlenformat
# ?/16\" oder # ?/32\" um die Zollangabe darzustellen.
Oder =TEXT(A1;"# ?/16\""")

Allerdings wird dann logischerweise z.B. 3,81 (2,54*1,5) nicht als 1 1/2" sondern als 1 8/16" dargestellt.