Das Portal zum Thema Excel-Formeln

Du willst alle Zellen zählen, die eine bestimmte Zeichenfolge enthalten.
Bereich: Spalte A

Suchtext steht rechts:

=ZÄHLENWENN(A:A;"*Text")

Bei Beachtung von Groß- und KLeinschreibung:

=SUMMENPRODUKT(IDENTISCH(RECHTS(A1:A100;Länge("Text"));"Text")*1)

Suchtext steht links

=ZÄHLENWENN(A:A;"Text*")

Bei Beachtung von Groß- und KLeinschreibung:

=SUMMENPRODUKT(IDENTISCH(LINKS(A1:A100;Länge("Text"));"Text")*1)

Suchtext steht irgendwo

=ZÄHLENWENN(A:A;"*Text*")

Bei Beachtung von Groß- und KLeinschreibung:

=SUMMENPRODUKT(ISTZAHL(FINDEN("Text";A1:A100))*1)

oder:

{=ANZAHL(FINDEN("Text";A1:A100))}

bzw. abgegenzt: Suchtext ist Anne aber Annette und Annemarie sollen nicht gezählt werden

{=ANZAHL(FINDEN(" "&"Text"&" ";" "&A1:A100&" "))}

Zellen zählen, die einen Stern* oder ein Fragezeichen? enthalten:

=ZÄHLENWENN(A:A;"*~**")

bzw.

=ZÄHLENWENN(A:A;"*~?*")

Sollen gleichzeitig mehrere Suchtexte gezählt werden, dann:

=SUMME(ZÄHLENWENN(A:A;{"*text1*";"*text2*";"*text3*"}))

Das ist keine Array-Formel die {geschweiften Klammern} also eingeben.
bzw.
wenn die Texte in Zellen (hier D1:D4) stehen:

=SUMMENPRODUKT(ZÄHLENWENN(A:A;"*"&D1:D4&"*"))