Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Textfunktionen

Beitrag: Buchstaben von rechts suchen und finden ohne Array-Formel

Aufgabe
Das FINDEN eines Zeichens von rechts kann auch ohne Array-Formel realisiert werden (ist identisch dem letzten Zeichen von links):
Autor: Ernst Albrecht Borgener

Lösung
Text steht in A1
gesuchtes Zeichen: "r"

=FINDEN("#";WECHSELN(A1;"r";"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"r";""))))
(gibt die Position von links an)

Ist der Suchbegriff länger als ein Zeichen, wird's etwas umfangreicher:
Der Suchbegriff steht in B1
=FINDEN("#";WECHSELN(A1;B1;"#";LÄNGE(A1)-(LÄNGE(B1)-1)*(LÄNGE(A1)-LÄNGE(WECHSELN(A1;B1;"")))/LÄNGE(B1)-LÄNGE(WECHSELN(A1;B1;""))))

verkürzt von Markus Wilmes
=FINDEN("~X~";WECHSELN(A1;B1;"~X~";LÄNGE(A1)-LÄNGE(WECHSELN(A1;B1;WIEDERHOLEN(" ";LÄNGE(B1)-1)))))

verkürzt am 20.08.06
=FINDEN("#";WECHSELN(A1;B1;"#";(LÄNGE(A1)-LÄNGE(WECHSELN(A1;B1;"")))/LÄNGE(B1)))

und am 07.09.2006 unschlagbar verkürzt von Josef Burch
=VERWEIS(9^9;FINDEN(B1;A1;SPALTE(1:1)))


von rechts:
=LÄNGE(A1)+1 minus obige Formel(n)






       A               B               C       
1 Katrin Grashoff  7  (von rechts)  
2   9