Das Portal zum Thema Excel-Formeln

In einer Spalte soll das Minimum / der Mittelwert ohne Berücksichtigung vorkommender Nullen bestimmt werden. Das erledigen die Array-Formeln:

{=MIN(WENN(A1:A1000;A1:A1000))}

sowie

{=MITTELWERT(WENN(A1:A1000;A1:A1000))}

Wie funktioniert das ohne Array-Formeln ?

Minimum:

=KKLEINSTE(A1:A1000;ZÄHLENWENN(A1:A1000;0)+1)

bzw.; - da kein Array, werden auch komplette Spalten akzeptiert:

=KKLEINSTE(A:A;ZÄHLENWENN(A:A;0)+1)

Mittelwert:

=SUMME(A:A)/ZÄHLENWENN(A:A;">0")

Obige Formeln gelten nur für positive Zahlen.

Mit negativen Zahlen:

=WENN(MIN(A:A)<0;MIN(A:A);KKLEINSTE(A:A;ZÄHLENWENN(A:A;0)+1))

sowie:

=SUMME(A:A)/(ZÄHLENWENN(A:A;">0")+ZÄHLENWENN(A:A;"<0"))

bzw.

=SUMME(A:A)/SUMME(ZÄHLENWENN(A:A;{">0"."<0"}))

Bei nicht zusammenhängen Zellen (nur Einzelzellen, keine Bereiche!) funktioniert das wie folgt:

=MIN(WENN(N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}));N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}))))

sowie

=MITTELWERT(WENN(N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}));N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}))))

Auch das sind seltsamerweise keine Arrayformeln !?

Wenn auch Bereiche vorkommen können, dann ab xl-Version 2019 (von Sabina - "Flotter Feger"):

=MIN(WENN(MINWENNS(INDIREKT({"B2:C2";"E2:F2";"D4:E4"});INDIREKT({"B2:C2";"E2:F2";"D4:E4"});"<>0")=0;"";MINWENNS(INDIREKT({"B2:C2";"E2:F2";"D4:E4"});INDIREKT({"B2:C2";"E2:F2";"D4:E4"});"<>0")))<br/>

bzw. seit xl365 mit LET kürzer (ebenfalls Sabina):

=LET(a;INDIREKT({"B2:C2";"E2:F2";"D4:E4"});w;MINWENNS(a;a;"<>0");MIN(WENN(w=0;"";w)))

ein Phänomen (bug)?
warum =SUMME(A:A)/(ZÄHLENWENN(A:A;">0")+ZÄHLENWENN(A:A;"<0"))
=SUMME(A:A)/ZÄHLENWENN(A:A;"<>0") sollte doch langen!

=ZÄHLENWENN(A:A;"<>0") zählt korrekt alle Zellen ungleich Null.

Werden Zahlen gelöscht (Taste Entf) verändert sich das Zählresultat nicht ???

Andy:
habe die Formeln getestet-OK
Allerdings:

=ZÄHLENWENN(A:A;"<>0") ist wohl ein Bug.

Die Ergebnisse sind beliebig und nicht nachvollziehbar.
Schon wenn man die Formel runterzieht, gibt sie verschiedene Ergebnisse aus.
Diese Formel darf NICHT verwendet werden!!