Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Excel4-Makrofunktionen

Beitrag: Tabellenindex ermitteln, arbeitsmappe durchnummerieren*

Aufgabe
- Position des aktuellen Tabellenblattes innerhalb der Arbeitsmappe ermitteln
- Arbeitsmappe durchnummerieren
- Aus der dritten Tabelle einen Wert auslesen
Lösung
Die Datei muß gespeichert sein!

1. Du willst die Position des aktuellen Tabellenblattes innerhalb der Arbeitsmappe ermitteln:

Wähle Einfügen>Namen>Festlegen und vergebe folgende Namen:

Name: Tabellen (Array aller Tabellen der Mappe)
bezieht sich auf:
=ARBEITSMAPPE.ZUORDNEN(1)

Name:Tab (Name der aktuellen Tabelle)
bezieht sich auf:
=TEIL(ZELLE("Dateiname";INDIREKT("A1"));FINDEN("[";ZELLE("Dateiname";INDIREKT("A1")));999)

Name:Nr (Position der aktuellen Tabelle)
bezieht sich auf:
=VERGLEICH(Tab;Tabellen;0)

Schreibe nun z.B. in A1
=Nr

Tip von Jürgen Recker:
Den Index der aktiven tabelle erhält man auch mit
=DATEI.ZUORDNEN(87) 

2. Tabellen durchnummerieren:
Selektiere die erste Tabelle
Drücke SHIFT und selektiere dabei die letzte Tabelle. Nun sind alle Tabellen selektiert.
Gibst Du jetzt in A1 =Nr ein, gilt das für alle Tabellen!

ACHTUNG: =Nr kann nicht über die Zwischenablage in eine andere Tabelle kopiert werden, dieser Bug tritt bei der Verwendung von Excel4-Makrofunktionen auf.
Dieser Versuch führt gelegentlich zum ABSTURZ von Excel!
Wenn Du die ganze Tabelle kopierst, geht es aber.

3.Auf dritte Tabelle zugreifen:

Du willst auf B2 der Tabelle zugreifen, die von links an dritter Position steht:
=INDIREKT("'"&(TEIL(INDEX(tabellen;3);FINDEN("]";INDEX(tabellen;3))+1;99)&"'!B2"))


Erläuterung
Falls die Formeln auch in anderssprachigen Versionen funktionieren müssen, ersetzt "Dateiname" durch "Filename". Das ist in allen Sprachen (auch deutsch) gültig.