Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Tabellennavigation

Beitrag: Fehlerwerte suchen und zählen

Aufgabe
In einer Spalte sollen Fehlerwerte gezählt und deren Position bestimmt werden.

       A       
1 1  
2 4  
3 #NAME?  
4 #NV  
5 2  
6 #DIV/0!  
7 x  
8 #BEZUG!  
9 #DIV/0! 

Lösung
In A1 bis A10 stehen die Werte

beliebigen Fehlerwerte zählen:
{=SUMME(ISTFEHLER(A1:A10)*1)} (ergibt 5)

Zeile des ersten Fehlerwertes ermitteln:
{=MIN(WENN(ISTFEHLER(A1:A10);ZEILE(1:10)))} (ergibt 3)

bestimmten Fehlerwert zählen, z.B. #DIV/0!
=ZÄHLENWENN(A1:A10;1/0) (ergibt 2)
oder
=ZÄHLENWENN(A1:A10;#DIV/0!)

Zeile des ersten Fehlerwertes #DIV/0! ermitteln:
{=MIN(WENN(ZÄHLENWENN(INDIREKT("A"&ZEILE(1:10));1/0);ZEILE(1:10)))}
oder mit der Funktion FEHLER.TYP:
{=MIN(WENN(ISTZAHL(FEHLER.TYP(A1:A10));WENN(FEHLER.TYP(A1:A10)=2;ZEILE(1:10))))}

Fehlerwert in mehrspaltiger Tabelle suchen:
zu durchsuchender Bereich: B1 bis Z100 (wegen Zirkelbezug müssen die Formeln außerhalb stehen).

in A1 (Hilfszelle) erhält man die Zeilenzahl:
{=MIN(WENN(ISTFEHLER(B1:Z100);ZEILE(B1:B100)))}

Die Zelladresse der Fehlermeldung lautet:
{="Fehler in "&ADRESSE(A1;MIN(WENN(ISTFEHLER(INDIREKT("B"&A1):INDIREKT("Z"&A1));SPALTE(B:Z))))}