Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Tabellennavigation

Beitrag: Informationen über die soundsovielte nichtleere Zelle einer Spalte

Aufgabe
Du willst wissen, was in der z.B. zehnten nicht leeren Zelle einer Spalte steht.

       A               B               C               D       
1     15  Die Zeile der 10. gefüllten Zelle  
2 20    $A$15  Zelladresse  
3     Zellinhalt  
4   53  Summe der ersten 10 gefüllten Zellen  
5      
6        
7        
8      
9      
10      
11      
12        
13      
14      
15 9       
16 10       
17 11       
18 12       


Lösung
Die Zeile der 10. gefüllten Zelle:
{=KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10)}

Zelladresse:
{=ADRESSE(KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10);1)}
oder
{="$A$"&KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10)}

Zellinhalt:
{=INDIREKT(ADRESSE(KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10);1))}
oder
{=INDIREKT("A"&KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10))}

Summe der ersten 10 gefüllten Zellen:
{=SUMME(A1:INDIREKT(ADRESSE(KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10);1)))}
oder
{=SUMME(A1:INDIREKT("A"&KKLEINSTE(WENN(A1:A100<>"";ZEILE(1:100));10)))}

Erläuterung
Gibt es weniger als 10 gefüllte Zellen, erscheint #ZAHL!
Soll stattdessen die letzte gefüllte Zelle herangezogen werden, dann in allen Formeln 10 ersetzen durch MIN(ANZAHL2(A1:A100);10)