Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Mathematische Funktionen

Beitrag: Entfernungsber. über Koordinaten + Google maps + Sonnenaufgang

Aufgabe
Von 2 Orten kennt man die Breiten- und Längengrade. Die Entfernung (Luftlinie) soll berechnet werden.
Siehe auch den Großkreis: Tip Nr. 41

Lösung
in A1 steht die Breite des Ortes 1 und in A2 die Länge
in A3 steht die Breite des Ortes 2 und in A4 die Länge
jeweils Grad - dezimal
Zur Umrechnung ins Bogenmaß steht in B1:
=A1*PI()/180
bis B4 kopieren
in B6 steht:
=ARCCOS(SIN(B1)*SIN(B3)+COS(B1)*COS(B3)*COS(B4-B2))*6367,4445

das Ergebnis in A6 (bis 1 km in m - dann km mit 1 Nachkommastelle - ab 100 km ohne):
=WENN(B6<1;RUNDEN(B6*1000;0)&" m";WENN(B6<100;TEXT(B6;"0,0")&" km";TEXT(B6;"#.##0")&" km"))

Wenn Du nicht weißt, wie auf dezimal umgerechnet wird:
in F1 stehen die Stunden / in G1 die Minuten / in H1 die Sekunden
=F1+G1/60+H1/3600

Feature für Google maps
=WECHSELN(A1;",";".")&","&WECHSELN(A2;",";".")
Mit diesem Formelergebnis in der Maps-Suche landest Du metergenau am Ort 1.
Der Freiburger Münsterplatz z.B. hat die Dezimalkoordinaten 47,99560 und 7,85222 . Das ergibt mit obiger Formel: 47.9956,7.85222
Diesen Wert kannst Du auch direkt aus der Google-Karte auslesen:
Mit der rechten Maustaste auf den Punkt Deiner Wahl (vorher bis zum geht-nicht-mehr vergrößern) klicken / Was ist hier?: et voilà

Dito für Ort 2 mit =WECHSELN(A3;",";".")&","&WECHSELN(A4;",";".") und bei Route berechnen eingegeben, erhältst Du die Gesamtkarte + Auto-km-Entfernung.

Berechnung von Sonnenaufgang und Sonnenuntergang für beide Orte (bzw. für individuell eingegebene Koordinaten)
mit Richtungsgrafik sowie den Sonnenphasen als download:

DOWNLOAD

natürlich dann auch Steigungswinkel + Geradengleichung

Erläuterung
Die Erde ist keine Kugel sondern ein Ellipsoid.
Der Äquatorradius beträgt 6.378.137 m und der Polradius 6.356.752 m.
Welchen von den beiden nimmt man - oder den (gewichteten) Mittelwert.
Ich hab den einfachen Mittelwert (6.367.444,5) genommen.
Die jeweilige Ellipse auszurechnen ist Extremmathematik - vergiss es.
Das Ergebnis ist also nie ganz genau: Distanzen Nord-Süd / West-Ost / Nordost-Südwest usw. haben je nach Lage der zwei Orte unterschiedliche Radien. Die maximale Abweichung (exakt Nord-Süd zu exakt West-Ost) beträgt +/- 0,17 Prozent.
WF