Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Tabellennavigation

Beitrag: Erste benutzte Zelle in einer Zeile oder Spalte

Aufgabe
Wie kann man die erste benutzte Zelle in einer Zeile oder Spalte ermitteln ?

       A               B               C               D               E               F               G       
1     3    7  
2 e             
3            
4              
5            
6              
7            
8              

Lösung
Spalte: A bzw. Zeile: 1

erste Zeile einer Spalte:
{=VERGLEICH(WAHR;A1:A999<>"";0)}
oder
{=MIN(WENN(A1:A999<>"";ZEILE(1:999)))}
oder
{=MIN(WENN(ISTLEER(A1:A999);"";ZEILE(1:999)))}
entsprechender Eintrag:
{=INDEX(A1:A999;VERGLEICH(WAHR;A1:A999<>"";0))}
Alternative ohne Abschluss als Arrayformel:
=VERGLEICH("?*";INDEX(A1:A999&"";0);0)
oder:
=VERGLEICH(WAHR;INDEX(A1:A999<>"";0);0)
Handelt es sich nur um Text, langt:
=VERGLEICH("*";A:A;0)

erste Spalte einer Zeile:
{=VERGLEICH(WAHR;A1:IQ1<>"";0)}
oder
{=MIN(WENN(A1:IQ1<>"";SPALTE(A1:IQ1)))}
oder
{=MIN(WENN(ISTLEER(A1:IQ1);"";SPALTE(A1:IQ1)))}
entsprechender Eintrag:
{=INDEX(A1:IQ1;VERGLEICH(WAHR;A1:IQ1<>"";0))}
Alternative ohne Abschluss als Arrayformel:
=VERGLEICH("?*";INDEX(A1:IQ1&"";0);0)
oder:
=VERGLEICH(WAHR;INDEX(A1:IQ1<>"";0);0)
bzw. bei nur Text:
=VERGLEICH("*";A1:IQ1;0)

Erläuterung
Die Varianten mit ISTLEER erkennen auch Zellen mit Fehlermeldungen und mit dem Formelergebnis "".

Fehlerignoranten
Funktionen, denen Fehlermeldungen im Bereich wurscht sind:
ANZAHL
ANZAHL2
ANZAHLLEEREZELLEN
ISTLEER
SUMMEWENN
SUMMEWENNS
VERGLEICH
VERWEIS
ZÄHLENWENN
ZÄHLENWENNS