Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Textfunktionen

Beitrag: Numerierung per Doppelbuchstaben *

Aufgabe
Eine Liste nicht mit Zahlen sondern mit Doppelbuchstaben durchnumerieren:
AA - AB - AC - ..... - AX - AY - AZ - BA - BB - BC - ..... - ZY - ZZ

Lösung
Beginn irgendwo:
=ZEICHEN(GANZZAHL(ZEILE(X26)/26)+64)&ZEICHEN(ZEILE(X65)-GANZZAHL(ZEILE(X1)/26,001)*26)
runterkopieren
Nach 676 Zeilen =26^2 entsprechend ZZ ist Sense.

In A1 stehen Doppelbuchstaben - diese entsprechen der Zahl:
=(SPALTE(INDIREKT(LINKS(A1)&1))-1)*26+SPALTE(INDIREKT(RECHTS(A1)&1))

und umgekehrt
In A2 steht eine Zahl - diese entspricht den Doppelbuchstaben:
=ZEICHEN(AUFRUNDEN(A2/26;0)+64)&ZEICHEN(AUFRUNDEN(REST(A2-0,1;26);0)+64)

Viel einfacher von lupo1 mit der Funktion Adresse:
=WECHSELN(ADRESSE(1;ZEILE(X27);4);1;)
runterkopieren

Buchstaben in Zahl:
=SPALTE(INDIREKT(A1&1))-26

Zahl in Buchstaben:
=WECHSELN(ADRESSE(1;A2+26;4);1;)

Geht nun bis zur Darstellungsgrenze von Excel: XFD =2^14-26 (dreibuchstabig)

Erläuterung
Sollen es Kleinbuchstaben sein, in obigen Formeln +64 durch +96 und X65 durch X97 ersetzen bzw. KLEIN(...) drumrum.