getmorespeed und application.calculation

Hallo zusammen,
nachdem ich mich in letzter Zeit etwas rar hier gemacht habe, nun mal wieder eine Frage.
Ich hatte mal irgendwann ein Makro "getmorespeed" hier im Forum gefunden (von Hajo, glaube ich?) und verwende dieses des Öfteren in meinem Code.
Hier für alle, die es nicht kennen:


Sub GetMoreSpeed(bYesNo As Boolean)
Application.ScreenUpdating = Not (bYesNo)
Application.EnableEvents = Not (bYesNo)
Application.Calculation = IIf(bYesNo, xlCalculationManual, xlCalculationAutomatic)
If Not bYesNo Then Calculate
End Sub

Ich war bisher der Meinung, dass der aktuelle Status von Application.Calculation mit der Option "Getmorespeed False" wieder auf den vorherigen Wert gesetzt wird.
Nun habe ich aber festgestellt, dass bei eingeschalteter manueller Berechnung und Ausführen meines Makros in der Form


Getmorespeed True
Mein Code
Getmorespeed False

hinterher die automatische Berechnung wieder eingeschaltet ist, was nicht gewollt ist.
Ich erkenne aber nicht, ob und wenn ja was ich ändern müsste, damit das funzt.
In meinem Code wird diese Option übrigens nicht angefasst (bevor jemand fragt)
Vielleicht kann mir ja jemand einen Tip geben.
Danke im Voraus.
Gruß
David

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

HAllo
Du solltest dafür sorgen das wenn dein Programm abstürzt, die alten Einstellungen wieder zurückgesetzt werden.
Schau dir mal diesen Code an:

Option Explicit
Dim AppCalc
Dim AppScreen
Dim AppEvents

Public Sub dein_Code()
On Error GoTo raus
Call More_speed
'Hier dein eigentlicher Code zum übertragen
'
'
'
'
raus:
Call Meine_Einstellungen
End Sub

Public Sub More_speed()
With Application
    '#######################
    'Einstellungen speichern
    AppCalc = .Calculation
    AppScreen = .ScreenUpdating
    AppEvents = .EnableEvents
    '#######################
    'Angezogene Bremsen lösen
    .Calculation = xlCalculationManual 'Berechnung auf manuell
    .ScreenUpdating = False 'Bildschirmaktualisierung aus
    .EnableEvents = False 'Ereignismakros abschalten
    '#######################
End With
End Sub

Public Sub Meine_Einstellungen()
With Application
    .Calculation = AppCalc
    .ScreenUpdating = AppScreen
    .EnableEvents = AppEvents
End With
End Sub

Der ist vom Prinzip her gleich wie:
Sub GetMoreSpeed(bYesNo As Boolean)
Es werden aber auf jedenfall die alten Einstellungen wieder gesetzt.
(und er ist leichter nachzuvollziehen ;-)
ransi

Beliebteste Forumthreads (12 Monate)

getmorespeed und application.calculation

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread