Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1032to1036
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Datumsformat

Datumsformat
22.12.2008 10:21:35
uwe
Hallo,
ich übertrage / Suche Daten mit folgendem Makro:
Dim rng As Range
Dim intRow As Integer
intRow = 1
Do Until IsEmpty(Cells(intRow, 1))
Set rng = Worksheets("Daten").Columns(1).Find(Cells(intRow, 1), _
lookat:=xlWhole, LookIn:=xlValues)
Range(rng.Offset(0, 1), rng.Offset(0, 3)).Value = Range(Cells(intRow, 2), Cells(intRow, 4)).Value
intRow = intRow + 1
Loop
Wenn jetzt aber in Spalte A Datumswerte stehen, kommt die Meldung
"Objektvariable oder with-Blockvariable nicht festgelegt."
Das muss mit dem Datumsformat zusammenhängen.
https://www.herber.de/bbs/user/57809.xls
Gruss Uwe

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Datumsformat
22.12.2008 11:12:00
Tino
Hallo,
das es Probleme beim finden von Datumsangaben gibt, wurde hier im Forum schon oft Diskutiert
Ich glaube Erich G. hat die Lösung mit der Match- Funktion damals gefunden.
So müsste es gehen.
Sub test()
   Dim LRow
   Dim intRow As Integer
   Dim Zelle As Range
   
   'erste Zelle 
   Set Zelle = Cells(1, 1)
   'Loop bis Zelle leer 
   Do Until IsEmpty(Zelle)
    
        With Worksheets("Daten")
            'Zeile Fundstelle, sonst Fehlertext 
            LRow = Application.Match(Zelle, .Columns(1), 0)
            'prüfe ob LRow eine Zahl ist 
            If IsNumeric(LRow) Then
            'Zellbereich übertragen 
              .Range(.Cells(LRow, 2), .Cells(LRow, 4)).Value = _
               Range(Zelle.Offset(0, 1), Zelle.Offset(0, 3)).Value
            End If
            'nächste Zelle 
            Set Zelle = Zelle.Offset(1, 0)
         
         End With
     
   Loop

End Sub


Gruß Tino

Anzeige
AW: Datumsformat - danke -
22.12.2008 11:18:32
uwe
Hallo Tino,
danke.
Excel hat bei dem Datum ein gewisses Eigenleben.
Gruss
Uwe
AW: Datumsformat - danke -
22.12.2008 13:51:00
Erich
Hallo Tino und Uwe,
Find nach Values hat nicht nur beim Datum, sondern allgemein bei Zahlen (und Texten!) Probleme
bei unterschiedlichen Formatierungen. Probiert mal mit einem leeren Blatt:

Sub Makro1()
Dim rngF As Range
Range("A3").FormulaR1C1 = "=1/2"
Range("A3").NumberFormat = "General"
Set rngF = Cells.Find(What:="0.5", After:=ActiveCell, LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If rngF Is Nothing Then
MsgBox "A: 0.5 nicht gefunden"
Else
MsgBox "A: Treffer in Zeile " & rngF.Row
End If
Range("A3").NumberFormat = "0.00%"        ' hier ändert sich nur das Format
Set rngF = Cells.Find(What:="0.5", After:=ActiveCell, LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If rngF Is Nothing Then
MsgBox "B: 0.5 nicht gefunden"
Else
MsgBox "B: Treffer in Zeile " & rngF.Row
End If
Range("A3").NumberFormat = "0.00E+00"     ' hier ändert sich nur das Format
Set rngF = Cells.Find(What:="0.5", After:=ActiveCell, LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If rngF Is Nothing Then
MsgBox "C: 0.5 nicht gefunden"
Else
MsgBox "C: Treffer in Zeile " & rngF.Row
End If
Range("A3").NumberFormat = "0.0"          ' hier ändert sich nur das Format
Set rngF = Cells.Find(What:="0.5", After:=ActiveCell, LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If rngF Is Nothing Then
MsgBox "D: 0.5 nicht gefunden"
Else
MsgBox "D: Treffer in Zeile " & rngF.Row
End If
End Sub

Alles Schöne und Gute für die kommenden SpecialDays wünscht euch Erich aus Kamp-Lintfort

Anzeige
AW: Datumsformat - danke -
22.12.2008 14:08:49
Tino
Hallo Erich,
genau, daher komme ich immer mehr von Find ab.
Frohe Weihnachten
Gruß Tino

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige