Pfeiltasten in Userforms

Hallo VBA-Profis :-)
mein Problem ist das ich in einer Userform nur bedingt mit den Pfeiltasten navigieren kann. Tabulator funktioniert immer, aber Pfeiltasten nur an einigen Stellen und nur auf und ab (zwischen Textboxen). Nun möchte ich aber zwischen den Textboxen auch links und rechts springen können. (z.B. um zur vorigen zurückzukommen wenn ein Eingabefehler passiert ist).
Die Textboxen sind nebeneinander und übereinander angeordnet.. teilweise unterbrochen von OptionButtons und Labels. Nur die einzutragenden Felder besitzen die Einstellung TabStop=True und nur zwischen diesen möchte ich mit Pfeiltasten navigieren können.
Gibt es da eine Einstellung in den Eigenschaften (Textbox oder Userform), oder eine andere Lösung?
Vielen Dank schonmal für die Hilfe :-)
Chris

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Chris,
versuch es mal so:

' **********************************************************************
' Modul: clsTextBox Typ: Klassenmodul
' **********************************************************************

Option Explicit

Private WithEvents mobjTextBox As MSForms.TextBox

Friend Property Set prpSetTextBox(objTextBox As MSForms.TextBox)
    Set mobjTextBox = objTextBox
End Property

Private Sub mobjTextBox_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 39 Then SendKeys "{TAB}"
    If KeyCode = 37 Then SendKeys "+{TAB}"
End Sub

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************

Option Explicit

Private objTextBoxClass() As clsTextBox

Private Sub UserForm_Activate()
    Dim intIndex As Integer
    Dim objControl As Control
    For Each objControl In Controls
        If TypeOf objControl Is MSForms.TextBox Then
            intIndex = intIndex + 1
            Redim Preserve objTextBoxClass(1 To intIndex)
            Set objTextBoxClass(intIndex) = New clsTextBox
            Set objTextBoxClass(intIndex).prpSetTextBox = objControl
        End If
    Next
End Sub

Private Sub UserForm_Terminate()
    Dim intIndex As Integer
    For intIndex = LBound(objTextBoxClass) To UBound(objTextBoxClass)
        Set objTextBoxClass(intIndex) = Nothing
    Next
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Pfeiltasten in Userforms

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread