FindNext bei verschachtelten Finds

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
das geht schon. Man muss nur an Stelle der FindNext-Methode die Find-Methode wieder anwenden und die zuletzt gefundene Zelle als Ausgangszelle benutzen (After).
Schreib einfach mal die Zahlen 1-10 in die erste Spalte so dass sie sie sich mehrfach wiederholen. Dann diese Tabelle kopieren (innerhalb der Mappe). Jetzt folgendes Beispiel durchsteppen:

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Sub Beispiel()
    Dim myRange1 As Range, myRange2 As Range
    Dim strAddress1 As String, strAddress2 As String
    Dim intIndex As Integer
    For intIndex = 1 To 10
        Set myRange1 = Worksheets(1).Columns(1).Find( _
            What:=intIndex, LookIn:=xlValues, _
            LookAt:=xlWhole)
        If Not myRange1 Is Nothing Then
            strAddress1 = myRange1.Address
            Do

                'Code für Schleife 1

                Set myRange2 = Worksheets(2).Columns(1).Find( _
                    What:=intIndex, LookIn:=xlValues, _
                    LookAt:=xlWhole)
                If Not myRange2 Is Nothing Then
                    strAddress2 = myRange2.Address
                    Do

                        'Code für Schleife 2

                        Set myRange2 = Worksheets(2).Columns(1). _
                            FindNext(myRange2)
                    Loop While Not myRange2 Is Nothing And _
                        strAddress2 <> myRange2.Address
                End If

                'hier kommt an Stelle von Findnext eine neue Find - Methode.

                Set myRange1 = Worksheets(1).Columns(1).Find( _
                    What:=intIndex, After:=myRange1, LookIn:=xlValues, _
                    LookAt:=xlWhole)
            Loop While Not myRange1 Is Nothing And _
                strAddress1 <> myRange1.Address
        End If
    Next
End Sub

Gruß
Nepumuk

Hallo Saster, hallo Luschi, hallo Nepumuk,
mit dieser Fülle von Antworten hatte ich gar nicht gerechnet. Vielen herzlichen Dank an euch alle, leider etwas verspätet. Bei mir ist etwas dazwischen gekommen, so
dass ich erst jetzt antworten kann. Bitte um Verständnis! (Man hat leider nicht immer so viel Zeit, wie man eigentlich haben wollte und müsste, um sich solchen interessanten Fragestellungen zu widmen.)
Wie ich euren Antworten entnehme, gibt es hier offenbar mehr als eine Möglichkeit, d.h. die Wiederholung
des Find-Befehls (mit neuem Bereich ab letzter Fundstelle), die Verwendung eines Jumbo-Arrays oder auch die Lösung mit VLookup, d.h. SVerweis. Ich habe mich für mein spezielles Problem in diesem Fall für die VLookup-Lösung entschieden, doch nicht ohne die Alternativen im Hinterkopf zu behalten.
Appropo Array noch meinerseits der Hinweis, dass man ein Array, wenn man in einem solchen Fall eines verwendet, auch mit der Worksheetfunction "Transpose" füllen kann. Soll angeblich schneller gehen. Ist euch Experten wohl längst bekannt, doch für manchen VBA-Normalverbraucher wie mir ist es neu. Beispiel: Range A1:A5 aus einem Worksheet in ein Array einlesen:
Dim iData(1 To 5)
iData = Application.WorksheetFunction.Transpose(ActiveSheet.Range("A1:A5"))
(Der Hinweis stammt von den chinesischen Excel-Experten von Excel Home, Excel 360 zhao, p. 31-8).
Grüße! Werner R.

Beliebteste Forumthreads (12 Monate)

FindNext bei verschachtelten Finds

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread