Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1096to1100
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

wenn Funktion mit 9 Abfragen

wenn Funktion mit 9 Abfragen
Nina
Hallo, ihr lieben Excel Profis,
ich versuche eine wenn-Funktion in Excel 2007 zu erstellen, habe aber dabei ein Problem, da ich hier 9 Abfragen benötige.
Ich habe gelesen, dass man in dieser Excel-Version, bis zu 64 Verschachtelungen erstellen kann, jedoch bekomme ich die Fehlermeldung, dass ich mehr Verschachtelungsebenen verwende, als zulässig sind.
Meine Funktion, sieht so aus:
=WENN(B6="A";ZÄHLENWENN(Tabelle2!E11:E15000;0);WENN(B6="B";ZÄHLENWENN(Tabelle2!E11:E15000;1); WENN(B6="C";ZÄHLENWENN(Tabelle2!E11:E15000;2);WENN(B6="D";ZÄHLENWENN(Tabelle2!E11:E15000;3); WENN(B6="E";ZÄHLENWENN(Tabelle2!E11:E15000;4);WENN(B6="F";ZÄHLENWENN(Tabelle2!E11:E15000;5); WENN(B6="G";ZÄHLENWENN(Tabelle2!E11:E15000;6);WENN(B6="H";ZÄHLENWENN(Tabelle2!E11:E15000;7); WENN(B6="I";ZÄHLENWENN(Tabelle2!E11:E15000;8);ZÄHLENWENN(Tabelle2!E11:E15000;9))))))))
Wenn ich in dieser Formel 2 Abfragen lösche, so dass ich wieder nur 7 Abfragen habe, ist es kein Problem und die Formel ist auch richtig. Gibt es da einen Trick?
Lieben Dank schonmal im voraus.
Liebe Grüße Nina
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:27:40
Luschi
Hallo Nina,
die Anzahl der geöffneten Klammern muß gleich der geschlossenen Klammern sein.
In Deiner Formel sind 19 '(' aber nur 17 ')'.
Gruß von Luschi
aus klein-Paris
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:32:47
Nina
Hallo Luschi,
entschuldigung. Ich hatte die Klammern jetzt nicht nochmal gezählt, da ich 2 abfragen wieder löschen mußte, damit die Formel überhaupt funktioniert.
Grundproblem bleibt trotzdem bestehen....
Liebe Grüße
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:29:19
MichaV
Hallo,
mach einfach die Formel kürzer ;o)
z.B. so: (angetestet)
=WENN(ODER(B6="a";B6="b";B6="c";B6="d";B6="e";B6="f";B6="g";B6="h";B6="i"); ZÄHLENWENN(Tabelle2!E11:E15000;CODE(GROSS(B6))-65);"")
Gruß- Micha
Anzeige
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:56:53
Nina
Hallo Micha,
vielen lieben Dank - es funktioniert!!
Dankeschööööön ;-)
Danke für die Rückmeldung mT
19.08.2009 13:01:02
MichaV
Kein Wunder daß sich alle mit ihren Antworten auf Dich stürzen, Du bist ja ne ganz nette :o)
Gruß- Micha
PS: und danke an Euch für die ODER(B6={"A";"B";"C";"D";"E";"F";"G";"H";"I"}) - Variante, ist mir schon wieder entfallen....
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:32:23
D.Saster
Hallo,
=ZÄHLENWENN(Tabelle2!E11:E15000;WENN(ODER(B6={"A";"B";"C";"D";"E";"F";"G";"H";"I"});CODE(GROSS(B6)) -65;9))
Gruß
Dierk
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:51:56
Nina
Dankeschöööön, für die schnelle Antwort!
Andere Variante
19.08.2009 12:32:42
Matthias5
Hallo Nina,
noch eine Möglichkeit:
=ZÄHLENWENN(Tabelle2!E11:E15000;VERGLEICH(B6;{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};0)-1)
Oder so, dann aber ohne Begrenzung der Buchstaben:
=ZÄHLENWENN(Tabelle2!E11:E15000;CODE(B6)-65)
Gruß,
Matthias
Anzeige
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:35:04
Hajo_Zi
Halo Nina,
ich habe mir die Formel nicht angesehen.
Mehr als 8 Ebenen bei wenn
Eine Formel kann bis zu sieben Ebenen einer verschaltelter Funktion enthalten.
http://www.excelformeln.de/formeln.html?welcher=128
=WENN(A1=1;1;WENN(A1=2;2;WENN(A1=3;3;WENN(A1=4;4;WENN(A1=5;5;WENN(A1=6;6;WENN(A1=7;7;))))))) +WENN(A1=8;8;WENN(A1=9;9;WENN(A1=10;10;WENN(A1=11;11;WENN(A1=12;12;)))))
von WF
Die Grenze liegt bei 1024 Zeichen für die Formel.
Wichtig ist es, die erste 7 Gruppe auf "" bei Text, dann weiter mit & oder auf 0 bei Zahl, dann weiter mit +enden zu lassen.
Hinweis Heinz Ulm

Anzeige
AW: wenn Funktion mit 9 Abfragen
19.08.2009 12:56:17
Nina
Hallo Hajo,
vielen lieben Dank, ich habe mich für die Formel von Micha entschieden. Die funktioniert prima.
Aber dankeschön für den Hinweis, der wird mir bei anderen Formeln sicherlich weiterhelfen.
Liebe Grüße Nina
weils so schön ist - noch mehr Varianten
19.08.2009 13:13:27
Erich
Hi Nina,
wegen der Menge habe ich jetzt nicht überprüft, ob von diesen Lösungen mehr als eine schon da war...
Tabelle1

 BC
6a7
7 7
8 7
9 7

Formeln der Tabelle
ZelleFormel
C6=WENN(ODER(B6="a";B6="b";B6="c";B6="d";B6="e";B6="f";B6="g";B6="h";B6="i"); ZÄHLENWENN(Tabelle2!E11:E120;CODE(GROSS(B6))-65); "")
C7=WENN(ODER(B6={"a"."b"."c"."d"."e"."f"."g"."h"."i"}); ZÄHLENWENN(Tabelle2!E11:E120;CODE(GROSS(B6))-65); "")
C8=WENN(ODER(B6={"a"."b"."c"."d"."e"."f"."g"."h"."i"}); ZÄHLENWENN(Tabelle2!E11:E120;CODE(B6)-97); "")
C9=WENN(ISTZAHL(FINDEN(B6;"abcdefghi")); ZÄHLENWENN(Tabelle2!E11:E120;CODE(B6)-97); "")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: weils so schön ist - noch mehr Varianten
19.08.2009 13:24:36
MichaV
Hallo Erich,
ohne zu testen fällt mir auf dass Du in den Formeln C8 und C9 das GROSS() weggelassen hast. Ich denke dann gibts einen Fehler wenn in B6 ein "A" steht. Und C9 ist auch falsch wenn B6 leer ist.
C6 und C7 wurden schon vorgestellt.
Gruß- Micha
AW: weils so schön ist - noch mehr Varianten
19.08.2009 14:17:04
Nina
Ihr seid ja sooo lieb, und scheint viel Spaß daran zu haben....
Bei mir läuft dank Euch jetzt alles supiiiiiiiii und ich habe viele weitere Tipps bekommen.
Echt Klasse ;-)
und noch eine
19.08.2009 15:46:37
Rudi
=ZÄHLENWENN(Tabelle2!E11:E15000;WAHL(MIN(CODE(GROSS(B6))-64;10);0;1;2;3;4;5;6;7;8;9))
Gruß
Rudi

335 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige