Hallo,
wie ich einen Wert durch Anzahl teile ist mir bekannt.
Nun steht in jeder Zelle aber ein Wert ab 0 , ich möchte die Zelle wo eine 0 steht nicht mit zählen bei der Anzahl.
Wie stelle ich das am besten an.
Mit freundlichem Gruß
Sankt
Hallo
ersetze Anzahl durcg Zählenwee : z.B. =ZÄHLENWENN(A1:A4;">0")
Serge
AW: Anzahl nur zählen wenn >0
20.08.2009 10:29:35
sanktflorian
Hi,
vielen Dank für Eure Antwort.
Aber irgenwie mache ich einen Fehler.
Meine Formel sieht so aus ZÄHLENWENN(B21;B43;B65;B87;B109;B131;"größerals0")
ich habe größer als nur hier ausgeschieben.
mit den Zellen. Er sagt mit zuviele Argumente.
Sankt
AW: Anzahl nur zählen wenn >0
20.08.2009 10:42:04
Rudi
Hallo,
du darfst nur einen Breich angeben.
Schau in die Hilfe!
Excel gut?
Gruß
Rudi
AW: Anzahl nur zählen wenn >0
20.08.2009 10:46:59
Luschi
Hallo sanktflorian,
versuch es mal so: =SUMMENPRODUKT((B21>0)+(B43>0)+(B65>0)+(B87>0)+(B109>0)+(B131>0))
Gruß von Luschi
aus klein-Paris
Anzeige
=SUMME(B21>0;B43>0;B65>0;B87>0;B109>0;B131>0)
20.08.2009 10:49:52
D.Saster
ZÄHLENWENN mit Mehrfachbereich
20.08.2009 11:35:39
{Boris}
Hi,
nicht zusammenhängende Bereiche musst Du für ZÄHLENWENN indirekt übergeben:
=SUMME(ZÄHLENWENN(INDIREKT({"B21"."B43"."B65"."B87"."B109"."B131"});">0"))
Oder aber auch - da Du eine 22-Zeilen-Abstand-Logik hast:
=SUMMENPRODUKT((REST(ZEILE(22:132);22)=0)*(B21:B131>0))
Grüße Boris
Apropos "eindampfen"...
20.08.2009 11:41:17
Matthias5
Hi Boris,
=SUMME(ZÄHLENWENN(INDIREKT("B"&{21.43.65.87.109.131});">0"))
Gruß,
Matthias
In diesem Fall: Ja ;-)
20.08.2009 11:49:27
{Boris}
Hi Matthias,
...aber um das Prinzip zu zeigen (und das nächste mal kommen bestimmt auch noch andere Spalten ins Spiel ;-) ), hab ich die "lange" Variante gewählt ;-)
Grüße Boris