Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1104to1108
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

komplexe Teilmengen Kalkulation

komplexe Teilmengen Kalkulation
gunair
Hallo Excel Spezialisten,
ich habe eine Aufgabe zur Kalkulation von Teilmengen die mit jeweils unterschiedlichen Preisen addiert werden müssen.
Verschiedene Produkttypen müssen je nach Menge mit unterschiedlichen Preisen berechnet werden.
Beispiel: von einem Produkt wird die Menge 450 benötigt
das Produkt kostet in der Menge 0-100 7€, 101-300 Stück 6€ 301-500 Stück 5€. Der Preis der Teilmengen soll jedoch konstant bleiben und kein Durchschnittswert ergeben. Das Beispiel zeigt was ich meine.
Vielen Dank für eure "Anteilnahme" ;-)
https://www.herber.de/bbs/user/64705.xls

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: komplexe Teilmengen Kalkulation
25.09.2009 15:34:38
jockel
hi gunnar, ich würde es so machen...:
kalkulation
 ABCDEFGHIJKLM
1Preis bei:bis Menge bestellt                    
2Typ A & B      summesumme kum.    Typ ATyp BTyp A & BTyp CTyp D
3 7,00 € 100450100700,00700,00  100 7,00 € 6,00 € 7,00 € 8,00 € 8,50 €
4 6,90 € 300  2001.380,002.080,00  300 6,90 € 5,90 € 6,90 € 8,00 € 8,50 €
5 5,00 € 500  150750,002.830,00  500 5,00 € 4,00 € 5,00 € 7,00 € 7,50 €
6 3,50 € 1000          1000 3,50 € 3,00 € 3,50 € 6,00 € 6,50 €
7 3,00 € 2000          2000 3,00 € 2,80 € 3,00 € 5,00 € 5,50 €
8 2,50 € 5000          5000 2,50 € 2,00 € 2,50 € 4,00 € 4,50 €
9                         
10                         
11                         
12                         
132.830,00   450                   
14                         
152.830,00                        

verwendete Formeln
Zelle Formel
A3 =INDEX($I3:$M3;;VERGLEICH($A$2;$I$2:$M$2;0))
D3 =WENN(MIN(B3;C$3)-SUMME(D$2:D2)=0;"";MIN(B3;C$3)-SUMME(D$2:D2))
E3 =WENN(D3="";"";A3*D3)
F3 =SUMME($E$3:E3)
A4 =INDEX($I4:$M4;;VERGLEICH($A$2;$I$2:$M$2;0))
D4 =WENN(MIN(B4;C$3)-SUMME(D$2:D3)=0;"";MIN(B4;C$3)-SUMME(D$2:D3))
E4 =WENN(D4="";"";A4*D4)
F4 =WENN(E4="";"";SUMME($E$3:E4))
A5 =INDEX($I5:$M5;;VERGLEICH($A$2;$I$2:$M$2;0))
D5 =WENN(MIN(B5;C$3)-SUMME(D$2:D4)=0;"";MIN(B5;C$3)-SUMME(D$2:D4))
E5 =WENN(D5="";"";A5*D5)
F5 =WENN(E5="";"";SUMME($E$3:E5))
A6 =INDEX($I6:$M6;;VERGLEICH($A$2;$I$2:$M$2;0))
D6 =WENN(MIN(B6;C$3)-SUMME(D$2:D5)=0;"";MIN(B6;C$3)-SUMME(D$2:D5))
E6 =WENN(D6="";"";A6*D6)
F6 =WENN(E6="";"";SUMME($E$3:E6))
A7 =INDEX($I7:$M7;;VERGLEICH($A$2;$I$2:$M$2;0))
D7 =WENN(MIN(B7;C$3)-SUMME(D$2:D6)=0;"";MIN(B7;C$3)-SUMME(D$2:D6))
E7 =WENN(D7="";"";A7*D7)
F7 =WENN(E7="";"";SUMME($E$3:E7))
A8 =INDEX($I8:$M8;;VERGLEICH($A$2;$I$2:$M$2;0))
D8 =WENN(MIN(B8;C$3)-SUMME(D$2:D7)=0;"";MIN(B8;C$3)-SUMME(D$2:D7))
E8 =WENN(D8="";"";A8*D8)
F8 =WENN(E8="";"";SUMME($E$3:E8))
D9 =WENN(MIN(B9;C$3)-SUMME(D$2:D8)=0;"";MIN(B9;C$3)-SUMME(D$2:D8))
E9 =WENN(D9="";"";A9*D9)
F9 =WENN(E9="";"";SUMME($E$3:E9))
D10 =WENN(MIN(B10;C$3)-SUMME(D$2:D9)=0;"";MIN(B10;C$3)-SUMME(D$2:D9))
E10 =WENN(D10="";"";A10*D10)
F10 =WENN(E10="";"";SUMME($E$3:E10))
A13 =SUMMENPRODUKT(A3:A10;D3:D10)
C13 =SUMME(D3:D10)
A15 {=SUMMENPRODUKT(((B3:B10)-(B2:B9))*(C$3>B2:B9);A3:A10)-(MIN(WENN(B3:B10>=C3;B3:B10))-C3)*INDEX(A3:A10;VERGLEICH(MIN(WENN(B3:B10>=C3;B3:B10));B3:B10;0))}
{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 4.24


cu jörg
ein feedback wär ganz reizend
Anzeige
AW: komplexe Teilmengen Kalkulation
01.10.2009 10:21:58
gunair
Hallo Jörg,
es hat eine Weile gedauert bis ich verstanden habe, wie ich auf deine Antwort ein feedback hier im Forum geben kann. Die Suche über meine eigenen Beiträge hat keine Funktion zum Antworten.
mein feedback: KLASSE!
Insbesondere habe ich mich über die Formel, welche du in der Spalte D verwendest gefreut. Die Funktion war mir im Kopf, aber ich wusste einfach nicht wie es umzusetzen ist. Ich kann alles nachvollziehen was du gemacht hast und spreche mein herzliches Dankeschön an dich aus. Habe alles geprüft und funktioniert tadellos.
Dank & Gruss
Gunnar
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige