Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1104to1108
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Textbox in Kommentarfeld auslesen
Constantin
Hallo,
ich komme nicht so recht weiter mit folgendem VBA-Problem: Ich habe eine Userform1, in der es eine textbox1 und eine textbox2 gibt und eine Befehlsschaltfläche "Übernehmen". Diese userform1 wird durch eine Befehlsschaltfläche in Tabelle1 aufgerufen.
Die Textbox1 soll immer den Zelleninhalt A1 von Tabelle1 beim Aufruf ausweisen. In Textbox2 kann ein freier Text eingetragen werden. Ich möchte nun diese beiden textbox(en) einmal in ein Kommentarfeld *) auslesen, genau an die Stelle (aktive Zelle), die vor dem Aufruf der Userform1 angefahren wurde (nur mit einem Schrägstrich getrennt) sowie in Tabelle2 der gleichen Exceldatei in die nächstfreie Zeile in Spalte A (für Textbox1) und Spalte B (für Textbox2), sozusagen als "strukturiertes" Auslesen in eine eigene Tabelle. Die Userform wird nach dem vollständigen Übertragen geschlossen und der Cursor auf die Ausgangszelle (wie beim Aufruf der Userform) gesetzt.
Wer könnte mir hier etwas weiterhelfen?
Grüße, Constantin
*) Ist bereits ein Kommentarfeld vorhanden, sollte der (neue) Kommentar nach einem Zeilenumbruch angehängt werden.

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Textbox in Kommentarfeld auslesen
29.09.2009 08:31:50
fcs
Hallo Constantin,
hier ein Beispiel-Code, der die gewünschten Funktionen beinhaltet.
Ich hab auch norch einen 2. Button "Abbrechen" berücksichtigt.
Gruß
Franz
'Erstellt mit Excel 2007, sollte aber auf allen Excelversionen ab 97 funktionieren
Private wks1 As Worksheet, wks2 As Worksheet
Private ZelleAktiv As Range, ZelleImmer As Range
Private Sub CommandButton1_Click()
'Übernehmen-Button
Dim Zeile As Long
With ZelleAktiv
'Prüfen, ob aktive Zelle schon eine Kommentar hat
If .Comment Is Nothing Then
.AddComment Text:=Me.TextBox1.Text & "/" & Me.TextBox2.Text
Else
.Comment.Shape.TextFrame.Characters.Text = .Comment.Text _
& vbLf & Me.TextBox1 & "/" & Me.TextBox2.Text
End If
End With
With wks2
Zeile = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
.Cells(Zeile, 1) = Me.TextBox1.Text
.Cells(Zeile, 2) = Me.TextBox2.Text
.Cells(Zeile, 3) = ZelleAktiv.Address
End With
ZelleAktiv.Select
Unload Me
End Sub
Private Sub CommandButton2_Click()
'Abbrechen-Button
ZelleAktiv.Select
Unload Me
End Sub
Private Sub UserForm_Activate()
'Tabellenblatt in dem Kommentare zu den Zellen hinzugefügt werden sollen
Set wks1 = Worksheets("Tabelle1")
'Zelle deren Inhalt immer im Kommentar als 1. Teil erscheinen soll
Set ZelleImmer = wks1.Range("A1")
'Tabellenblatt in dem alle eingetragenen Kommentare gelistet werden sollen
Set wks2 = Worksheets("Tabelle2")
'Aktive Zelle merken
Set ZelleAktiv = ActiveCell
'Textbox1 ausfüllen
Me.TextBox1 = ZelleImmer.Text
Me.Caption = "Kommentar für Zelle " & ZelleAktiv.Address & " erstellen/ergänzen"
Me.TextBox2.SetFocus
End Sub

Anzeige
AW: Textbox in Kommentarfeld auslesen
30.09.2009 11:02:04
Constantin
Hallo Franz,
es funktioniert - großartig! Vielen Dank für den umfassenden Lösungsansatz. Und sorry, dass ich so spät antworte; ich hatte als Forumsneuling im falschen Bereich gesucht und damit das Antwortformular nicht erhalten. Jetzt klappt auch dieses.
Gruß, Constantin

302 Forumthreads zu ähnlichen Themen


Hallo zusammen,
wie bekomme ich es hin, in eine Zelle "7 a" (7 Leerzeichen a) zu schreiben? Excel macht mir dann immer 7:00 AM daraus oder 0,29...
Danke
Anzeige

Guten Tag zusammen!
Bitte helft mir bei folgendem Problem:
In einer Userform habe ich eine ganze Reihe Textboxen, in die zum größten Teil Zahlen eingegeben werden.
Nun ist ja bekannt, dass beim Schreiben in Zellen der Inhalt der Textboxen als Text interpretiert wird. Mit der Anweisu...

Guten Tag zusammen!
Bitte helft mir bei folgendem Problem:
In einer Userform habe ich eine ganze Reihe Textboxen, in die zum größten Teil Zahlen eingegeben werden.
Nun ist ja bekannt, dass beim Schreiben in Zellen der Inhalt der Textboxen als Text interpretiert wird. Mit der Anweisu...
Anzeige

Hallo,
ich habe eine umfangreiche Artikelliste (ca. 250.000 Artikel) aus einer Datanormdatei erstellt.
Aus dieser muss ich jetzt alle Artikel entfernen, dessen Artikelnummer (in Spalte A; als Text formatiert, damit führende Nullen nicht gelöscht werden) keinerlei Zahlen enthalten.
E...

Hi Leute
Ich habe hier diesen netten VBA Code geschrieben und leider wie solls auch anders sein kommt dauernd eine Fehlermeldung :)
CODE:
rowbeforeinteger = 2
Dim text As String
text = "=IF(" & epsoldcolumn & rowbeforeinteger & "=""x"";1;0)+IF(" & emailsoldco...

Guten Morgen!
wie ich Daten über Userform TextBoxen in die Zellen zurückschreibe, dafür habe ich bereits eine Lösung.
Is es jedoch möglich einen gefärbten Hintergrund einer TextBox in die dafür vorgesehene Zelle zu übertragen?
Wenn ja, wie würde dann bitte eine VBA Lösung lauten?
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige