HERBERS Excel-Forum - das Archiv
Bewerten Sie hier bitte das Excel-Portal
Shortcut um zwischen Blättern zu springen
nicospostbox

Hallo zusammen!
Gibt es eine Möglichkeit, mit Hilfe von Shortcuts zwischen Arbeitsblättern einer Excel-Datei hin- und herzuspringen?
Ich habe eine Datei mit etwa 20 Blättern und muss immer wieder zwischen einigen hin- und herspringen und würde mir hier das Leben gerne etwas einfacher machen (z.B. Alt-D für "Datenbank", Alt-Z für "Zusammenfassung", Alt-A für "Annahmen").
Hat jemand eine Idee?
Danke & Grüße,
Nico

AW: Shortcut um zwischen Blättern zu springen
Hajo_Zi

Hallo Nico,
Tastenkombinationen Excel Wechsel zwischen Arbeitsmappen
Strg +Bild Auf ein Register vor
Strg +Bild Ab ein Register zurück
Strg + F6 andere Arbeitsmappe
Strg + SHIFT + F6 andere Arbeitsmappe
Strg + Tab andere Arbeitsmappe
zwischen den Tabellen
Strg+Bild Auf
Strg+Bild Ab

AW: Shortcut um zwischen Blättern zu springen
nicospostbox

Hallo Hajo!
Danke schön! Aber die kannte ich schon - ich denke, ich habe mich nicht ganz glücklich ausgedrückt!
Ich möchte z.B. vom 1. Register (z.B. Datenbank) direkt zum 12. (z.B. Zusammenfassung) springen und von dort weiter zum 5. (z.B. Annahmen), ohne durch alle Register "blättern" zu müssen.
Geht das?
Danke schön!
Nico
AW: Shortcut um zwischen Blättern zu springen
Hajo_Zi

Hallo Nico,
das geht nur mit Hyprlink.
Gruß Hajo
AW: Shortcut um zwischen Blättern zu springen
nicospostbox

Ok - kann ich Hyperlinks per Shortcut ansprechen?
AW: Shortcut um zwischen Blättern zu springen
Hajo_Zi

Hallo Nico,
die sind doch in einer Zelle. Ich glaube nicht.
Gruß Hajo
AW: Shortcut um zwischen Blättern zu springen
nicospostbox

Schade! Danke trotzdem!
AW: Shortcut um zwischen Blättern zu springen
Josef

Hallo Nico,
probier mal folgenden Code. Er estellt automatisch Shortcuts zu den Blättern die mit
[STRG]+[SHIFT]+[Erster Buchstabe des Blattnamens] angesprungen werden.
Bei 20 Blättern wirst du damit aber sicher probleme bekommen, weil sicher mehrere Blätter
den selben Anfangsbuchstaben besitzen. Wenn du neue Blätter hinzufügst, musst du den
Code von Hand starten, sonst erhalten diese keinen Shortcut.
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Activate()
  createShortCuts
End Sub

Private Sub Workbook_Deactivate()
  destroyShortCut
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub createShortCuts()
  Dim objSh As Worksheet
  Dim strCommand As String, strSC As String
  
  For Each objSh In ThisWorkbook.Worksheets
    strSC = "^+" & Left(objSh.Name, 1)
    strCommand = "'switchSheet """ & objSh.Name & """'"
    Application.OnKey strSC, strCommand
  Next
  
End Sub

Sub destroyShortCut()
  Dim objSh As Worksheet
  Dim strSC As String
  
  For Each objSh In ThisWorkbook.Worksheets
    strSC = "^+" & Left(objSh.Name, 1)
    Application.OnKey strSC
  Next
End Sub

Sub switchSheet(ByVal SheetName As String)
  On Error Resume Next
  ThisWorkbook.Sheets(SheetName).Activate
  On Error GoTo 0
End Sub

Gruß Sepp