Herbers Excel/VBA-Archiv

Nichtfarbige Zellen löschen | Herbers Excel-Forum

• Nichtfarbige Zellen löschen von Walter vom 20.01.2010 14:38:45
• AW: Nichtfarbige Zellen löschen - von Tino am 20.01.2010 15:01:23
  • AW: Nichtfarbige Zellen löschen - von Tino am 20.01.2010 15:03:45
• AW: Nichtfarbige Zellen löschen - von Rudi Maintaire am 20.01.2010 15:02:38
  • AW: Nichtfarbige Zellen löschen - von Walter am 20.01.2010 16:10:05

Betrifft: Nichtfarbige Zellen löschen von: Walter
Geschrieben am: 20.01.2010 14:38:45

Hallo Excelfreunde,

Ich möchte in einer Tabelle alle nicht markierten Zellen löschen.
Im Forum habe ich zwei Lösungen gefunden, bekomme es aber nicht hin.
Bitte um Hilfe.
www.herber.de/bbs/user/67349.xls"

Es grüßt
Rentner Walter

Betrifft: AW: Nichtfarbige Zellen löschen von: Tino
Geschrieben am: 20.01.2010 15:01:23

Hallo,
versuche es mal mit diesem Code.

Sub test()
Dim Bereich As Range, tmpRng As Range

Set Bereich = Range("A1", Cells(Cells(Rows.Count, 1).End(xlUp).Row, 70))

Application.ScreenUpdating = False
    For Each Bereich In Bereich
     If Bereich.Interior.ColorIndex <> xlColorIndexNone Then
        If Not tmpRng Is Nothing Then
           Set tmpRng = Union(tmpRng, Bereich)
        Else
           Set tmpRng = Bereich
        End If
     End If
    Next Bereich
    
    If Not tmpRng Is Nothing Then
        tmpRng.ClearContents
    End If
Application.ScreenUpdating = True
End Sub

Gruß Tino

Betrifft: AW: Nichtfarbige Zellen löschen von: Tino
Geschrieben am: 20.01.2010 15:03:45

Hallo,
Du möchtest ja die nicht farbigen Zellen löschen.

Mach aus

If Bereich.Interior.ColorIndex <> xlColorIndexNone Then

dies

If Bereich.Interior.ColorIndex = xlColorIndexNone Then

Gruß Tino

Betrifft: AW: Nichtfarbige Zellen löschen von: Rudi Maintaire
Geschrieben am: 20.01.2010 15:02:38

Hallo,
also alles, was keinen oder weißen Hintergrund hat?

Sub tt()
  Dim rngDel As Range
  Dim rngC As Range
  Application.ScreenUpdating = False
  For Each rngC In ActiveSheet.UsedRange.Cells
    If rngC.Interior.ColorIndex = xlNone _
      Or rngC.Interior.Color = RGB(255, 255, 255) Then
      If rngDel Is Nothing Then
        Set rngDel = rngC
      Else
        Set rngDel = Union(rngDel, rngC)
      End If
    End If
  Next
  If Not rngDel Is Nothing Then rngDel.ClearContents
  Application.ScreenUpdating = True
End Sub

Gruß
Rudi

Betrifft: AW: Nichtfarbige Zellen löschen von: Walter
Geschrieben am: 20.01.2010 16:10:05

Dank an Euch,

geht wunderbar

Gruß
Walter

Beiträge aus den Excel-Beispielen zum Thema "Nichtfarbige Zellen löschen"