AW: Textdatei Import nach Excel
30.09.2010 11:29:54
Tino
Hallo,
kannst dies mal testen.
Deine Excel- Datei sollte aber im xlsm Format gespeichert vorliegen wegen der anzahl Zeilen.
Du müsstest dies im Code noch anpassen.
Pfad, erste Zeile, erste Spalte, Text Delimiter (Trennzeichen für Spalten im Text)
Sub txt_ReadLine()
Dim meText() As String, sLine As String, sFilename As String
Dim lngRow As Long, lngCol As Long
Dim F As Long
'Delimiter angeben
Const strDelimiter$ = ";"
'Pfad
sFilename = "C:\Temp\Test.txt"
'erste Zeile: erste Spalte
lngRow = 2: lngCol = 1
If Dir$(sFilename) <> "" Then
meEvent False
'Sicherheit wegen Event Abschaltung
On Error GoTo Fehler:
'Bereich leer machen für neue Daten
Range(Cells(2, 1), Cells(Rows.Count, 11)).ClearContents
F = FreeFile
Open sFilename For Input As #F
While Not EOF(F)
Line Input #F, sLine
meText = Split(sLine, strDelimiter)
Cells(lngRow, lngCol).Resize(, Ubound(meText) + 1) = meText
lngRow = lngRow + 1
Wend
Close #F
meEvent True
End If
Exit Sub
Fehler:
On Error Resume Next
Close #F
meEvent True
MsgBox "Fehler aufgetreten!", vbCritical
On Error GoTo 0
End Sub
Sub meEvent(boo_On_Off As Boolean)
Static int_xlCalc As Integer
With Application
int_xlCalc = IIf(boo_On_Off, int_xlCalc, .Calculation)
.Calculation = IIf(boo_On_Off, int_xlCalc, xlCalculationManual)
.ScreenUpdating = boo_On_Off
.EnableEvents = boo_On_Off
End With
End Sub
Gruß Tino