Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1224to1228
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zellen kopieren, Leerzeilen löschen - nach Prüfung

Zellen kopieren, Leerzeilen löschen - nach Prüfung
Konstantin
Hallo in die Expertenrunde,
ich bekomme Daten aus einer Auswertungsliste in Excel-Form und diese muss entsprechend für einen weiteren Arbeitsschritt von mir „angepasst“ werden.
Die automatisch generierten Daten kommen allerdings in einer für mich etwas unglücklicher Form, so dass manueller und zeitraubender Aufwand entsteht.
Spalte 1: Projektbeschreibung (Bezeichnung variert)
Spalte 2: Budget – (Detailbeschreibung – kann gleich sein wie Spalte 1, kann aber auch variieren, wenn es ein weiteres Teil / Unterprojekt ist)
Aufgabenstellung:
Die Spalte 1 – Projektbeschreibung muss nach unten kopiert werden – wenn eine neue Beschreibung kommt entsprechend.
Leerzeilen müssen entfernt werden, wenn in Spalte C,D,E keine Zahlen eingetragen sind.
Gibt es eine Möglichkeit dieses per VBA Makro abzufangen?
Ich wäre Euch sehr verbunden.
vielen Dank und Grüsse
Konstantin
Demodaten:
https://www.herber.de/bbs/user/76089.xls

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Zellen kopieren, Leerzeilen löschen - nach Prüfung
10.08.2011 13:06:28
fcs
Hallo Konstantin,
nachfolgend ein Makro zu Aufbereitung der Daten.
Gruß
Franz
Sub AufbereitenImport()
Dim wks As Worksheet
Dim Zeile As Long, Zeile_1 As Long, Zeile_L As Long
Dim sProjekt As String
Set wks = ActiveSheet
With wks
'Letzte Zeile mit Eintrag in Spalte B
Zeile_L = .Cells(.Rows.Count, 2).End(xlUp).Row
' Zeile mit Spaltentiteln ermitteln
Zeile_1 = 1
Do Until .Cells(Zeile_1, 1) = "Projekt" And .Cells(Zeile_1, 2) = "Budgetebene"
Zeile_1 = Zeile_1 + 1
Loop
Zeile_1 = Zeile_1 + 1 'Zeile unter den Spaltentiteln
Application.ScreenUpdating = False
For Zeile = Zeile_1 To Zeile_L
'Projektbezeichnungen nachtragen in Spalte A
If .Cells(Zeile, 1).Value  "" Then
sProjekt = .Cells(Zeile, 1).Value
Else
.Cells(Zeile, 1).Value = sProjekt
End If
'Projekt löschen wenn in Spalten C, D und E keine Einträge
If .Cells(Zeile, 3) = "" And .Cells(Zeile, 4) = "" And .Cells(Zeile, 5) = "" Then
.Cells(Zeile, 1).ClearContents
End If
Next
'Zeilen löschen, wenn leer in Spalte A
With .Range(.Cells(Zeile_1, 1), .Cells(Zeile_L, 1))
If Application.WorksheetFunction.CountBlank(.Cells) > 0 Then
.SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End If
End With
Application.ScreenUpdating = True
End With
End Sub

Anzeige
AW: Zellen kopieren, Leerzeilen löschen - nach Prüfung
10.08.2011 15:08:25
Konstantin
Hallo Franz,
vielen herzlichen Dank für den Excel-VBA-Code.
Klappt einwandfrei!
Gruss
Konstantin

303 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige