Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1224to1228
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Numerologische Werte

Numerologische Werte
Alifa
Hallo,
ich suche die numerologischen Werte der Zahlen von 1 bis 1000. Beispiel: 3 hat den Wert 36. Drei=4+18+5+9=36. Das Makro müsste zuerst die Zahlen in Worte umwandeln und anschließend den Wert berechnen. Kann mir jemand dabei helfen?
Gruß, Alifa
AW: Numerologische Werte
14.08.2011 09:02:08
Hajo_Zi
nur wenige sehen warum 3 = 4+18+5+9=36 ist. Ich verstehe auch nicht was Du berechnen willst bzw.was das mit 3 zu tun hat.

AW: Numerologische Werte
14.08.2011 12:59:10
robert
Hallo Hajo,
du musst von dem Wort DREI ausgehen.
D = 4.Buchstabe, R=18.Buchstabe im Alphabet, usw..
dann 4+18 usw. addieren, = 36
Sinn und Zweck ?
Gruß
robert
AW: Numerologische Werte
14.08.2011 09:12:51
Herby
Hallo Alifa,
anbei eine halbautomatische Lösung. Die Ziffern in Buchstaben umwandeln
geht z.B. per Formeln: www.excelformeln.de Formel Nr. 36
https://www.herber.de/bbs/user/76174.xls
viele Grüße
Herby
Anzeige
AW: Numerologische Werte
14.08.2011 13:58:37
Alifa
Hallo Herby
Der Link löst mein Problem. Eine Frage reiche ich nach: Gibt es ein Makro auch in Französisch und Englisch?
Die Zahlen werden also in französischer oder englischer Sprache dargestellt. Beispiel ONE =>15+14+5=34.
oder THREE=>20+8+18+5+5=56. Oder in Französisch: ONZE=>15+14+26+5=60. Für mich ist das eine interessante Freizeitbeschäftigung, aus Freude an Excel und VBA.
Danke für die Hilfe
Alifa
AW: Numerologische Werte
14.08.2011 14:45:17
mpb
Hallo,
das geht auch ohne VBA und benutzerdefinierte Funktion. Wenn der Text "eins" in Zelle A1 steht, folgende Matrixformel:
=SUMME(WENN(ISTZAHL(CODE(TEIL(A1;ZEILE($1:$100);1))-96);CODE(TEIL(A1;ZEILE($1:$100);1))-96;0))
Die Eingabe der Formel mit der Tastenkombination STRG-SHIFT-ENTER, nicht mit ENTER abschließen. Funktioniert in jeder Sprache bei Zahlwörtern mit höchstens 100 Buchstaben (ansonsten die Vorgabe bei ZEILE erhöhen), sofern nur Kleinbuchstaben verwendet werden.
Gruß
Martin
Anzeige
Alternative ohne WENN
14.08.2011 18:09:14
Erich
Hi zusammen,
die Summe könnte man auch so wie in C1 bilden:
 ABC
1einhundertfünfzehn353353

Formeln der Tabelle
ZelleFormel
B1{=SUMME(WENN(ISTZAHL(CODE(TEIL(A1;ZEILE($1:$100); 1))-96); CODE(TEIL(A1;ZEILE($1:$100); 1))-96;0))}
C1{=SUMME(CODE(TEIL(A1;ZEILE($1:$1000); 1)&ZEICHEN(1)))-95*LÄNGE(A1)-1000}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
Zahlworte und numerologische Werte
15.08.2011 16:51:16
Erich
Hi Erhard,
so könnte es von 1 bis 999 schon mal klappen:
 ABCDEFGHIJK
1ZahlTextNumerologHZEZET HT ZET ET Z
21eins470101 eins  
35fünf1820505  fünf 
410zehn5301010   zehn
5120einhundertzwanzig22412020einhundert  zwanzig
6211zweihundertelf17621111zweihundertelf  
7216zweihundertsechzehn24121616zweihundertsechzehn  
8317dreihundertsiebzehn21431717dreihundertsiebzehn  
9501fünfhunderteins3195101fünfhunderteins  
10777siebenhundertsiebenundsiebzig31477777siebenhundert siebenundsiebzig
11999neunhundertneunundneunzig33399999neunhundert neunundneunzig

Formeln der Tabelle
ZelleFormel
B2=H2&I2&J2&K2
C2{=SUMME(CODE(TEIL(B2;ZEILE($1:$100); 1)&ZEICHEN(1)))-95*LÄNGE(B2)-100}
D2=REST(KÜRZEN(A2/100); 10)
E2=REST(KÜRZEN(A2); 100)
F2=REST(KÜRZEN(A2/10); 10)
G2=REST(KÜRZEN(A2); 10)
H2=WENN(D2>0;WAHL(D2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
I2=WENN(ISTNV(VERGLEICH(E2;{1.11.12.16.17};0)); "";VERWEIS(E2;{1.11.12.16.17};{"eins"."elf"."zwölf"."sechzehn"."siebzehn"}))
J2=WENN(I2="";WAHL(G2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
K2=WENN(I2="";WENN((G2>0)*(F2>1); "und";"")&WAHL(F2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Ich habe nicht ausgiebig getestet.
Sind die Umlaute ü und ö in fünf und zwölf eventuell ein Problem?
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
Zahlen in Worten - bis 999.999.999
15.08.2011 21:19:58
Erich
Hi Erhard,
damit die 1000 auch noch geht, hab ich die Formeln noch ein wenig aufgebohrt - bis 999.999.999:
 ABCDEFGHIJKLMNOPQRSTUVWXYZAAAB
1ZahlTextHMZEMZMEMHTZETZTETHZEZEx HMx ZEMx EMx ZMMx HTx ZETx ETx ZTTX HX ZEX EX Z
2123456789einhundertdreiundzwanzigmillionenvierhundertsechsundfünfzigtausendsiebenhundertneunundachtzig123234565678989einhundert dreiundzwanzigmillionenvierhundert sechsundfünfzigtausendsiebenhundert neunundachtzig

Formeln der Tabelle
ZelleFormel
B2=O2&P2&Q2&R2&S2&T2&U2&V2&W2&X2&Y2&Z2&AA2&AB2
C2=REST(KÜRZEN($A2/100000000); 10)
D2=REST(KÜRZEN($A2/1000000); 100)
E2=REST(KÜRZEN($A2/10000000); 10)
F2=REST(KÜRZEN($A2/1000000); 10)
G2=REST(KÜRZEN($A2/100000); 10)
H2=REST(KÜRZEN($A2/1000); 100)
I2=REST(KÜRZEN($A2/10000); 10)
J2=REST(KÜRZEN($A2/1000); 10)
K2=REST(KÜRZEN($A2/100); 10)
L2=REST(KÜRZEN($A2); 100)
M2=REST(KÜRZEN($A2/10); 10)
N2=REST(KÜRZEN($A2); 10)
O2=WENN(C2>0;WAHL(C2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
P2=WENN(ISTNV(VERGLEICH(D2;{1.11.12.16.17};0)); "";VERWEIS(D2;{1.11.12.16.17};{"ein"."elf"."zwölf"."sechzehn"."siebzehn"}))
Q2=WENN(P2="";WAHL(F2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
R2=WENN(P2="";WENN((E2>0)*(D2>1); "und";"")&WAHL(E2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
S2=WENN(O2&P2&Q2&R2="";"";"million"&WENN(C2+D2>1;"en";""))
T2=WENN(G2>0;WAHL(G2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
U2=WENN(ISTNV(VERGLEICH(H2;{1.11.12.16.17};0)); "";VERWEIS(H2;{1.11.12.16.17};{"ein"."elf"."zwölf"."sechzehn"."siebzehn"}))
V2=WENN(U2="";WAHL(J2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
W2=WENN(U2="";WENN((J2>0)*(I2>1); "und";"")&WAHL(I2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
X2=WENN(T2&U2&V2&W2="";"";"tausend")
Y2=WENN(K2>0;WAHL(K2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
Z2=WENN(ISTNV(VERGLEICH(L2;{1.11.12.16.17};0)); "";VERWEIS(L2;{1.11.12.16.17};{"eins"."elf"."zwölf"."sechzehn"."siebzehn"}))
AA2=WENN(Z2="";WAHL(N2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
AB2=WENN(Z2="";WENN((N2>0)*(M2>1); "und";"")&WAHL(M2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
@Erich : Upload für Faule :-D
15.08.2011 22:47:50
NoNet
Hallo Erich,
Deine Funktion sieht toll aus und funktioniert auch offenbar ganz gut.
Du hast ja freundlicherweise auch die Funktionen gleich mit gepostet.
Da ich jedoch zu der Gattung fauler äähhhh... 'effizient und optimiert arbeitender' Mensch gehöre, würde ich gerne auf eine Eingabe der Funktionen verzichten (auch kein langwieriges Copy-Paste), da das eine unötige Arbeitsredundanz bedeuten würde (schliesslich hast DU diese Arbeit ja bereits geleistet )
Daher möchte ich Dich bitten, für die "Nachwelt" ein funktionierendes Beispiel bei herber hochzuladen und den passenden Link hier zu veröffentlichen.
Vielen Dank vorab !
Gruß, NoNet
Exceltreffen 28.-30.10.2011 in Chemnitz
Ein Treffen für alle Excel-Freunde und Besucher deutschsprachiger Excel-Foren.
Alle Infos - Programm - Anmeldung - Teilnehmerliste etc. gibt es auf
http://www.exceltreffen.de/index.php?page=211
Wir freuen uns auf euch...

Anzeige
Upload: in Worten...
16.08.2011 09:34:02
Erich
Hi Thomas und Erhard,
klar, nachdem ich noch mindestens zwei Fehler ausgebaut habe, lade ich das gern hoch:
https://www.herber.de/bbs/user/76203.xls
Für Erhard habe ich hinten die numerologischen Summen dringelassen.
Wie viele Fehler ich auch noch dringelassen habe, weiß ich natürlich (noch) nicht... ;-)
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
@Erich : Danke Dir...
16.08.2011 11:36:28
NoNet
...damit ist meiner Faulheit Arbeits-Effizienz genüge getan ;-))
Salut, NoNet
Exceltreffen 28.-30.10.2011 in Chemnitz
Ein Treffen für alle Excel-Freunde und Besucher deutschsprachiger Excel-Foren.
Alle Infos - Programm - Anmeldung - Teilnehmerliste etc. gibt es auf
http://www.exceltreffen.de/index.php?page=211
Wir freuen uns auf euch...

Anzeige
numerologischen Summen..
16.08.2011 12:32:49
robert
Hi Erich,
ich habs mir auch "ausgeliehen" .... ;-)
aber zB. bei 3(drei) sollte
doch 36 rauskommen-oder?
Gruß
robert
numerologische Summen korrigiert
16.08.2011 13:13:28
Erich
Hi Robert,
da hast du gleich den nächsten Fehler gefunden, danke!
Durch ein nachträgliches Einfügen von Zeilen ist aus ZEILE($1:$100) in der Formel in Spalte AC ZEILE($1:$104) geworden,
aber es muss natürlich ZEILE($1:$100) heißen.
Hier noch mal alle Formeln:
 ABCDEFGHIJKLMNOPQRSTUVWXYZAAABAC
1ZahlTextHMZEMZMEMHTZETZTETHZEZEx HMx ZEMx EMx ZMMx HTx ZETx ETx ZTTX HX ZEX EX ZNumerolog
23drei000000000303            drei 36

Formeln der Tabelle
ZelleFormel
B2=O2&P2&Q2&R2&S2&T2&U2&V2&W2&X2&Y2&Z2&AA2&AB2
C2=REST(KÜRZEN($A2/100000000); 10)
D2=REST(KÜRZEN($A2/1000000); 100)
E2=REST(KÜRZEN($A2/10000000); 10)
F2=REST(KÜRZEN($A2/1000000); 10)
G2=REST(KÜRZEN($A2/100000); 10)
H2=REST(KÜRZEN($A2/1000); 100)
I2=REST(KÜRZEN($A2/10000); 10)
J2=REST(KÜRZEN($A2/1000); 10)
K2=REST(KÜRZEN($A2/100); 10)
L2=REST(KÜRZEN($A2); 100)
M2=REST(KÜRZEN($A2/10); 10)
N2=REST(KÜRZEN($A2); 10)
O2=WENN(C2>0;WAHL(C2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
P2=WENN(ISTNV(VERGLEICH(D2;{1.11.12.16.17};0)); "";VERWEIS(D2;{1.11.12.16.17};{"eine"."elf"."zwölf"."sechzehn"."siebzehn"}))
Q2=WENN(P2="";WAHL(F2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
R2=WENN(P2="";WENN((F2>0)*(E2>1); "und";"")&WAHL(E2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
S2=WENN(O2&P2&Q2&R2="";"";"million"&WENN(D2>1;"en";""))
T2=WENN(G2>0;WAHL(G2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
U2=WENN(ISTNV(VERGLEICH(H2;{1.11.12.16.17};0)); "";VERWEIS(H2;{1.11.12.16.17};{"ein"."elf"."zwölf"."sechzehn"."siebzehn"}))
V2=WENN(U2="";WAHL(J2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
W2=WENN(U2="";WENN((J2>0)*(I2>1); "und";"")&WAHL(I2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
X2=WENN(T2&U2&V2&W2="";"";"tausend")
Y2=WENN(K2>0;WAHL(K2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
Z2=WENN(ISTNV(VERGLEICH(L2;{1.11.12.16.17};0)); "";VERWEIS(L2;{1.11.12.16.17};{"eins"."elf"."zwölf"."sechzehn"."siebzehn"}))
AA2=WENN(Z2="";WAHL(N2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
AB2=WENN(Z2="";WENN((N2>0)*(M2>1); "und";"")&WAHL(M2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
AC2{=SUMME(CODE(TEIL(B2;ZEILE($1:$100); 1)&ZEICHEN(1)))-95*LÄNGE(B2)-100}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Und die korrigierte Mappe für NoNet ;-) : https://www.herber.de/bbs/user/76209.xls
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
Danke im Namen der "faulen"-owT
16.08.2011 13:44:51
robert
Zahl in Worten - Vorzeichen+Nachkommastellen
17.08.2011 09:42:47
Erich
Hi zusammen,
hier noch eine kleine Erweiterung. Jetzt werden auch ein "minus" und zwei Nachkommastellen ausgegeben,
letztere etwas anders als im Excelformeln-Tipp Nr. 36:
 ABCDEFGHIJKLMNOPQRSTUVWXYZAAABACADAEAFAGAH
1ZahlNkTextAbsHMZEMZMEMHTZETZTETHZEZEn Zn Ex HMx ZEMx EMx ZMMx HTx ZETx ETx ZTTX HX ZEX EX Zn Zn E
2-3,570minus drei3,5700000000030357            drei fünfsieben
3-3,571minus drei 57/1003,5700000000030357            drei fünfsieben
4-3,572minus drei komma fünf sieben3,5700000000030357            drei fünfsieben
5-11,000minus elf11,00000000000111100           elf  null 
6-11,001minus elf 00/10011,00000000000111100           elf  null 
7-11,002minus elf komma null 11,00000000000111100           elf  null 
8-11,102minus elf komma eins null11,10000000000111110           elf  einsnull
9-11,012minus elf komma null eins11,01000000000111101           elf  nulleins

Formeln der Tabelle
ZelleFormel
C2=WENN(A2<0;"minus ";"")&S2&T2&U2&V2&W2&X2&Y2&Z2&AA2&AB2&AC2&AD2&AE2&AF2&WAHL(B2+1;"";TEXT(REST(D2*100;100); " 00")&"/100";" komma "&AG2&" "&AH2;"")
D2=ABS(A2)
E2=REST(KÜRZEN($D2/100000000); 10)
F2=REST(KÜRZEN($D2/1000000); 100)
G2=KÜRZEN(F2/10)
H2=REST(F2;10)
I2=REST(KÜRZEN($D2/100000); 10)
J2=REST(KÜRZEN($D2/1000); 100)
K2=KÜRZEN(J2/10)
L2=REST(J2;10)
M2=REST(KÜRZEN($D2/100); 10)
N2=REST(KÜRZEN($D2); 100)
O2=KÜRZEN(N2/10)
P2=REST(N2;10)
Q2=REST(KÜRZEN(10*$D2); 10)
R2=RUNDEN(REST(100*$D2;10); )
S2=WENN(E2>0;WAHL(E2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
T2=WENN(ISTNV(VERGLEICH(F2;{1.11.12.16.17};0)); "";VERWEIS(F2;{1.11.12.16.17};{"eine"."elf"."zwölf"."sechzehn"."siebzehn"}))
U2=WENN(T2="";WAHL(H2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
V2=WENN(T2="";WENN((H2>0)*(G2>1); "und";"")&WAHL(G2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
W2=WENN(S2&T2&U2&V2="";"";"million"&WENN(F2>1;"en";""))
X2=WENN(I2>0;WAHL(I2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
Y2=WENN(ISTNV(VERGLEICH(J2;{1.11.12.16.17};0)); "";VERWEIS(J2;{1.11.12.16.17};{"ein"."elf"."zwölf"."sechzehn"."siebzehn"}))
Z2=WENN(Y2="";WAHL(L2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
AA2=WENN(Y2="";WENN((L2>0)*(K2>1); "und";"")&WAHL(K2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
AB2=WENN(X2&Y2&Z2&AA2="";"";"tausend")
AC2=WENN(M2>0;WAHL(M2;"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")&"hundert";"")
AD2=WENN(ISTNV(VERGLEICH(N2;{1.11.12.16.17};0)); "";VERWEIS(N2;{1.11.12.16.17};{"eins"."elf"."zwölf"."sechzehn"."siebzehn"}))
AE2=WENN(AD2="";WAHL(P2+1;"";"ein";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun"); "")
AF2=WENN(AD2="";WENN((P2>0)*(O2>1); "und";"")&WAHL(O2+1;"";"zehn";"zwanzig";"dreißig";"vierzig";"fünfzig";"sechzig";"siebzig";"achtzig";"neunzig"); "")
AG2=WAHL(Q2+1;"null";"eins";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")
AH2=WAHL(R2+1;WENN(Q2>0;"null";""); "eins";"zwei";"drei";"vier";"fünf";"sechs";"sieben";"acht";"neun")

Und hier natürlich wieder die Mappe: https://www.herber.de/bbs/user/76220.xls
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
Zahl in Worten - Nachkommastellen anders
19.08.2011 08:14:59
Erich
Hi zusammen,
vielleicht interessiert euch diese Version auch noch: https://www.herber.de/bbs/user/76243.xls
Schönes Wochenende allerseits! Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige