Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1224to1228
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Tabelle nach Liste kopieren und eintragen

Tabelle nach Liste kopieren und eintragen
Lutz
Hallo Excel-Spezialisten,
leider habe ich mal wieder ein Problem:
Ich habe eine Tabelle mit rund 150 Artikeln im Blatt "Artikelliste" von Zelle A2:A150
die Zeilenanzahl kann sich aber immer ändern.
Jetzt soll eine Tabelle "Kalkulation" so oft kopiert werden wie es Artikel gibt und immer
den Namen "K"+ den Namen des Artikels aus A2:A150 bekommen.
Und dann wäre es ganz toll, wenn immer in die erstellte Tabelle in die Zelle A2 der
Artikel aus A2:A150 eingetragen werden würde.
Ich denke, am Anfang ermittelt man aus A2:A150 mit Count die Anzahl der Artikel = i
dann kopiert man mit i die Tabellen und benennt diese und trägt dann die variable aus der
Benennung in die Zelle A2 ein
dann nächstes i….
Leider kann ich nicht wirklich programmieren - vielleicht hat jemand das auch schon mal als
Lösung erstellt?
Vielen Dank und viele Grüße Lutz

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Tabelle nach Liste kopieren und eintragen
23.08.2011 22:27:44
Josef

Hallo Lutz,
teste mal.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub BlaetterAnlegen()
  Dim rng As Range
  Dim objShCopy As Worksheet
  
  On Error GoTo ErrExit
  tranquilize
  
  Set objShCopy = Sheets("Kalkulation")
  
  With Sheets("Artikelliste")
    For Each rng In .Range("A2:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
      If rng <> "" Then
        If Not SheetExist("K" & rng.Text) Then
          objShCopy.Copy After:=Sheets(Sheets.Count)
          Sheets(Sheets.Count).Name = "K" & rng.Text
          Sheets(Sheets.Count).Cells(2, 1) = rng
        End If
      End If
    Next
    .Activate
  End With
  
  ErrExit:
  tranquilize True
  
  Set objShCopy = Nothing
End Sub


Private Function SheetExist(ByVal sheetName As String, Optional Wb As Workbook) As Boolean
  Dim wks As Worksheet
  On Error GoTo ERRORHANDLER
  If Wb Is Nothing Then Set Wb = ThisWorkbook
  For Each wks In Wb.Worksheets
    If LCase(wks.Name) = LCase(sheetName) Then SheetExist = True: Exit Function
  Next
  ERRORHANDLER:
  SheetExist = False
End Function


Public Sub tranquilize(Optional ByVal Modus As Boolean = False)
  Static lngCalc As Long
  
  With Application
    .ScreenUpdating = Modus
    .EnableEvents = Modus
    .DisplayAlerts = Modus
    .EnableCancelKey = IIf(Modus, 1, 0)
    If Not Modus Then lngCalc = .Calculation
    If Modus And lngCalc = 0 Then lngCalc = -4105
    .Calculation = IIf(Modus, lngCalc, -4135)
    .Cursor = IIf(Modus, -4143, 2)
  End With
  
  If Modus Then
    With Err
      If .Number <> 0 Then
        MsgBox IIf(Erl, vbLf & "Fehler in Zeile:" & vbTab & Erl & vbLf & vbLf, "") & _
          "Fehlernummer:" & vbTab & .Number & vbLf & vbLf & "Beschreibung:" & vbLf & _
          .Description, vbExclamation, "Fehler"
      End If
      .Clear
    End With
  End If
End Sub



« Gruß Sepp »

Anzeige
AW: Tabelle nach Liste kopieren und eintragen
23.08.2011 23:07:16
lutz
Hallo Sepp,
ich bin schwer beeindruckt - klappt wie verrückt!!!
Vielen, vielen Dank und noch eine gute Nacht.
Viele Grüße Lutz

304 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige