Dateien öffnen und wieder schliessen

Guten Abend
In Zeile 3 (Spalte B bis L) stehen 10 Dateinamen (möglicherweise einige mehrmals), der Pfad (immer gleich) ist in einer Variable enthalten. Die Dateien sind möglicherweise offen, oder eben nicht.
Am Anfang des Subs sollen alle Dateien die geschlossen sind, geöffnet werden.
Anschliessend läuft der eigentliche Code ab (diverse Abfragen).
Dann möchte ich alle Dateien, die nicht offen waren, wieder schliessen - ohne zu speichern. Nicht klar ist mir, wie ich die Dateien in eine Variable schreibe, die durch den ablaufenden Code geöffnet werden.
Codestruktur
- alle Dateinamen aus B3 bis L3 überprüfen ob offen
- wenn nicht offen, Dateiname in Variable xyz schreiben, resp. diese mit weiterem Dateiamen ergänzen
- nachdem alle Dateien offen, eigentlicher Code ablaufen lassen (diverse Abfragen)
anschliessend
- alle Dateien, deren Name in Variable xyz gespeichert sind schliessen ohne zu speichern.
Meine Fragen:
- wie muss ich die Variable xyz dimensionieren
- wie weise ich die einzelnen Dateinamen zu
- wie arbeite ich die der Variable zugewiesenen Dateinamen ab
Danke für jeden Hinweis.
Gruss, Peter

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Peter,
das geht z. B. so.


Sub AufZu()
  Dim objWB As Workbook, objWBOpen As Workbook
  Dim rng As Range
  Dim vntOpen() As Variant
  Dim lngIndex As Long
  Dim strPath As String
  Dim bolOpen As Boolean
  
  strPath = "E:\Forum\"
  
  Redim vntOpen(0)
  
  For Each rng In ThisWorkbook.Sheets("Tabelle1").Range("B3:M3")  'Tabellenname anpassen
    If rng <> "" Then
      bolOpen = False
      If Dir(strPath & rng.Text, vbNormal) <> "" Then
        For Each objWB In Application.Workbooks
          If objWB.FullName = strPath & rng.Text Then
            bolOpen = True
            Exit For
          End If
        Next
        If Not bolOpen Then
          If IsError(Application.Match(strPath & rng.Text, vntOpen, 0)) Then
            Redim Preserve vntOpen(lngIndex)
            vntOpen(lngIndex) = strPath & rng.Text
            lngIndex = lngIndex + 1
            Workbooks.Open (strPath & rng.Text)
          End If
        End If
      End If
    End If
  Next
  
  'dein Code
  '...
  
  If lngIndex > 0 Then
    For Each objWB In Application.Workbooks
      If Not IsError(Application.Match(objWB.FullName, vntOpen, 0)) Then
        objWB.Close , False
      End If
    Next
  End If
  
End Sub

« Gruß Sepp »

Beliebteste Forumthreads (12 Monate)

Dateien öffnen und wieder schliessen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread