Autofilter per VBA aufheben

Hallo zusammen,
ich habe eine sehr große Excel-Datei 13mb, mit ca. 37000 Zeilen und 120 spalten.
Mittels VBA setze ich einen Autofilter um bestimmte Daten in dieser Tabelle auszulesen.
Tab2.Range("A2:DN37000").AutoFilter Field:=4, Criteria1:="Name"
das setzen des Autofilter und rausschreiben der Daten geht auch relativ schnell. Nur wenn ich den Autofilter wieder per VBA aufhebe, dauert dies extrem lange (länger als 1min) man bekommt schon das Gefühl das Excel sich aufgehängt hat.
Zum Aufheben verwende ich folgenden Befehl:
Tab2.Range("A2:DN37000" & LZ).AutoFilter
zusätzlich befindet sich zu begin des Codes folgendes um den Durchlauf zu beschleunigen:
Application.ScreenUpdating = False
Application.Calculation = xlManual
Hat jemand von euch evtl. eine Idee wieso das im VBA so lange dauert den Filter wieder aufzuheben und ob es vielleicht eine Lösung gibt, das irgendwie noch zu beschleunigen?
Danke & Gruss
Dennis

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo,
weiß jetzt nicht ob es bei Deiner Tabelle hilft, ein Versuch ist es aber wert.
Versuch mal und sortiere zuerst die Tabelle mit einer Hilfsspalte,
zusammenhängende Bereiche kann Excel besser verwalten.
Beispiel:


Sub AutoFilterSetze()
Dim iCalc%, ColHilfsSpalte As Range
Dim strFilterCrit$, lngFilterSpalte&

strFilterCrit = "Name"
lngFilterSpalte = 4

With Application
    iCalc = .Calculation
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False
    
    With Tab2.Range("A2:DN37000")
        With .EntireRow
            Set ColHilfsSpalte = .Columns(.Columns.Count)
            ColHilfsSpalte.FormulaR1C1 = "=RC" & lngFilterSpalte & "=""" & strFilterCrit & """"
            .Sort Key1:=ColHilfsSpalte.Cells(1, 1), Order1:=xlDescending, Header:=xlYes
        End With
        
        .AutoFilter Field:=lngFilterSpalte, Criteria1:=strFilterCrit
        
        ColHilfsSpalte.EntireColumn.Delete
    End With
  
    .Calculation = iCalc
    .ScreenUpdating = True
    .EnableEvents = True
End With
End Sub

Sub AutoFilterAufheben()
Dim iCalc%
If Tab2.FilterMode Then
    With Application
        iCalc = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    
         Tab2.ShowAllData
        
        .Calculation = iCalc
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End If
End Sub

Gruß Tino

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

301 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Autofilter per VBA aufheben

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

301 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread