Microsoft Excel

Herbers Excel/VBA-Archiv

Datum ohne WE und Feiertage - Nachtrag | Herbers Excel-Forum


Betrifft: Datum ohne WE und Feiertage - Nachtrag von: Andreas
Geschrieben am: 02.01.2012 16:12:16

Hallo Excelprofis!

Mit Hilfe des nachfolgenden Codes, den ich mit freundlicher Hilfe dieses Forums bekommen habe, erstelle ich Tabellenblätter mit fortlaufendem Datum ohne Wochenenden und Feiertage. Dies funktioniert auch super.
Nun muß ich aber auch alle Mittwoche rausnehmen.

Kann mir Jemand sagen wie der veränderte Code aussehen muß.

{=Termin!A1+KKLEINSTE(WENN((WOCHENTAG(Termin!A1+(ZEILE(INDIREKT("1:"&1*9))-1))<6)*ISTNV(VERGLEICH(Termin!A1+(ZEILE(INDIREKT("1:"&1*9)));Termin!$I$1:Termin!$I$12;0));ZEILE(INDIREKT("1:"&1*9)));1)}

Danke für die Hilfe!

mfg, Andreas

  

Betrifft: BeiSpielMappe? von: Erich G.
Geschrieben am: 02.01.2012 16:55:07

Hi Andreas,
mit einer BeiSpielMappe wäre das sicher einfacher.

Deine Formel (nicht Code) scheint mir etwas 'suboptimal' zu sein.
Termin!$I$1:$I$12 wäre einfacher als
Termin!$I$1:Termin!$I$12

Warum steht in der Formel einige Male
ZEILE(INDIREKT("1:"&1*9))
und nicht
ZEILE(INDIREKT("1:9"))
oder kürzer
ZEILE($1:$9)
Wofür wird da x-mal 1*9 gerechnet?

Du schribest, dass du dei Formel hier im Forum bekommen hast.
Vielleicht könntest du einen Link auf den alten Thread
im Archiv posten, in dem du die Formel bekommen hast.
Wenn nicht, wäre es wohl auch die Angabe hilfreich, wann diese alte Anfrage war.

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich


  

Betrifft: ...denn deine Fml scheint auch im Original ... von: Luc:-?
Geschrieben am: 02.01.2012 17:14:16

…suboptimal zu sein, Andreas,
oder ist die Datumswiederholung beim FmlZiehen Absicht oder unwirksam in deiner Tab?
Gutes Neues, Luc :-?


  

Betrifft: AW: ...denn deine Fml scheint auch im Original ... von: Andreas
Geschrieben am: 02.01.2012 17:31:47

Hallo Erich!

Datumswiederholung? Ich ändere das Datum in der Zelle A1 im Blatt Termin und das Datum wird dann in 20 weiteren Blättern in der gleichen Zelle geändert.

mfg, Andreas


  

Betrifft: AW: BeiSpielMappe? von: Andreas
Geschrieben am: 02.01.2012 17:27:23

Hallo Erich!

Kann die ursprüngliche Formel nicht mehr finden, da ich diese aus einem anderen Thread genommen habe.
Leider habe ich zu wenig Ahnung um zu sagen warum, was, wie berechnet wird.

Habe jetzt die Formel von Josef probiert und allses funktioniert.

Danke für die schnelle Antwort.

mfg, Andreas


  

Betrifft: AW: Datum ohne WE und Feiertage - Nachtrag von: Josef Ehrensberger
Geschrieben am: 02.01.2012 17:01:36


Hallo Andreas,

so vielleicht.

{=Termin!A1+KKLEINSTE(WENN((WOCHENTAG(Termin!A1+(ZEILE(INDIREKT("1:"&1*9))-1))<6) *(WOCHENTAG(Termin!A1+(ZEILE(INDIREKT("1:"&1*9))-1))<>3) *ISTNV(VERGLEICH(Termin!A1+(ZEILE(INDIREKT("1:"&1*9)));Termin!$I$1:Termin!$I$12;0)); ZEILE(INDIREKT("1:"&1*9)));1) }




« Gruß Sepp »



  

Betrifft: AW: Datum ohne WE und Feiertage - Nachtrag von: Andreas
Geschrieben am: 02.01.2012 17:23:45

Hallo!

Danke für die Hilfe! Funktioniert super.

mfg, Andreas


  

Betrifft: Formel etwas "bereinigt" von: Josef Ehrensberger
Geschrieben am: 02.01.2012 17:46:23


Hallo Andreas,

=Termin!A1+KKLEINSTE(WENN((WOCHENTAG(Termin!A1+ZEILE($1:$9);2)<6) *(WOCHENTAG(Termin!A1+ZEILE($1:$9);2)<>3)*ISTNV(VERGLEICH(Termin!A1+ZEILE($1:$9); Termin!$I$1:$I$12;0));ZEILE($1:$9));1)




« Gruß Sepp »



  

Betrifft: AW: Formel etwas "bereinigt" von: Andreas
Geschrieben am: 02.01.2012 17:53:38

Hallo!

Vielen Dank für die Hilfe.

mfg, Andreas


  

Betrifft: nochmal verkürzt von: Josef Ehrensberger
Geschrieben am: 02.01.2012 17:54:00

{=Termin!A1+KKLEINSTE(WENN((ISTZAHL(VERGLEICH(REST(Termin!A1+ZEILE($1:$9);7);{2;3;5;6};0))) *ISTNV(VERGLEICH(Termin!A1+ZEILE($1:$9);Termin!$I$1:$I$12;0));ZEILE($1:$9));1) }

« Gruß Sepp »



  

Betrifft: AW: nochmal verkürzt von: Andreas
Geschrieben am: 02.01.2012 19:53:05

Hallo Sepp!

Danke für die Mühe und Hilfe!

mfg, Andreas


  

Betrifft: ein paar Zeichen gehen noch;-)) von: Josef Ehrensberger
Geschrieben am: 02.01.2012 20:08:42

{=Termin!A1+MIN(WENN(ISTZAHL(VERGLEICH(REST(Termin!A1+ZEILE($1:$9);7);{2;3;5;6};0)) *ISTNV(VERGLEICH(Termin!A1+ZEILE($1:$9);Termin!$I$1:$I$12;0));ZEILE($1:$9))) }

« Gruß Sepp »



Beiträge aus den Excel-Beispielen zum Thema "Datum ohne WE und Feiertage - Nachtrag"