Microsoft Excel

Herbers Excel/VBA-Archiv

Formatierung übernehmen und zusammenführen | Herbers Excel-Forum


Betrifft: Formatierung übernehmen und zusammenführen von: onkelbobby
Geschrieben am: 02.08.2012 13:17:31

Hi,

habe in Spalte I vereinzelten Text stehen, der rot markiert und fett gedruckt wird.

Diesen Text möchte ich in Spalte H (in gleicher Formatierung) stehen haben, jedoch verbunden mit dem Text, der bereits in dieser Spalte H steht.

Also Beispiel: Zelle H5 = "Hallo", Zelle I5 = "Super"
Zelle H5 (neu) = "Hallo Super", wobei Text aus I5 fett und rot ist und auch in H5 so erscheinen soll, der Text aus H5 ("Hallo") soll weiterhin "normal" formatiert sein.

Mit diesem Code habe ich die Spalte I formatiert und danach H und I zusammengeführt.

Sub Farb()

Dim Zelle As Range
For Each Zelle In Sheets("Laufliste").Range("I5:I1000")
    Zelle.Font.ColorIndex = 3
    Zelle.Font.Bold = True
Next Zelle
With Sheets("Laufliste")
Dim t As Long
For t = 5 To Sheets("Laufliste").Cells(Sheets("Laufliste").Rows.Count, 1).End(xlUp).Row
Cells(t, "H").Value = Cells(t, "H").Value & " " & Cells(t, "I").Value
Next t
End With
End Sub

Formatierung von I verschwindet aber.

Wie löse ich das?

Danke!

Robert

  

Betrifft: AW: Formatierung übernehmen und zusammenführen von: Rudi Maintaire
Geschrieben am: 02.08.2012 13:35:51

Hallo,

Sub Farb()

  Dim t As Long, sTextH As String, sTextI As String
  
  With Sheets("Laufliste")
    For t = 5 To .Cells(.Rows.Count, 1).End(xlUp).Row
      With .Cells(t, 8)
        sTextH = .Value
        sTextI = .Offset(, 1)
        .Value = sTextH & " " & sTextI
        With .Characters(Len(sTextH) + 2, Len(sTextI)).Font
          .ColorIndex = 3
          .Bold = True
        End With
      End With
    Next t
  End With

End Sub

Gruß
Rudi


  

Betrifft: AW: Formatierung übernehmen und zusammenführen von: onkelbobby
Geschrieben am: 02.08.2012 13:54:33

Danke!

Klappt perfekt!

Robert


Beiträge aus den Excel-Beispielen zum Thema "Formatierung übernehmen und zusammenführen"