Microsoft Excel

Herbers Excel/VBA-Archiv

Werte nur in Markierten Zellen ändern | Herbers Excel-Forum


Betrifft: Werte nur in Markierten Zellen ändern von: Valeri
Geschrieben am: 13.08.2012 08:45:38

Hallo ihr Allwissenden,

mit folgendem Code ändere ich markierte Zellen:

Sub Zelle_Urlaub_rot()
Application.ScreenUpdating = False
    Dim c As Range

    For Each c In Selection
    If Not (IsEmpty(c)) Then
        c.FormulaR1C1 = "U"
        c.Interior.Color = 255
    End If
Next c
Application.ScreenUpdating = True
End Sub
Wie kann dieser Code so umgeschrieben werden, das nur Zellen geändert werden deren Inhalt grösser "" ist?

Gruß Valeri

  

Betrifft: AW: Werte nur in Markierten Zellen ändern von: Josef Ehrensberger
Geschrieben am: 13.08.2012 08:49:38


Hallo Valeri,

Sub Zelle_Urlaub_rot()
  Dim rng As Range
  
  On Error Resume Next
  Set rng = Selection.SpecialCells(xlCellTypeConstants)
  On Error GoTo 0
  
  If Not rng Is Nothing Then
    With rng
      .Value = "U"
      .Interior.Color = 255
    End With
  End If
  
  Set rng = Nothing
End Sub




« Gruß Sepp »



  

Betrifft: AW: Werte nur in Markierten Zellen ändern von: Valeri
Geschrieben am: 13.08.2012 08:56:40

Hallo Josef,

funktioniert einwandfrei!

Supper! Vielen Dank!

Gruß Valeri


  

Betrifft: AW: Werte nur in Markierten Zellen ändern von: Valeri
Geschrieben am: 13.08.2012 09:21:03

Hallo Josef,

ich habe vorhin festgestellt dass wenn nur eine Zelle angewählt ist beim ausführen einmal die komplette Tabelle in "U" und Rot umschrieben wird!

Gedankenfehler?

Gruß Valeri


  

Betrifft: AW: Werte nur in Markierten Zellen ändern von: Josef Ehrensberger
Geschrieben am: 13.08.2012 09:29:23


Hallo Valeri,

kein Gedankenfehler, aber SpecialCells() ist manchmal etwas eigenartig;-))

Sub Zelle_Urlaub_rot()
  Dim rng As Range
  
  On Error Resume Next
  Set rng = Intersect(Selection, Cells.SpecialCells(xlCellTypeConstants))
  On Error GoTo 0
  
  If Not rng Is Nothing Then
    With rng
      .Value = "U"
      .Interior.Color = 255
    End With
  End If
  
  Set rng = Nothing
End Sub






« Gruß Sepp »



  

Betrifft: AW: Werte nur in Markierten Zellen ändern von: Valeri
Geschrieben am: 13.08.2012 10:51:50

Danke Josef!

Scheint zu gehen!

Gruß Valeri


Beiträge aus den Excel-Beispielen zum Thema "Werte nur in Markierten Zellen ändern"