Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema InputBox
BildScreenshot zu InputBox InputBox-Seite mit Beispielarbeitsmappe aufrufen

Musseingabe VBA Schleife | Herbers Excel-Forum


Betrifft: Musseingabe VBA Schleife von: rene
Geschrieben am: 20.08.2012 18:42:01

Hallo zusammen,

Bräuchte wieder mal eure Hilfe ,hab hier schon etwas gefunden was mir weitergeholfen hat ,Habe daraus einen Code gebastelt ,aber ne Kleinigkeit fehlt noch. wie können mehrere Kriterien abgefragt werden ,zusätzlich zur" Bestellnummer "zB "Rechnung"(ActiveWorkbook.Sheets("Tabelle1").Cells(3, 1).Value und "Flughafen",)ActiveWorkbook.Sheets("Tabelle1").Cells(4, 1).Value,

hier ein Beispielcode

Private Sub Workbook_Open()
Range("A1:A2").Select
Selection.ClearContents
Dim titel As String
titel = "Bestellnummer "
Do
Eingabe = InputBox("Bitte unbedingt die Bestellnummer eingeben!", titel)
If Trim(Eingabe) = "" Then
titel = "Bestellnummer"
Else
ActiveWorkbook.Sheets("Tabelle1").Cells(2, 1).Value = Eingabe
Exit Do
End If
Loop
End Sub
Danke im voraus

Rene

  

Betrifft: AW: Musseingabe VBA Schleife von: Hajo_Zi
Geschrieben am: 20.08.2012 19:11:34

Hallo Rene,

Option Explicit

Private Sub Workbook_Open()
    Range("A1:A2").ClearContents
    Dim Eingabe As String
    Do
        Eingabe = InputBox("Bitte unbedingt die Bestellnummer eingeben!", "Bestellnummer ")
        If Trim(Eingabe) <> "" Then
            ActiveWorkbook.Sheets("Tabelle1").Cells(2, 1).Value = Eingabe
            Exit Do
        End If
    Loop
    Do
        Eingabe = InputBox("Bitte unbedingt die Rechnungsnummer eingeben!", "Rechnung")
        If Trim(Eingabe) <> "" Then
            ActiveWorkbook.Sheets("Tabelle1").Cells(3, 1).Value = Eingabe
            Exit Do
        End If
    Loop
End Sub
Gruß Hajo


  

Betrifft: AW: Musseingabe VBA Schleife von: Hajo_Zi
Geschrieben am: 20.08.2012 19:27:47

Hallo Rene,

oder mit einer Do Schleife.

Option Explicit

Private Sub Workbook_Open()
    Range("A1:A2").ClearContents
    Dim Eingabe As String
    Dim InI As Integer
    Do
        InI = 0
        If ActiveWorkbook.Sheets("Tabelle1").Cells(2, 1) = "" Then
            Eingabe = InputBox("Bitte unbedingt die Bestellnummer eingeben!", "Bestellnummer ")
            If Trim(Eingabe) <> "" Then
                ActiveWorkbook.Sheets("Tabelle1").Cells(2, 1).Value = Eingabe
                InI = InI + 1
            End If
        Else
            InI = InI + 1
        End If
        If ActiveWorkbook.Sheets("Tabelle1").Cells(3, 1) = "" Then
            Eingabe = InputBox("Bitte unbedingt die Rechnungsnummer eingeben!", "Rechnung")
            If Trim(Eingabe) <> "" Then
                ActiveWorkbook.Sheets("Tabelle1").Cells(3, 1).Value = Eingabe
                InI = InI + 1
            End If
        Else
            InI = InI + 1
        End If
        If InI = 2 Then Exit Do
    Loop
End Sub
Gruß Hajo


  

Betrifft: AW: Musseingabe VBA Schleife von: fcs
Geschrieben am: 21.08.2012 07:24:15

Hallo Rene,

hier noch eine kleine Variante

Gruß
Franz

Private Sub Workbook_Open()
 Range("A1:A2").Select
 Selection.ClearContents
 With ActiveWorkbook.Sheets("Tabelle1")
    .Cells(2, 1).Value = MussEingabe("Bitte unbedingt die Bestellnummer eingeben!", _
        "Bestellnummer")
    .Cells(3, 1).Value = MussEingabe("Bitte unbedingt die Rechnung eingeben!", "Rechnung")
    .Cells(4, 1).Value = MussEingabe("Bitte unbedingt die Flughafen eingeben!", "Flughafen")
 End With
End Sub

Function MussEingabe(ByVal strPrompt As String, ByVal strTitel As String) As String
 Do
    MussEingabe = InputBox(strPrompt, strTitel)
 Loop Until Trim(MussEingabe) <> ""
End Function



Beiträge aus den Excel-Beispielen zum Thema "Musseingabe VBA Schleife "