Zellen nach unterschiedlichen Werten durchsuchen

Forumthread: Zellen nach unterschiedlichen Werten durchsuchen

20.12.2012 19:57:48

alej

Hallo zusammen,
ich habe eine Tabelle (Bsp. Tabelle 1)
Deb-Nr. Name OP Buch.-Dat. usw
10021
10021
10045
34567
10045
12556
in einer zweiten Tabelle habe ich wieder eine Liste mit Debitorennummern (Bsp. Tabelle 2)
10021
10045
10001
10002
usw.
Wie ich eine Zeile nach einem bestimmten Inhalt z.B. 10021 durchsuche und dann kopiere habe ich an hand von Beispielen rausgefunden. Wie bekomme ich es aber hin, das die Tabelle 2 als Referenz für die Suche genommen wird
wenn tabelle2.wertX = tabelle1.wertX
dann kopiere tabelle1.reiheX
nach tabelle3.reiheX
usw.
Am Ende sollen in Tabelle 3 nur die Reihen "stehen", die auch in Tabelle 2 vorkommen
Grüße
alej

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zellen nach unterschiedlichen Werten durchsuchen

20.12.2012 23:48:29

fcs

hallo alej,
das Grundgerüst für solch eine Kopieraktion mit Prüfung in einem 2. Blatt sieht wie folgt aus.
Gruß
Franz

Sub Kopieren_Nach_Tabelle3()
Dim wksQuelle As Worksheet, wksZiel As Worksheet, wksVergleich As Worksheet
Dim varDebNr As Variant
Dim Zeile_Q As Long, Zeile_Z As Long
Dim rngZelle As Range, rngVergleich As Range
Set wksQuelle = ActiveWorkbook.Worksheets(1)
Set wksVergleich = ActiveWorkbook.Worksheets(2)
Set wksZiel = ActiveWorkbook.Worksheets(3)
With wksVergleich
'Zellbereich mit den Debitorennummern im Vergleichsblatt in Spalte A
Set rngVergleich = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
End With
With wksZiel
'letzte Zeile mit Daten in Spalte A der Zieltabelle
Zeile_Z = .Cells(.Rows.Count, 1).End(xlUp).Row
End With
With wksQuelle
For Zeile_Q = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
varDebNr = .Cells(Zeile_Q, 1).Value
'Debitorennummer im Vergleichsblatt suchen
Set rngZelle = rngVergleich.Find(What:=varDebNr, LookIn:=xlValues, lookat:=xlWhole)
If Not rngZelle Is Nothing Then
Zeile_Z = Zeile_Z + 1
.Rows(Zeile_Q).Copy Destination:=wksZiel.Rows(Zeile_Z)
End If
Next Zeile_Q
End With 'wksQuelle
End Sub

AW: Zellen nach unterschiedlichen Werten durchsuchen

21.12.2012 00:05:25

Ass

Hallo alej

Option Explicit
Sub alej()
Dim w_Tab1 As Worksheet, w_Tab2 As Worksheet, w_Tab3 As Worksheet
Dim arInput, arVergleich, arOutput
Dim i&, j&, k&, l&
Set w_Tab1 = Worksheets("Tabelle1")
Set w_Tab2 = Worksheets("Tabelle2")
Set w_Tab3 = Worksheets("Tabelle3")
arInput = w_Tab1.Range("b2").CurrentRegion
arVergleich = w_Tab2.Range("a1").CurrentRegion
ReDim arOutput(1 To UBound(arInput), 1 To UBound(arInput, 2))
For i = 1 To UBound(arVergleich)
For j = 1 To UBound(arInput)
If arInput(j, 1) = arVergleich(i, 1) Then
k = k + 1
For l = 1 To UBound(arInput, 2)
arOutput(k, l) = arInput(j, l)
Next
End If
Next
Next
w_Tab3.Range("A1").Resize(UBound(arOutput, 1), UBound(arOutput, 2)) = arOutput
End Sub

Gruß
Rudi

Beliebteste Forumthreads (12 Monate)

Zellen nach unterschiedlichen Werten durchsuchen

Forumthread: Zellen nach unterschiedlichen Werten durchsuchen

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Zellen nach unterschiedlichen Werten durchsuchen

Forumthread: Zellen nach unterschiedlichen Werten durchsuchen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread