Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1292to1296
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Daten ins Archiv übertragen & sortieren
17.01.2013 13:41:31
Jasper
Hallo liebe Excel-Profis,
da VBA ein rotes Tuch für mich ist, ich im Forum zwar so einige VBA-Bausteine finde, diese aber nicht für meine Wünsche umsetzten kann, wende ich mich erneut an Euch.
Problem:
Im Blatt „Seite2“ stehen Datum&Namen, aber auch leere Zeilen, die aus Blatt „Seite1“ zusammengestellt werden.
Diese mögen so gerne sortiert ins Blatt „Archiv X“.
Doch sie wollen nicht so recht…..
Welcher Sportsmann kann helfen?
Mit einem großen Dankeschön im Voraus.
Jasper
https://www.herber.de/bbs/user/83455.xlsx

11
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Daten ins Archiv übertragen & sortieren
17.01.2013 14:27:56
Klaus
Hi Jasper,
dein Musterblatt macht leider ziemlich viel Bahnhof. Bitte präzisier nochmal deine Anforderungen.
Denk dran, nur du weisst was das ganze erreichen soll. Was für dich Selbstverständlich scheint, müssen wir mühsam erraten.
Das Blatt ist geschützt.
ist es nicht.
Marko über [Strg] & [Shift] & [X]
da ist kein Makro
Hier die Namen suchen
WO die Namen suchen? In Zelle B4?
und das neue Datum
Sowohl im "Seite 1" als auch in "Seite 2" stehen mehrere Namen und Datums. Was davon ist denn "das neue Datum"?
rechts neben dem letzten Datum der Reihe nach eintragen.
Kein Problem!
Und sortieren ? Ja, geht das denn?
Hmmmm .... die Datums sind Horizontal ausgerichtet. Sortiert wird vetikal. Natürlich KÖNNTE man die Zeilen jeweils auslesen, in ein Array schreiben, das Array sortieren und dann das Array zurück schreiben. Oder du transponierst die Tabelle (Namen Horizontal, Datums vertikal)
Bei neuen Namen, den Namen unten ansetzen und das Datum zuordnen.
Wo werden neue Namen gesucht?
Und sortieren ?
siehe oben
Fehlt auf Seite 2 beim Namen das Datum oder beim Datum der Namen, darf Excel ordentlich schimpfen…kein Problem
Grüße,
Klaus M.vdT.

Anzeige
AW: Daten ins Archiv übertragen & sortieren
17.01.2013 15:34:47
Jasper
Hallo Klaus,
danke für die schnelle Antwort.
-ups… hoffe, dass ich jetzt alle Infos zusammen habe.
-Kennwort „Sport“
-Marko ist da.
-Archiv ist umgebaut.
Mit neuem Datum & suchen sind die Daten aus „Seite 2 E7:D32“ gemeint.
Bekannte Namen, die schon im Archiv stehen, sollten erkannt werden.
Unbekannte, neue Namen, der Reihe nach einsortieren. A-Z ist dabei egal.
Ein bereits im Archiv bekanntes Datum bei einem bereits archivierten Namen, sollte zu einem „Schimpfen“ führen. Doppelte Datums je Spalte sind nicht möglich.
Ein Datum können sich mehrere teilen, aber beim Namen sind keine doppelten Datums möglich.
Danke und Grüße
Jasper
https://www.herber.de/bbs/user/83457.xlsm

Anzeige
Teilantwort
17.01.2013 16:03:22
Klaus
Hi Jasper,
eine Teilantwort, weil ich heute keine Zeit mehr hab. Ich lass aber offen, vielleicht vervollständigt ja jemand anders.
Gelöst:
-Namen durchgehen
-Namen ins Archiv eintragen, falls sie fehlen
-Datümer ins Archiv passend zu den Namen eintragen
-meckern wenn ein Datum fehlt
noch offen:
-meckern wenn ein Name fehlt
-Datums-Einträge sortieren
-Zellformatierungen auf Datum setzen im Makro
-Fehlerbehandlungsroutine
Sub Makro1()
' Makro1 Makro
' Tastenkombination: Strg+Umschalt+X
'   ################### FÜR MICH EIN ROTES TUCH (...)  1000x :-) :-) :-) :-)   ################# _
'   Das wird alles!
HoleNamen
End Sub
Sub HoleNamen()
Dim lRowFirstName As Long
Dim lRowNameArchiv As Long
Dim iColNames As Integer
Dim iColDates As Integer
Dim wksData As Worksheet
Dim wksArchive As Worksheet
'HIER musst du ein paar Sachen deklarieren, falls deine Mastertabelle abweicht
lRowFirstName = 7                   'Namen stehen ab Zeile 7
iColNames = 5                       'Namen stehen in Spalte 5 (=D)
iColDates = 4                       'Datums stehen in Spalte 4 (=E)
lRowNameArchiv = 8                  'im Archiv stehen die Namen in Zeile 8
Set wksData = Sheets("Seite2")      'Tabellenname
Set wksArchive = Sheets("Archiv X") 'Tabellenname
Dim rNames As Range
Dim lRowLastName As Long
Dim iColLast As Integer
Dim lRowLast
With wksData
lRowLastName = .Cells(Rows.Count, iColNames).End(xlUp).Row  'lezte Zeile automatisch
'jeden Namen einzeln durchgehen
For Each rNames In .Range(.Cells(lRowFirstName, iColNames), .Cells(lRowLastName, iColNames)) _
'prüfe ob leer
If rNames.Value = "" Then
'prüfe ob auch das Datum fehlt
If .Cells(rNames.Row, iColDates).Value = "" Then
'wenn beides fehlt, nix! (aber auch kein Datum eintragen)
GoTo skipit
Else
'sonst meckern und diesen überspringen
MsgBox ("Da fehlt ein Datum!!")
GoTo skipit
End If
End If
'gibt es den Namen schon im Archiv?
If Application.WorksheetFunction.CountIf(wksArchive.Cells(lRowNameArchiv, 1).EntireRow,  _
rNames.Value) = 1 Then
'Namen gibts schon, mache nix
Else
'Name fehlt, Name nachtragen
iColLast = wksArchive.Cells(lRowNameArchiv, Columns.Count).End(xlToLeft).Column + 1
wksArchive.Cells(lRowNameArchiv, iColLast).Value = rNames.Value
End If
'Datum eintragen (den Namen gibt es ja jetzt)
iColLast = Application.WorksheetFunction.Match(rNames.Value, wksArchive.Cells( _
lRowNameArchiv, 1).EntireRow, False)
lRowLast = wksArchive.Cells(Rows.Count, iColLast).End(xlUp).Row + 1
wksArchive.Cells(lRowLast, iColLast).Value = .Cells(rNames.Row, iColDates)
skipit:
Next rNames
End With
Ich hoffe das hilft schon mal etwas.
Grüße und bis morgen,
Klaus M.vdT.

Anzeige
AW: Teilantwort
17.01.2013 16:12:36
Jasper
Ich freue mich auf morgen ! ! ! ! :-)

AW: komplette Antwort
18.01.2013 08:50:26
Klaus
Hi Jasper,
-Blattschutz setzen, Passwort "Sport"
erledigt
-Zellformatierungen auf Datum setzen im Makro
Egal: Zellen direkt im Sheet als Datum formatiert. Gleiches Ergebnis, weniger Code.
-meckern wenn ein Name fehlt
erledigt. Fehler (Datum oder Name fehlt) werden gesammelt am Ende ausgebeben (kein MsgBox-Clickwettbewerb mehr wie in der ersten Version).
Die Fehl-Felder zeige ich in eine Messagebox, aber daraus kannst du den Text nicht kopieren. Auf ein Post-It abschreiben geht aber gar nicht in Zeiten von Excel :-) darum schreibe ich die Fehl-Zellen auch "unsichtbar" in das Direktfenster (debug.print). Kannst du dir dann von dort wegkopieren. Wenn du das ganze lieber in der Tabelle hättest, gibts du kurz laut.
Ausserdem habe ich das hässliche GoTo entfernt und durch eine Wächtervariable ersetzt (Effekt = keiner, aber die Programmierung ist so etwas eleganter. GoTo gilt als "dirty trick".)
-Datums-Einträge sortieren
check
-Fehlerbehandlungsroutine
bin ich jetzt zu faul zu :-) Sieh zu, dass in den Zellen keine Fehlermedlungen wie #NV! stehen.
Hier das neue Makro zum kopieren:
Sub Makro1()
' Makro1 Makro
' Tastenkombination: Strg+Umschalt+X
HoleNamen
End Sub
Sub HoleNamen()
'### Holt eventuell fehlende Namen aus anderer Tabelle ins Archiv,
'### schreibt die entsprechenden Datümer zu den Namen
Dim lRowFirstName As Long
Dim lRowNameArchiv As Long
Dim iColNames As Integer
Dim iColDates As Integer
Dim wksData As Worksheet
Dim wksArchiv As Worksheet
'HIER musst du ein paar Sachen deklarieren, falls deine Mastertabelle abweicht
lRowFirstName = 7                   'Namen stehen ab Zeile 7
iColNames = 5                       'Namen stehen in Spalte 5 (=D)
iColDates = 4                       'Datums stehen in Spalte 4 (=E)
lRowNameArchiv = 8                  'im Archiv stehen die Namen in Zeile 8
Set wksData = Sheets("Seite2")      'Tabellenname Quelle
Set wksArchiv = Sheets("Archiv X")  'Tabellenname Archiv
'Anmerkung: eigentlich gehören alle DIMs nach oben. Ich hab hier unten weiter
'Dimensioniert, um den oberen (händisch zu ändernden) Codeteil etwas übersichtlicher zu lassen.
Dim rNames As Range
Dim lRowLastName As Long
Dim iColLast As Integer
Dim lRowLast
Dim bDoIt As Boolean
Dim sMissDate As String
Dim sMissName As String
Dim bShowMiss As Boolean
sMissDate = "Da fehlt ein Datum!" & Chr(10)
sMissName = "Da fehlt ein Name!" & Chr(10)
bShowMiss = False 'Voreinstellung: keine Fehlermeldung
With wksData
'Blatt schützen mit Passwort. Wenn das Blatt schon geschützt ist,
'wird der Schutz trotzdem neu gesetzt. Userinterfaceonly(True) erlaubt VBA,
'trotz Blattschutz die Zellen zu ändern!
wksArchiv.Protect Password:="Sport", userinterfaceonly:=True
'lezte Zeile automatisch ermitteln
lRowLastName = .Cells(Rows.Count, iColNames).End(xlUp).Row
'jeden Namen einzeln durchgehen
For Each rNames In .Range(.Cells(lRowFirstName, iColNames), .Cells(lRowLastName, iColNames)) _
'Wächter setzen
bDoIt = True
'prüfe ob Name oder beide leer. Die Wächtervariable bDoIt verhindert dann,
'dass "Namen/Datum holen" ausgeführt wird.
'Wenn nur der Name fehlt, Fehlermeldung schreiben.
If rNames.Value = "" Then
'prüfe ob auch das Datum fehlt
If .Cells(rNames.Row, iColDates).Value = "" Then
'wenn beides fehlt, nix! (aber auch kein Datum eintragen)
bDoIt = False
Else
'sonst meckern und diesen überspringen
'sMissDate = sMissDate & rNames.Address & Chr(10)
sMissName = sMissName & rNames.Address & Chr(10)
bShowMiss = True 'Fehlermeldung am Ende zeigen
bDoIt = False
End If
Else
'prüfe ob nur das Datum fehlt, Fehlermeldung schreiben.
If .Cells(rNames.Row, iColDates).Value = "" Then
sMissDate = sMissDate & .Cells(rNames.Row, iColDates).Address
bShowMiss = True 'Fehlermeldung am Ende zeigen
bDoIt = False
End If
End If
If bDoIt Then
'gibt es den Namen schon im Archiv?
If Application.WorksheetFunction.CountIf(wksArchiv.Cells(lRowNameArchiv, 1). _
EntireRow, rNames.Value) = 1 Then
'Namen gibts schon, mache nix
Else
'Name fehlt, Name nachtragen
iColLast = wksArchiv.Cells(lRowNameArchiv, Columns.Count).End(xlToLeft).Column + _
1
wksArchiv.Cells(lRowNameArchiv, iColLast).Value = rNames.Value
End If
'Datum eintragen (den Namen gibt es ja jetzt)
iColLast = Application.WorksheetFunction.Match(rNames.Value, wksArchiv.Cells( _
lRowNameArchiv, 1).EntireRow, False)
lRowLast = wksArchiv.Cells(Rows.Count, iColLast).End(xlUp).Row + 1
wksArchiv.Cells(lRowLast, iColLast).Value = .Cells(rNames.Row, iColDates)
'aktive Spalte sortieren
Dim rSortRange As Range
With wksArchiv
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=.Range(.Cells(lRowNameArchiv + 1, iColLast), .Cells( _
lRowLast, iColLast)), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.SetRange Range(.Cells(lRowNameArchiv, iColLast), .Cells(lRowLast,  _
iColLast))
.Sort.Header = xlYes
.Sort.MatchCase = False
.Sort.Orientation = xlTopToBottom
.Sort.SortMethod = xlPinYin
.Sort.Apply
End With
End If
Next rNames
'falls Namen / Datümer fehlten, Fehlermeldung anzeigen
If bShowMiss Then
Debug.Print sMissDate
Debug.Print sMissName
MsgBox sMissDate & Chr(10) & Chr(10) & sMissName
End If
End With
End Sub
Was mich jetzt noch stören würde: Wenn ich das ganze laufen lasse, und dann das fehlende Datum / den fehlenden Namen nachtrage, und dann das ganze nochmal laufen lasse: dann verdoppeln sich alle Datümer, dies vorher schonmal gab, im Archiv.
Normalerweise würd ich einfach im Blatt "Seite2" die kopierten Namen / Datümer löschen, aber du hast in deinem Muster an dieser Stelle sicher nicht ohne Grund Verknüpfungen angegeben (sonst hätte ich die Daten ja direkt vom Blatt "Seite1" geholt). Nu kenn ich die Logik deiner Mastertabelle nicht und kann darum auch keinen Workaround entwickeln.
Intuitiv würd ich, bevor ein Datum eingetragen wird, prüfen ob es dieses Datum bei diesem Namen schon gibt im Archiv. Allerdings kann es ja auch sein, dass eine Datums-Doppelung erlaubt oder sogar erwünscht ist!
Grüße,
Klaus M.vdT.

Anzeige
ich poste immer zu schnell - kosmetische Korrektur
18.01.2013 09:04:51
Klaus
Hi Jasper,
Ich war etwas voreilig. Das Makro hat noch kosmetische Fehler.
Die Zeilen
'sMissDate = sMissDate & rNames.Address & Chr(10) (mit Hochkomma am Anfang!!!)
Dim rSortRange As Range
sind vom Entwickeln übrig geblieben, die kannst du löschen.
Die Zeile (diesmal ohne hochkomma, also die echte)
sMissDate = sMissDate & .Cells(rNames.Row, iColDates).Address
muss um einen weiteren Zeilenumbruch ergänzt werden, sonst ist die Fehlermeldung am Ende kaum lesbar
sMissDate = sMissDate & .Cells(rNames.Row, iColDates).Address & Chr(10)
Da oben ein Zeilenumbruch extra kommt, kann er unten wieder raus:
MsgBox sMissDate & Chr(10) & Chr(10) & sMissName
wird zu:
MsgBox sMissDate & Chr(10) & sMissName
und dann müsste alles schick sein.
Grüße,
Klaus M.vdT.

Anzeige
schönes Wochenende!
18.01.2013 10:52:45
Klaus
Hallo Jasper,
ich geh ins Wochenende. Wenn nochwas ist, antworte ich am Montag!
Grüße,
Klaus M.vdT.

AW: schönes Wochenende!
18.01.2013 20:14:04
Jasper
Hallo Klaus,
1000 Dank für die tolle Arbeit und besonders für die vielen Infos & Erklärungen, ich bin sehr beeindruckt.
Eine Kleinigkeit fehlt leider noch.
Es entstehen doppelte Datums, wenn beim entsprechenden Namen ein bereits bekanntes Datum erneut zugeordnet werden soll. Oder wenn man mehrmals das Makro aktiviert….
Je Spalte darf das Datum nur einmal auftauchen.
Eine Fehlermeldung ist nicht nötig. Ein überschreiben des Datums oder weglassen, da bereits vorhanden, würde ausreichen.
Allerdings wäre es schön wenn zu Anfang eine Sicherheitsabfrage kommen würde, die würde die größten Fehler ausmerzen. Es müsste eine Abfrage zum Monat/Jahr stattfinden.
Monat steht in „Archiv X“ A10, das Jahr in „Archiv X“ B10
Frage: „Ist Bearbeitungsmonat Moant“A10“und Jahr“B10“richtig?“
Ja =weiter / nein =Abbruch
Nochmals Danke, schönes Wochenende & Grüße
Jasper

Anzeige
überarbeitet!
21.01.2013 08:34:47
Klaus
Hi Jasper,
danke für die freundlichen Rückmeldungen!
Ich habe deine zwei Sonderwünsche noch eben eingebaut, ausserdem die kosmetischen Korrekturen aus meinem Thread weiter oben umgesetzt. Bei der Monat/Jahr MsgBox hab ichs mir einfach gemacht und den gesamten Code in eine "IF-MsgBox=Ja-Then" Schleife gepappt.
Option Explicit
Sub Makro1()
' Makro1 Makro
' Tastenkombination: Strg+Umschalt+X
HoleNamen
End Sub
Sub HoleNamen()
'### Holt eventuell fehlende Namen aus anderer Tabelle ins Archiv,
'### schreibt die entsprechenden Datümer zu den Namen
Dim lRowFirstName As Long
Dim lRowNameArchiv As Long
Dim iColNames As Integer
Dim iColDates As Integer
Dim wksData As Worksheet
Dim wksArchiv As Worksheet
'HIER musst du ein paar Sachen deklarieren, falls deine Mastertabelle abweicht
lRowFirstName = 7                   'Namen stehen ab Zeile 7
iColNames = 5                       'Namen stehen in Spalte 5 (=D)
iColDates = 4                       'Datums stehen in Spalte 4 (=E)
lRowNameArchiv = 8                  'im Archiv stehen die Namen in Zeile 8
Set wksData = Sheets("Seite2")      'Tabellenname Quelle
Set wksArchiv = Sheets("Archiv X")  'Tabellenname Archiv
'Prüfe ob Monat / Jahr korrekt. (MsgBox vbyesno = ja ergibt 6)
If MsgBox("Ist Bearbeitungsmonat Moant (sic!) " & wksArchiv.Range("A10").Value & " und Jahr " &  _
wksArchiv.Range("B10").Value & " richtig?", vbYesNo) = 6 Then
'Anmerkung: eigentlich gehören alle DIMs nach oben. Ich hab hier unten weiter
'Dimensioniert, um den oberen (händisch zu ändernden) Codeteil etwas übersichtlicher zu  _
lassen.
Dim rNames As Range
Dim lRowLastName As Long
Dim iColLast As Integer
Dim lRowLast
Dim bDoIt As Boolean
Dim sMissDate As String
Dim sMissName As String
Dim bShowMiss As Boolean
sMissDate = "Da fehlt ein Datum!" & Chr(10)
sMissName = "Da fehlt ein Name!" & Chr(10)
bShowMiss = False 'Voreinstellung: keine Fehlermeldung
With wksData
'Blatt schützen mit Passwort. Wenn das Blatt schon geschützt ist,
'wird der Schutz trotzdem neu gesetzt. Userinterfaceonly(True) erlaubt VBA,
'trotz Blattschutz die Zellen zu ändern!
wksArchiv.Protect Password:="Sport", userinterfaceonly:=True
'lezte Zeile automatisch ermitteln
lRowLastName = .Cells(Rows.Count, iColNames).End(xlUp).Row
'jeden Namen einzeln durchgehen
For Each rNames In .Range(.Cells(lRowFirstName, iColNames), .Cells(lRowLastName,  _
iColNames))
'Wächter setzen
bDoIt = True
'prüfe ob Name oder beide leer. Die Wächtervariable bDoIt verhindert dann,
'dass "Namen/Datum holen" ausgeführt wird.
'Wenn nur der Name fehlt, Fehlermeldung schreiben.
If rNames.Value = "" Then
'prüfe ob auch das Datum fehlt
If .Cells(rNames.Row, iColDates).Value = "" Then
'wenn beides fehlt, nix! (aber auch kein Datum eintragen)
bDoIt = False
Else
'sonst meckern und diesen überspringen
'sMissDate = sMissDate & rNames.Address & Chr(10)
sMissName = sMissName & rNames.Address & Chr(10)
bShowMiss = True 'Fehlermeldung am Ende zeigen
bDoIt = False
End If
Else
'prüfe ob nur das Datum fehlt, Fehlermeldung schreiben.
If .Cells(rNames.Row, iColDates).Value = "" Then
sMissDate = sMissDate & .Cells(rNames.Row, iColDates).Address & Chr(10)
bShowMiss = True 'Fehlermeldung am Ende zeigen
bDoIt = False
End If
End If
If bDoIt Then
'gibt es den Namen schon im Archiv?
If Application.WorksheetFunction.CountIf(wksArchiv.Cells(lRowNameArchiv, 1). _
EntireRow, rNames.Value) = 1 Then
'Namen gibts schon, mache nix
Else
'Name fehlt, Name nachtragen
iColLast = wksArchiv.Cells(lRowNameArchiv, Columns.Count).End(xlToLeft). _
Column + 1
wksArchiv.Cells(lRowNameArchiv, iColLast).Value = rNames.Value
End If
'Datum eintragen (den Namen gibt es ja jetzt)
iColLast = Application.WorksheetFunction.Match(rNames.Value, wksArchiv.Cells( _
lRowNameArchiv, 1).EntireRow, False)
lRowLast = wksArchiv.Cells(Rows.Count, iColLast).End(xlUp).Row + 1
'prüfe ob das Datum doppelt ist
If Application.WorksheetFunction.CountIf(wksArchiv.Range(wksArchiv.Cells( _
lRowNameArchiv + 1, iColLast), wksArchiv.Cells(lRowLast, iColLast)), .Cells(rNames.Row, iColDates)) = 0 Then
'wenn das Datum bisher 0-mal vorkommt, trage es ein.
wksArchiv.Cells(lRowLast, iColLast).Value = .Cells(rNames.Row, iColDates)
Else
'wenn das Datum bereits 1-mal vorkommt, mache nix.
'wenn es 2-mal vorkommt, ist irgendwas kaputt! Meckern! (dürfte nie  _
passieren)
If Application.WorksheetFunction.CountIf(wksArchiv.Range(wksArchiv.Cells( _
lRowNameArchiv + 1, iColLast), wksArchiv.Cells(lRowLast, iColLast)), .Cells(rNames.Row, iColDates)) >= 2 Then
MsgBox ("ACHTUNG! Ein Datum steht doppelt im Archiv! Bitte Einträge für  _
" & rNames.Value & " prüfen")
End If
End If
'aktive Spalte sortieren
Dim rSortRange As Range
With wksArchiv
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=.Range(.Cells(lRowNameArchiv + 1, iColLast), . _
Cells(lRowLast, iColLast)), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
.Sort.SetRange Range(.Cells(lRowNameArchiv, iColLast), .Cells(lRowLast,  _
iColLast))
.Sort.Header = xlYes
.Sort.MatchCase = False
.Sort.Orientation = xlTopToBottom
.Sort.SortMethod = xlPinYin
.Sort.Apply
End With
End If
Next rNames
'falls Namen / Datümer fehlten, Fehlermeldung anzeigen
If bShowMiss Then
Debug.Print sMissDate
Debug.Print sMissName
MsgBox sMissDate & Chr(10) & sMissName
End If
End With
End If 'MsgBox "Datum richtig?"
End Sub
Grüße,
Klaus M.vdT.

Anzeige
AW: überarbeitet!
21.01.2013 18:09:56
Jasper
Hallo Klaus
1000 Dank !
Eingebaut, umgebaut, angepasst, geprüft, für sehr gut befunden!!!
Perfekt ! Bin begeistert !
Super Forum, dank super Leute!
Grüße
Jasper

Danke für die Rückmeldung! owT.
22.01.2013 07:19:39
Klaus
,

155 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige