Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1336to1340
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Ausgabe mehrerer Treffer

Ausgabe mehrerer Treffer
22.11.2013 11:46:24
Natascha
Hallo ihr Lieben!
Habe mich die letzten Nachmittage durch etliche Beiträge und Internetseiten gequält, leider ohne Ergebnis, weshalb ich nun hier Hilfe erbitte.
Muss eigentlich eine völlig banale Lösung geben, nur leider komme ich nicht drauf.
Meine Ausgangstabelle beinhaltet im wesentlichen drei Spalten mit einer Person, Vater und Mutter, wobei die Person durch ein Geburtsdatum eindeutig ist und daher keine doppelten Personen vorkommen.
Im nächsten Register stehen nun die Personen in einer Spalte und in den weiteren Spalten sollen die Kinder aufgelistet werden. Durch die Ausgangsliste sollte es ja nicht so schwer sein, nur bringe ich bei den Formeln scheinbar ständig etwas durcheinander, weshalb das Ergebnis nicht stimmt.
https://www.herber.de/bbs/user/88209.xlsx
Vielen Dank schonmal für Eure Bemühungen.
Lg, Natascha

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Ausgabe mehrerer Treffer
23.11.2013 02:18:08
fcs
Hallo Natascha,
eine banale Lösung gibt es hier nicht, da SVERWEIS immer nur einen Namen liefern kann.
Kinder

 ABCDEFGH
2INDEXINDEXIDPersonKind 1Kind 2Kind 3 
3        
41_BJxxBurger Josef [x - x]    

Formeln der Tabelle
ZelleFormel
B4=SVERWEIS($A4;Gesamtliste!$A$4:$P$992;2;FALSCH)
C4=SVERWEIS($A4;Gesamtliste!$A$4:$P$992;3;FALSCH)
D4=SVERWEIS($A4;Gesamtliste!$A$4:$P$992;4;FALSCH)
E4{=WENNFEHLER(INDEX(Gesamtliste!$D$4:$D$15;KKLEINSTE(WENN(((Gesamtliste!$R$4:$R$15=$D4)+(Gesamtliste!$S$4:$S$15=$D4))>0;ZEILE(Gesamtliste!$D$4:$D$15); 999); SPALTE()-4)-3); "")}
F4{=WENNFEHLER(INDEX(Gesamtliste!$D$4:$D$15;KKLEINSTE(WENN(((Gesamtliste!$R$4:$R$15=$D4)+(Gesamtliste!$S$4:$S$15=$D4))>0;ZEILE(Gesamtliste!$D$4:$D$15); 999); SPALTE()-4)-3); "")}
G4{=WENNFEHLER(INDEX(Gesamtliste!$D$4:$D$15;KKLEINSTE(WENN(((Gesamtliste!$R$4:$R$15=$D4)+(Gesamtliste!$S$4:$S$15=$D4))>0;ZEILE(Gesamtliste!$D$4:$D$15); 999); SPALTE()-4)-3); "")}
H4{=WENNFEHLER(INDEX(Gesamtliste!$D$4:$D$15;KKLEINSTE(WENN(((Gesamtliste!$R$4:$R$15=$D4)+(Gesamtliste!$S$4:$S$15=$D4))>0;ZEILE(Gesamtliste!$D$4:$D$15); 999); SPALTE()-4)-3); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Die Formel in E4 kannst du nach rechts und nach unten kopieren.
Die Zeilennummer 15 in den Formeln muss du an die Zeilen in der Gesamtliste anpassen. ggf. auch die 999 wenn du 1000 oder mehr Zeilen hast.
Wenn du sehr viele Zeilen in der Gesamtliste hast, dann schlagen die Formeln, da rechenintensiv, voll auf die Berechnunszeiten der Tabelle durch.
Gruß
Franz

Anzeige
AW: Ausgabe mehrerer Treffer
25.11.2013 09:59:41
Natascha
Hallo Franz,
danke für die schnelle Antwort.
Könntest du die Formel vielleicht kurz erklären. Die innere Wennfunktion ist klar. Was sagen die Zahlen der Kkleinste (Spalte()-4) und Indexfunktion (-3) und die Apostrophe der Wennfehlerfunktion aus!?
Könnte man sich auch auf die Tabelle "Eltern" beziehen oder gibt Excel dann einen Zirkelbezug oder eine Fehler aus!?
Danke!
Lg, Natascha

AW: Ausgabe mehrerer Treffer
25.11.2013 13:19:58
fcs
Hallo Natascha,
die innere WENN-Funktion erzeugt eine Liste von Zeilennummern, da es sich hier um eine Matrix-Funktion handelt. Immer wenn die Person in Spalte D mit dem Namen des Vaters oder der Mutter in der Gesamtliste übereinstimmt, dann ist das Ergebnis die Nummer der Zeile, ansonsten 999.
Auf diese Liste wird jetzt die Funktion KKLEINSTE angewendet.
SPALTE()-4 berechnet, ob der erstkleinste, zweitkleinste, usw. Wert aus der Liste genommen werden soll; also die Zeile mit dem 1., 2., usw. Kind. Da die Formel für das 1. Kind in Spalte E (Nummer = 5) steht muss 4 subtrahiert werden, damit 1 rauskommt; bei den Spalten F, G, usw. ist das Ergebnis dann 2, 3, usw. für die weiteren Kinder.
In INDEX wird dann das Ergebnis von KKLEINSTE (= Zeilennummer von Kind) verarbeitet. Da die Zeilennummern ab der Zeile 1 ermittelt werden und der Bereich auf den sich INDEX bezieht in Zeile 4 beginnt, muss von der Zeilennummer noch 3 subtrahiert werden, damit die Zeilenzählung innerhabl des INDEX-Bereiches stimmt.
Mit WENNFEHLER kannst du ein bestimmtes Ergebnis anzeigen lassen, wenn in der eigentlichen Formel ein Fehler auftritt. Das ist in deinem Fall hier immer dann der Fall, wenn KKLEINSTE als Ergebnis 999 auspuckt weil der INDEX-Bereich weniger als 999 Zeilen hat. "" scheint mir hier ein sinnvolles Ergebnis. In der Spalte E könte man natürlich auch "keine Kinder" als Fehlerergebnis anzeigen.
Gruß
Franz
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige