Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1368to1372
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Interntet IE öffnen mit 50% Zoom

Interntet IE öffnen mit 50% Zoom
14.07.2014 09:50:20
Michael
Hallo!
Wie bekomme ich die Internetseite mit Zoom 50% geöffnet?
Nach der Bearbeitung soll er wieder auf 100% zurück?
(Seit Windows 8.1 übernimmt er nur noch die Daten, die zu sehen sind! Der Rest ist verschwunden. Codeschnipsel aus herberts Forum)
  • Private Sub CopyHtmlToClipboard(wwwAdress As String)
    Dim appIE As Object
    Set appIE = CreateObject("InternetExplorer.Application")
    appIE.navigate wwwAdress
    appIE.Visible = True ' True sichtbar  ; mit false hier läuft es im Hintergrund
    '  appIE.Zoom = 50
    If Application.Wait(Now + TimeValue("0:00:15")) Then
    Do: Loop Until appIE.Busy = False
    appIE.ExecWb 17, 0 'Select All
    Do: Loop Until appIE.Busy = False
    appIE.ExecWb 12, 0 'Copy
    Do: Loop Until appIE.Busy = False
    ' appIE.Zoom = 100
    appIE.Application.Quit
    Set appIE = Nothing
    End If
    End Sub
    


  • 5
    Beiträge zum Forumthread
    Beiträge zu diesem Forumthread

    Betreff
    Datum
    Anwender
    Anzeige
    AW: Interntet IE öffnen mit 50% Zoom
    14.07.2014 11:24:49
    Nepumuk
    Hallo,
    zoomen kannst du erst nach dem die Seite geladen ist.
    Deine Warteschleifen und die Wait-Methode von Excel sind wahre Bremsen für das laden der Seite, die hab ich mal geändert.
    Option Explicit

    Private Declare Sub Sleep Lib "kernel32.dll" ( _
        ByVal dwMilliseconds As Long)

    Private Const OLECMDEXECOPT_DONTPROMPTUSER As Long = 2
    Private Const OLECMDID_COPY As Long = 12
    Private Const OLECMDID_SELECTALL As Long = 17
    Private Const OLECMDID_OPTICAL_ZOOM As Long = 63

    Private Sub CopyHtmlToClipboard(wwwAdress As String)
        
        Dim appIE As Object
        
        Set appIE = CreateObject("InternetExplorer.Application")
        
        With appIE
            
            .Navigate wwwAdress
            
            .Visible = True ' True sichtbar ; mit false hier läuft es im Hintergrund
            
            Do While .Busy
                DoEvents
                Call Sleep(100)
            Loop
            
            .ExecWb OLECMDID_OPTICAL_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER, 50&, Null '50% Zoom
            
            .ExecWb OLECMDID_SELECTALL, OLECMDEXECOPT_DONTPROMPTUSER, Null, Null 'Select All
            
            .ExecWb OLECMDID_COPY, OLECMDEXECOPT_DONTPROMPTUSER, Null, Null 'Copy
            
            .ExecWb OLECMDID_OPTICAL_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER, 100&, Null '100% Zoom
            
            .Quit
            
        End With
        
        Set appIE = Nothing
        
    End Sub

    Gruß
    Nepumuk

    Anzeige
    AW: Interntet IE öffnen mit 50% Zoom
    14.07.2014 11:57:17
    Michael
    Danke Nepumuk!
    Nur er nimmt es nicht an, da er bei Sub Sleep meckert?
    "Private Declare Sub Sleep Lib "kernel32.dll" ( _ByVal dwMilliseconds As Long)"

    AW: Interntet IE öffnen mit 50% Zoom
    14.07.2014 12:02:36
    Nepumuk
    Hallo,
    ändere die Zeile so:
    Private Declare PtrSafe Sub Sleep Lib "kernel32.dll" ( _
    ByVal dwMilliseconds As Long)
    

    Gruß
    Nepumuk

    AW: Interntet IE öffnen mit 50% Zoom
    14.07.2014 12:10:21
    Michael
    Vielen, vielen Dank!
    Das rennt wie verrückt!
    Fehler lag am PtrSafe?

    AW: Interntet IE öffnen mit 50% Zoom
    14.07.2014 12:13:53
    Nepumuk
    Hallo,
    ja, denn du hast eine 64Bit-Version von Excel was ich nicht wusste.
    Gruß
    Nepumuk

    Beliebteste Forumthreads (12 Monate)

    Anzeige

    Beliebteste Forumthreads (12 Monate)

    Anzeige
    Anzeige
    Anzeige