Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen
Informationen und Beispiele zum Thema TextBox
BildScreenshot zu TextBox TextBox-Seite mit Beispielarbeitsmappe aufrufen

Wert wird nicht gefunden

Betrifft: Wert wird nicht gefunden von: Peter (hpo)
Geschrieben am: 30.07.2014 11:46:52

Hallo Zusammen

Hier benötige ich mal wieder Eure Hilfe.

In einer Schleife durchlaufe ich alle belegten Zellen in eineer Spalte und wenn der Wert in der Zelle gleich ist wie in einer Textbox soll eine Meldung ausgegben werden.

Dazu habe ich eine kleine Bsp. Datei erstellt.

Nun ist es bei mir so, das im Direktfenster alles gleich ist und es wird trozdem keine Meldung ausgegeben warum????????????

Ich konnte kein Fehler im Code feststellen, vieliecht einer von Euch und kann mir auf die Sprüngen helfen

https://www.herber.de/bbs/user/91780.xlsm

Vielen Dank und viele Grüße
Peter (hpo)

  

Betrifft: AW: Wert wird nicht gefunden von: Werner
Geschrieben am: 30.07.2014 12:09:35

Hallo Peter,

ändere folgende Zeile in deinem code

If e.Value = CVar(TextBox1.Value) Then
in
If e.Value = CVar(TextBox1.Value * 1) Then
Textboxen beinhalten Text, auch wenn du dort Zahlen eingibst. Du vergleichst mit deinem Code also Text mit Zahlen, da kann keine Übereinstimmung gefunden werden.
Durch die Multiplikation mit 1 wird aus dem Text in der Textbox eine Zahl und es funktioniert.

Gruß Werner


  

Betrifft: AW: Wert wird nicht gefunden von: Peter (hpo)
Geschrieben am: 30.07.2014 12:31:18

Hallo Werner

Vielen Dank für Deine Hilfe.

Mein Problem ist aber, das ich sowohl Zahlen mit Text oder auch nur Text oder nur Zahlen habe nach dem gesucht werden muss. Deshalb habe ich ja vor der Textbox das "Cvar" angegeben.

Wie kann ich den dies auffangen, damit ich keine Fehlermeldung bekommen und der Inhalt auch gefunden wird?

Vieleicht kannst Du mir hier weiter helfen. Wäre sehr schön ;-)

Viele dank

Gruß
Peter (hpo)


  

Betrifft: AW: Wert wird nicht gefunden von: Peter Feustel
Geschrieben am: 30.07.2014 12:51:06

Hallo Peter,

so sollte das aber funtionieren:

If CStr(rZelle.Value) = CStr(TextBox1.Value) Then
Gruß Peter


  

Betrifft: AW: Wert wird nicht gefunden von: EtoPHG
Geschrieben am: 30.07.2014 13:25:21

Hallo Peter & Peter

1. Wenn du nach dem sichtbaren Inhalt einer Zelle suchen willst, benutze e.Text, statt e.Value
2. CStr(e.Value) hilft nicht, viel wenn es sich z.b. um Kommazahlen handelt, bei der nicht alle Kommastellen sichtbar sind. Gefunden würden hier nur Zellen, für die alle Kommastellen der Zahl angeben würden.
3. Würde ich diesen Befehl vorziehen, da er auch Funde mit 'beginnt mit' aufzeigt:

If TextBox1 & "*" like e.Text Then 
Gruess Hansueli


  

Betrifft: AW: Wert wird nicht gefunden von: Rudi Maintaire
Geschrieben am: 30.07.2014 12:56:33

Hallo,
das im Direktfenster alles gleich ist
klar. Ob du eine Zahl als Zahl oder Text reinschreibst is egal. Sieht immer gleich aus. Ist es aber nicht.

Da Textboxen immer Text enthalten:

    If CStr(e) = TextBox1 Then
Gruß
Rudi


  

Betrifft: AW: Wert wird nicht gefunden von: Peter (hpo)
Geschrieben am: 30.07.2014 13:08:32

Hallo Zusammen (Rudi, Peter, Werner)

Vielen Dank für Eure Hilfe.

Manchmal steht man auf der Leitung, den Inhalt in ein Str. zu wandel macht natürlich mehr sin und Funktioniert wunderbar.

Nochmal vielen Dank

Gruß
Peter (hpo)


  

Betrifft: AW: Wert wird nicht gefunden von: Peter Feustel
Geschrieben am: 30.07.2014 13:59:45

Hallo Peter,

warum verwendest Du nicht die Find-Methode oder Match?

Dim WkSh      As Worksheet
Dim rZelle    As Range
 
   Set WkSh = ThisWorkbook.Worksheets("Tabelle1")
   
   With WkSh.Columns(2)
      Set rZelle = .Find(What:=TextBox1.Value, LookAt:=xlWhole, LookIn:=xlValues)
      If Not rZelle Is Nothing Then
         MsgBox "Der Begriff  """ & TextBox1.Value & """  wurde in der Zeile  """ & _
            rZelle.Row & """  gefunden."
       Else
         MsgBox "Der Begriff  """ & TextBox1.Value & """  wurde nicht gefunden."
      End If
   End With
Gruß Peter


  

Betrifft: AW: Wert wird nicht gefunden von: Peter Feustel
Geschrieben am: 30.07.2014 14:11:48

Hallo Peter

hier noch die Match-Variante

Dim WkSh      As Worksheet
Dim vZeile    As Variant
 
   Set WkSh = ThisWorkbook.Worksheets("Tabelle1")
   
   If IsNumeric(TextBox1.Value) Then
      vZeile = Application.Match(CDbl(TextBox1.Value), WkSh.Columns(2), 0)
    Else
      vZeile = Application.Match(TextBox1.Value, WkSh.Columns(2), 0)
   End If
   If IsNumeric(vZeile) Then
      MsgBox "Der Begriff  """ & TextBox1.Value & """  wurde in der Zeile  """ & _
         vZeile & """  gefunden."
    Else
      MsgBox "Der Begriff  """ & TextBox1.Value & """  wurde nicht gefunden."
   End If

Gruß Peter


 

Beiträge aus den Excel-Beispielen zum Thema "Wert wird nicht gefunden"