Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema ScrollBar
BildScreenshot zu ScrollBar ScrollBar-Seite mit Beispielarbeitsmappe aufrufen

VBA blockiert copy and paste

Betrifft: VBA blockiert copy and paste von: MRInterNETT
Geschrieben am: 09.09.2014 21:16:12

Hallo Zusammen,

ich habe eine Datei mit mehreren Tabellenblättern. Da ich im Startblatt keine Scrollbalken wollte, habe ich in "dieseArbeitsmappe" Displayscrollbar auf false gesetzt und in jedem einzelnen Tabellenblatt wieder auf true. Wenn vbacode für die einzelnen Tabellenblätter eingegeben ist, kann ich leider nicht mehr von einem ins andere Tabellenblatt per strg+c und strg+v kopieren. Wie kann man das per vba wieder ermöglichen?

Gruß MRInterNETT

  

Betrifft: AW: VBA blockiert copy and paste von: fcs
Geschrieben am: 10.09.2014 01:59:44

Hallo MRInterNETT,

wenn du den Code unter DieseArbeitsmappe wie fogt aufbaust, dann wird der Kopiermodus nur deaktiviert, wenn das Startblatt aktiviert oder wieder verlassen wird. Bei einem Wechsel zwischen den anderen Blättern bleibt der Kopiermodus aktiv, da der Display-Modus der Scrollbalken nur noch geändert wird, wenn er für das aktive Blatt falsch ist.

Den Code zum Einblenden der Scrollbalken unter den einzelnen Blättern muss du löschen.

Gruß
Franz

'Code unter diese Arbeitsmappe
Option Explicit
'

Private Sub prcScrollbarsOn_Off(bolOn As Boolean)
    With ActiveWindow
        If Not .DisplayHorizontalScrollBar = bolOn Then .DisplayHorizontalScrollBar = bolOn
        If Not .DisplayVerticalScrollBar = bolOn Then .DisplayVerticalScrollBar = bolOn
    End With
End Sub

Private Sub Workbook_Open()
    Sheets("Start").Activate
    Call prcScrollbarsOn_Off(bolOn:=False)
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Select Case Sh.Name
        Case "Start"
            Call prcScrollbarsOn_Off(bolOn:=False)
        Case Else
            Call prcScrollbarsOn_Off(bolOn:=True)
    End Select
End Sub