@ Nepumuk - Windows Zwischenspeicher auslesen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: @ Nepumuk - Windows Zwischenspeicher auslesen
von: Thomas Kahnt
Geschrieben am: 18.04.2015 18:53:51

Hallo Nepumuk,
muss leider doch noch eine Nachfrage starten:
Scheinbar hat der Code ein Prob. sofern der Zwischenspeicher leer ist. Läuft dann auf folgenden Fehler:
Laufzeitfehler'-2147221404(80040064)':
DataObject:GetText Ungültige FORMATETC-Struktur
Könntest du bitte noch einmal schauen?!
Danke im Vorwege
Thomas
Public Sub Verify_Clipboard()
Dim objClipBoard As Object
Set objClipBoard =
CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
Call objClipBoard.GetFromClipboard
If Left$(objClipBoard.GetText, 10) = "Dienstplan" Then
'MeinMacro
Else
MsgBox "Falscher Inhalt im Clipbard", vbExclamation, "Hinweis"
End If
Set objClipBoard = Nothing

Bild

Betrifft: AW: @ Nepumuk - Windows Zwischenspeicher auslesen
von: Nepumuk
Geschrieben am: 18.04.2015 19:41:43
Hallo,
na dann so:

Option Explicit

#If VBA7 Then
Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32.dll" ( _
    ByVal wFormat As Long) As Long
#Else
Private Declare Function IsClipboardFormatAvailable Lib "user32.dll" ( _
    ByVal wFormat As Long) As Long
#End If

Private Const CF_TEXT As Long = 1

Public Sub Verify_Clipboard()
    Dim objClipBoard As Object
    If IsClipboardFormatAvailable(CF_TEXT) Then
        Set objClipBoard = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
        Call objClipBoard.GetFromClipboard
        If Left$(objClipBoard.GetText, 10) = "Dienstplan" Then
            'MeinMacro
            Stop
        Else
            MsgBox "Falscher Inhalt im Clipbard.", vbExclamation, "Hinweis"
        End If
    Else
        MsgBox "Kein Inhalt im Clipboard.", vbExclamation, "Hinweis"
    End If
    Set objClipBoard = Nothing
End Sub

Gruß
Nepumuk

Bild

Betrifft: AW: @ Nepumuk - Windows Zwischenspeicher auslesen
von: Nepumuk
Geschrieben am: 18.04.2015 19:44:23
Hallo,
die Stop-Anweisung im Code ist noch vom Testen übrig, die kannst du löschen.
Gruß
Nepumuk

Bild

Betrifft: OT - Nochmal danke, das war's !!
von: Thomas Kahnt
Geschrieben am: 18.04.2015 23:34:18


 Bild

Beiträge aus den Excel-Beispielen zum Thema "@ Nepumuk - Windows Zwischenspeicher auslesen"