Wenn wert in Liste dann

Bild

Betrifft: Wenn wert in Liste dann
von: MJ
Geschrieben am: 20.10.2015 18:03:50

Hallo ihr Experten
Habe mich hier angemeldet weil ich bisher immer ne Lösung für meine Probleme hier gefunden hab. Nun aber nichtmehr.
Also ich möchte erreichen das ein Ausgegebener Wert, der eine Zahl ist mit einer Tabelle von Zahlen verglichen wird. DAs jedoch ist jetzt eigentlich noch nicht das Problem. =VERGLEICH(AH24;AF3:AF20;0) Das bekomme ich noch hin auch wenn mir hier nicht die Richtige Zahl wiedergegeben wird. die gesuchte Zahl ist die 13 wiedergegeben wird die 14?
Nun die eigentliche Schwierigkeit wenn der Wert gefunden wird soll in der Spalte daneben der dazugehörige Geldwert genommen werden und mit der Anzahl Tage im Monat multipliziert werden.
Als Beispiel: Ein Kind ist 13 Jahre alt und bekommt pro Tag 1€.
Ein Kind ist 7 Jahre alt und bekommt pro Tag 0,43€
Dies soll sich nun pro monat über Anwesenheitsliste berechnen. Die Liste steht und funkioniert es werden mir die Tage der anwesenheit ausgegeben.
Hinbekommen habe ich die sache schon aber leider werden da immer die Tatsächlichen Monatstage angenommen und nicht 30 Tage wenn der Monat voll ist.
Ich poste hier mal meinen ersten versuch:
=WENN(AH23=$AF$3;$AH$3*AF23;WENN(AH23=$AF$4;$AH$4*AF23;WENN(AH23=$AF$4;$AH$4*AF23;WENN(AH23=$AF$5; $AH$5*AF23;WENN(AH23=$AF$6;$AH$6*AF23;WENN(AH23=$AF$7;$AH$7*AF23;WENN(AH23=$AF$8;$AH$8*AF23; WENN(AH23=$AF$9;$AH$9*AF23;WENN(AH23=$AF$10;$AH$10*AF23;WENN(AH23=$AF$11;$AH$11*AF23; WENN(AH23=$AF$12;$AH$12*AF23;WENN(AH23=$AF$13;$AH$13*AF23;WENN(AH23=$AF$14;$AH$14*AF23; WENN(AH23=$AF$15;$AH$15*AF23;WENN(AH23=$AF$16;$AH$16*AF23;WENN(AH23=$AF$17;$AH$17*AF23; WENN(AF18=$AH$23;$AH$18*AF23;WENN(AH23=$AF$19;$AH$19*AF23;WENN(AH23=$AF$20;$AH$20*AF23;0)))))))))))) ) ))))))
Er würde funktionieren wenn der Monat immer 30 Tage hätte.
MfG und ich hoffe ihr versteht was ich erreichen möchte der MJ

Bild

Betrifft: AW: Wenn wert in Liste dann
von: Spenski
Geschrieben am: 20.10.2015 18:41:19
Hallo
Wäre nett wenn du eine Beispieldatei Hochladen würdest. Ganz Klar wird mir nicht was du da haben möchtest.
mfg
Christian

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 20.10.2015 19:19:42
Ok naja habs zweimal nun haochgeladen..... erst lesen dann schließen :)
https://www.herber.de/bbs/user/100915.xlsx
Da der link hab mal die gesammte Tabelle bisher hochgeladen.

Bild

Betrifft: AW: Wenn wert in Liste dann
von: Spenski
Geschrieben am: 20.10.2015 19:45:59
Hallo..also im ersten Post sehe ich keinen Link ;)
Zu deiner Formel in AI23, die kann man auch kürzer schreiben:
AI23=SVERWEIS(AH23;$AF$3:$AH$20;3)*AF23 (und dann runterkopieren)
Ich würde dir gerne helfen, allerdings versteh ich diesen text nicht ganz genau :
Hier soll das Ergebnis pro monat stehen aber der Monat soll mit maximal 30 Tagen und minimal 30 Tagen berechnet werden. Also der Februar wenn er komplett ist mit 30 Tagen.
wenn du es ein bisschen genauer erklären kannst, evtl auch wie die das Ergebnis aussehen soll würd ich dir dann gerne dabei weiterhin helfen
mfg
christian

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 20.10.2015 19:57:35
OK ich versuchs mal zu erklären.
Also wenn ein Kind Beispielsweise nur 15 Tage anwesend ist soll es nur für 15 Tage Taschengeld bekommen, ist ein kind aber einen ganzen Monat anwesend soll es für 30 Tage Taschengeld bekommen. Dabei muss es aber egal sein ob der Monat 29, 30, oder 31 Tage hat. Und das soll halt automatisch berechnet werden.
Hoffe das hilft als Erklärung.....?
Danke fürs vereinfachen der Formel in AI23..... das hätt ich mal eher wissen müssen :)
Und danke für´s Intresse an meinem Problemchen!
MfG MJ


Bild

Betrifft: AW: Wenn wert in Liste dann
von: Spenski
Geschrieben am: 20.10.2015 19:59:56
Ich nochmal...ich glauebe ich weiss worauf du hinaus willst. wie wäre es mit einer prozentualen lösung?
Beispiel 13 jähriger bekommt 30€ im Monat:
war er zb 31 von 31 tagen im Januar da bekommt er 100% von 30€, also 30€
war er zb 16 von 28 tagen im Februar da bekommt er 51,14% von 30€, also 15,34€
Meinst du das in etwa so?
gruss
christian

Bild

Betrifft: AW: Wenn wert in Liste dann
von: Spenski
Geschrieben am: 20.10.2015 20:15:30
So wäre es glaube ich nach deinem Wunsch. Bedeutet aber das im Januar jemand mit 30 tagen Anwesenheit genausoviel Taschengeld wie jemand mit 31 tagen Anwesenheit bekommen würde, fänd ich ungerecht :)
AI=WENN(TAG(DATUM(JAHR(Januar!$Y$1);MONAT(Januar!$Y$1)+1;1)-1)=AF23;SVERWEIS(AH23;$AF$3:$AG$20;2;0);SVERWEIS(AH23;$AF$3:$AH$20;3;0)*AF23) (und dann wieder runterkopieren)
schau dir mal den vorschlag im vorpost von mir an mit dem prozentualen Lösungsvorschlag
mfg
christian

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 20.10.2015 20:34:21
OK und ich glaube zu wissen was du meinst. Das hieße ich müsste die Einzelnen Monate mit jeweils 100% bei der jeweiligen Anzahl von Tagen hinterlegen und dann pro Monat berechnen. OK soweit komm ich mit Aber dann müsste in dieser Formel die Anzahl Tage zu 100% flexiebel sein da es ja SChaltjahre giebt.
Wie bekomme ich das dann hin?

Bild

Betrifft: AW: Wenn wert in Liste dann
von: Spenski
Geschrieben am: 20.10.2015 21:22:44
prozentual würde es dann so aussehen
AI23=SVERWEIS(AH23;$AF$3:$AG$20;2;0)*AF23/TAG(DATUM(JAHR(Januar!$Y$1);MONAT(Januar!$Y$1)+1;1)-1) (wieder runterkopieren)
gruss
christian

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 20.10.2015 22:02:26
Wow du machst dir echt Arbeit danke dir ich meld mich morgen Abend wieder wenn ich wieder am PC sitze.
Aber so richtig die Lösung wars noch nicht. Auch wenns schon echt weiterhilft.
Vieleicht hab ich ja im schlaf noch ne zündende Idee.
Danke und bis Morgen.
MJ

Bild

Betrifft: AW: Wenn wert in Liste dann
von: hary
Geschrieben am: 21.10.2015 08:50:13
Moin
Moechstest du wirklich volle Monate mit 30 Tage?
=WENN(AH23="";"";SVERWEIS(AH23;$AF$3:$AH$20;3;0)*WENN(AF23=TAG(MONATSENDE(Januar!Y1;0));30;AF23))
GRUSS HARY

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 21.10.2015 16:27:30
HAllo erstmal
Ja immer 30 Tage so das es volles geld giebt wenn das Kind 30 tage im Januar da war auch wenn der Januar 31 hat und im Februar am 28. Tag volles geld hat aber am 27 eben nur für 27 tage. Ist nicht auf meinem Mist gewachsen......
Und ja ich brauche es genau so danke für die Formel und total super währe wenn du sie mir noch kurz erklärst, ganz versteh ich sie nicht und hab aber schon den Drang danach das was ich tuhe auch zu verstehen. Man lernt ja nie aus.
Danke an euch Helfer für die guten Ideen
MfG MJ

Bild

Betrifft: AW: Wenn wert in Liste dann
von: MJ
Geschrieben am: 21.10.2015 18:56:42
Also ich nochmal ;)
Habe mir jetzt die Endlösung meiner Formel zurechtgebastelt so das ich sie ohne zusatzberechnungen auf alle Tabellenblätter anwenden kann.
Fals es Intresse daran giebt: =WENN(Berechnungen!AH24="";"";SVERWEIS(Berechnungen!AH24;Berechnungen!$AF$3:$AH$20;3;0)*WENN(ZÄHLENWENN(D3:AH3;"x")+ZÄHLENWENN(D3:AH3;"u")=TAG(MONATSENDE(AA1;0));30;ZÄHLENWENN(D3:AH3;"x")+ZÄHLENWENN(D3:AH3;"u")))
Danke nochmals für eure Hilfreichen Tips.
MfG MJ

Bild

Betrifft: AW: Erklaerung
von: hary
Geschrieben am: 22.10.2015 06:51:42
Moin
~f~=WENN(AH23="";"";SVERWEIS(AH23;$AF$3:$AH$20;3;0)*WENN(AF23=TAG(MONATSENDE(Januar!Y1;0));30;AF23))
WENN(AH23="";"";
Wenn Ah23 ist leer dann Formelergebniss leer sonst
SVERWEIS(AH23;$AF$3:$AH$20;3;0)
SVerweis vergleicht 1.Spalte(AF) im Bereich $AF$3:$AH$20 mit H23. Die 0(Null) heisst genaue Uebereinstimmung und gibt bei Treffer die 3.Spalte (die 3) wieder.
MONATSENDE(Januar!Y1;0) gibt das Datum des letzten Tages im Monat wieder.
TAG(MONATSENDE(Januar!Y1;0)) gibt den Tag wieder.
also wird verglichen ob AF23(Zahl) gleich Tag, wenn ja dann 30 sonst AF23(Zahl).
Du kannst einzelne Formelteile markieren, dann F9-Taste druecken. Dann wird dir der Wert des Formelteils angezeigt. Achtung: Rueckgaengig machen mit ESC-Taste.
gruss hary

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Mit mehreren Farben filtern"