Inputbox

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
InputBox MsgBox
Bild

Betrifft: Inputbox
von: Fritz_W
Geschrieben am: 24.11.2015 13:57:02

Hallo VBA-Experten,
ich bitte um Hilfe bei der Umsetzung folgenden Vorhabens:
Ich möchte mittels einer Inputbox einen Text in Zellen der Spalte C der Tabelle2 eingeben.
Zunächst sollte in die Inputbox eine ganze Zahl eingegeben werden. Der dann (in die Inputbox)noch einzugegebene Text sollte dann in die Spalte C derjenigen Zeile der Tabelle2 eingefügt werden, in der in der Spalte A der Tabelle2 die eingegebene Zahl steht:
Beispiel:
Ich gebe in die Inputbox die Zahl 5 ein, in der Tabelle2 steht die Zahl 5 in der Zelle A9. Dann sollte der über die Inputbox eingegebene Text in die Zelle C9 der Tabelle2 eingefügt werden.
Hinweis: In der Spalte A der Tabelle2 kommt jede Zahl nur 1x vor.
Wird eine Zahl eingegeben, die in der Spalte A der Tabelle2 nicht enthalten ist, sollte das Makro mit einem entsprechenden Hinweis abgebrochen werden.
Im Voraus besten Dank für Eure Unterstützung.
mfg
Fritz

Bild

Betrifft: AW: Inputbox
von: Nepumuk
Geschrieben am: 24.11.2015 14:57:31
Hallo,
teste mal:

Option Explicit

Public Sub Eingabe()
    Dim objCell As Range
    Dim strInput As String
    Set objCell = Cells.Find(What:=vbNullString)
    
    strInput = InputBox("Zahl eingeben.", "Eingabe")
    If IsNumeric(strInput) Then
        Set objCell = Columns(1).Find(What:=CDbl(strInput), LookIn:=xlValues, LookAt:=xlWhole)
        If Not objCell Is Nothing Then
            strInput = InputBox("Text eingeben.", "Eingabe")
            Cells(objCell.Row, 3).Value = strInput
        Else
            Call MsgBox("Zahl nicht gefunden.", vbExclamation, "Hinweis")
        End If
    End If
End Sub

Gruß
Nepumuk

Bild

Betrifft: AW: Inputbox
von: Fritz_W
Geschrieben am: 24.11.2015 15:09:23
Hallo Nepumuk,
zunächst vielen Dank für Deine Unterstützung.
Das Makro funktioniert dann, wenn ich die Tabelle2 das aktive Tabellenblatt ist.
Ich möchte jedoch gerne die Eingabe aus einem anderen Tabellenblatt vornehmen.
Würde mich freuen, wenn Du das entsprechend anpassen könntest.
mfg
Fritz

Bild

Betrifft: AW: Inputbox
von: Nepumuk
Geschrieben am: 24.11.2015 15:28:18
Hallo,
es wäre nett wenn du so etwas in deiner ersten Frage schon erwähnst.

Option Explicit

Public Sub Eingabe()
    Dim objCell As Range
    Dim strInput As String
    
    With Worksheets("Tabelle2")
        
        Set objCell = .Cells.Find(What:=vbNullString)
        
        strInput = InputBox("Zahl eingeben.", "Eingabe")
        If IsNumeric(strInput) Then
            Set objCell = .Columns(1).Find(What:=CDbl(strInput), LookIn:=xlValues, LookAt:=xlWhole)
            If Not objCell Is Nothing Then
                strInput = InputBox("Text eingeben.", "Eingabe")
                .Cells(objCell.Row, 3).Value = strInput
            Else
                Call MsgBox("Zahl nicht gefunden.", vbExclamation, "Hinweis")
            End If
        End If
    End With
End Sub

Gruß
Nepumuk

Bild

Betrifft: AW: Inputbox
von: Fritz_W
Geschrieben am: 24.11.2015 15:39:01
Hallo Nepumuk,
funktioniert nun wie gewünscht.
Ich bitte um vielmals um Entschuldigung, was meine unzureichende Beschreibung betrifft.
Ich bin sehr dankbar für die Unterstützung durch die vielen kompetenten Helfer in diesem Forum und möchte diesen Helfern gewiss nicht unnötig ihre Arbeit erschweren.
Beste Grüße
Fritz

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Inputbox"