Planungsproblem

Hallo zusammen,
habe eine neue Problemstellung
Ein Projekt A besitzt eine Auftragszeit und ein Liefertermin.
Auf einer fortlaufenden Kalenderwochenleiste, soll der Liefertermin eingeordnet werden. dafür soll die Fertigungszeit auf zwei Wochen VOR eintreten des Liefertermins geplant werden. ich hoffe die Beispielmappe stellt mein Problem umfassend dar.

Die Datei https://www.herber.de/bbs/user/102424.xlsx wurde aus Datenschutzgründen gelöscht

Das Problem soll mit VBA umgesetzt werden. Normale Excelformeln waren nicht genug.
Ich wollte das über If-Then Funktionen bewältigen.
If Range(D2,S2)=Range(U3,U26) Then ...
Also: Wenn ein Wert aus dem Bereich D2 bis S2 mit einem Wert aus dem Bereich U3 bis U26 übereinstimmt, soll der dazugwehörige Wert, aus der Zeile aus dem Bereich W3 bis W26, auf zwei Wochen vor dem Schnittpunkt verteilt werden.
Mein Problem ist das ich nicht so recht weis mit was ich anfangen muss. Bin vorallem daran Interessiert es zu verstehen um auf solche Fragen in Zukunft verzichten zu können.
Vielen Dank schonmal.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Planungsproblem

23.12.2015 15:37:15

Sepp

Nachtrag

23.12.2015 15:38:40

Sepp

AW: Nachtrag

28.12.2015 06:22:59

Florian

AW: Nachtrag

28.12.2015 09:03:11

Sepp

AW: Nachtrag

28.12.2015 10:58:32

Florian

Hallo Florian,
ob der VBA-Code leichter zu pflegen ist, wird sich noch herausstellen.
Für deine Beispieldatei.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub planung()
Dim varPlan() As Variant, varKW As Variant, varValues As Variant
Dim varRet As Variant
Dim lngR As Long, lngLastRow As Long, lngLastCol As Long

With Tabelle1
  'Letzte Zeile in Spalte C ermitteln
  lngLastRow = Application.Max(3, .Cells(.Rows.Count, 3).End(xlUp).Row)
  'Letzte Spalte in Zeile 2 ermitteln
  lngLastCol = Application.Max(4, .Cells(2, .Columns.Count).End(xlToLeft).Column)

  'Array mit den KW's
  varKW = .Range(.Cells(2, 4), .Cells(2, lngLastCol))
  'Array mit den Werten
  varValues = .Range("U3:W" & lngLastRow)
  'Ausgabearray dimensionieren
  Redim varPlan(1 To lngLastRow, 1 To UBound(varKW, 2))

  For lngR = 1 To UBound(varValues, 1)
    varRet = Application.Match(varValues(lngR, 1), varKW, 0)
    If IsNumeric(varRet) Then
      If varRet - 1 > 0 Then varPlan(lngR, varRet - 1) = varValues(lngR, 3) / 2
      If varRet - 1 > 1 Then varPlan(lngR, varRet - 2) = varValues(lngR, 3) / 2
    End If
  Next
  'Ausgabe
  .Range("D3").Resize(UBound(varValues, 1), UBound(varKW, 2)) = varPlan
End With
End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X
1
2	Projekt	KW01	KW02	KW03	KW04	KW05	KW06	KW07	KW08	KW09	KW10	KW11	KW12	KW13	KW14	KW15	KW16
3	20016																		KW01		200
4	20017	200,0																	KW02		400
5	20018																		KW01		200
6	20019		100,0	100,0															KW04		200
7	20020				200,0	200,0													KW06		400
8	20021				200,0	200,0													KW06		400
9	20022				200,0	200,0													KW06		400
10	20023						214,3	214,3											KW08		429
11	20024					228,6	228,6												KW07		457
12	20025					242,9	242,9												KW07		486
13	20026									257,1	257,1								KW11		514

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread