Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema Image
BildScreenshot zu Image Image-Seite mit Beispielarbeitsmappe aufrufen

Bitmap in den Zwischenspeicher schubsen.


Betrifft: Bitmap in den Zwischenspeicher schubsen. von: Kai Thiel
Geschrieben am: 14.09.2017 22:36:00

Hallo und guten Abend!

ich brauche eure Hilfe:

Auf dem Laufwerk C:\ liegt eine Bitmap Datei, diese soll in den Zwischenspeicher geladen werden, das ist alles! Ich brauche bitte, falls jemand von euch weiß wie, den Code für das Makro welches mit dir Bitmap-Datei:

C:\test.bmp

In die Zwischenablage lädt. Diese heißt soweit ich weiß Clipboard in Excel.
Das ist bereits alles.

Ich brauche dies für ein Makro das soweit schon funktioniert, dies ist der letzte Baustein den ich brauche. Vielen Dank bereits im voraus :)!

MfG Euer Kai

  

Betrifft: AW: Bitmap in den Zwischenspeicher schubsen. von: Nepumuk
Geschrieben am: 15.09.2017 08:45:13

Hallo Kai,

so:

Option Explicit

Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function OpenClipboard Lib "user32.dll" ( _
    ByVal hwnd As Long) As Long
Private Declare Function SetClipboardData Lib "user32.dll" ( _
    ByVal wFormat As Long, _
    ByVal hMem As Long) As Long
Private Declare Function CopyImage Lib "user32.dll" ( _
    ByVal handle As Long, _
    ByVal imageType As Long, _
    ByVal newWidth As Long, _
    ByVal newHeight As Long, _
    ByVal lFlags As Long) As Long

Private Const CF_BITMAP = 2
Private Const IMAGE_BITMAP = 0
Private Const LR_COPYRETURNORG = &H4

Public Sub ImageToClipBoard()
    Dim objPicture As IPictureDisp
    Dim lngReturn As Long
    Set objPicture = LoadPicture("C:\test.bmp")
    Call OpenClipboard(0&)
    Call EmptyClipboard
    lngReturn = CopyImage(objPicture, IMAGE_BITMAP, _
        0&, 0&, LR_COPYRETURNORG)
    Call SetClipboardData(CF_BITMAP, lngReturn)
    Call CloseClipboard
End Sub

Gruß
Nepumuk


Beiträge aus den Excel-Beispielen zum Thema "Bitmap in den Zwischenspeicher schubsen."