Daten filtern/löschen/bearbeiten mit VBA

Hallo zusammen,
ich würde gerne meine Daten bearbeiten, schaffe das jedoch leider selbst nicht in VBA und hoffe jemand kann mir unter die Arme greifen.
Ich hänge ein Beispiel an das verdeutlicht was ich machen will. Und zwar sollen von identischen Wertpaaren aus "PLZ" und "Ziffer" nur eines übrig bleiben - also eine Kombination von Werten soll es nur einmal geben.
Außerdem sollen die Zeilen aller PLZ farblich markiert werden, welche für verschiedene Ziffern verwendet werden - also wenn eine PLZ mehrfach unterschiedlichen Ziffern zugeordnet sind, soll das sichtbar sein.
Ich hoffe ich konnte das einigermaßen verständlich ausdrücken, sonst ist im Beispiel auch nochmal ersichtlich was ich meine.
Schon mal Vielen Dank.
Grüße,
Bastian
https://www.herber.de/bbs/user/121354.xlsx

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Bastian,
hier ein entsprechendes Makro.
Gruß
Franz

Sub Doppelte_PLZ_Ziffer_loeschen_und_mehrfach_PLZ_markieren()
Dim wks As Worksheet
Dim Zei_L As Long, Spa_L As Long
Dim rngData As Range
Set wks = ActiveSheet
With wks
'letzte Zeile mit Daten in Spalte A
Zei_L = .Cells(1, 1).End(xlDown).Row
'letzte Spalte mit Daten in Zeile 1
Spa_L = .Cells(1, 1).End(xlToRight).Column
'Datenbereich setzen
Set rngData = .Range(.Cells(1, 1), .Cells(Zei_L, Spa_L))
'Zeilen mit identischen Ziffern (Spalte B) und PLZ (Spalte D) löschen
rngData.RemoveDuplicates Columns:=Array(2, 4), Header:=xlYes
'neue letzte Zeile mit Daten in Spalte A
Zei_L = .Cells(1, 1).End(xlDown).Row
'neuer Bereich mit Daten
Set rngData = .Range(.Cells(2, 1), .Cells(Zei_L, Spa_L))
'bedingte Formatierung einfügen-Zeilen mit mehrfach vorkommender PLZ markieren
With rngData
.FormatConditions.Delete
.FormatConditions.Add Type:=xlExpression, Formula1:= _
"=ZÄHLENWENN(" & rngData.Columns(4).Address(True, True, xlA1) & ";" _
& rngData.Cells(1, 4).Address(False, True, xlA1) & ")>1"
.FormatConditions(.FormatConditions.Count).SetFirstPriority
With .FormatConditions(1).Interior
.PatternColorIndex = xlAutomatic
.Color = 65535  'gelb
.TintAndShade = 0
End With
.FormatConditions(1).StopIfTrue = False
End With
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Daten filtern/löschen/bearbeiten mit VBA

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

139 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Daten filtern/löschen/bearbeiten mit VBA

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

139 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread