Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1632to1636
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Daten aus einer Datei in eine Master Datei einspie

Daten aus einer Datei in eine Master Datei einspie
04.07.2018 14:47:16
Jürgen
Hallo zusammen, nachdem mir hier schon zwei mal hervorragend geholfen wurde, möchte ich euch Experten nochmal befragen.
Ich habe eine Masterdatei entwickelt. Diese Datei hat mehrere Tabellenblätter. Nennen wir die hier mal "Blatt1", "Blatt2", ... , "Blatt7". In den Tabellen "Blatt8 und "Blatt9" werden die Daten verarbeitet".
Dann gibt es eine Datei, nennen wir diese mal "Daten für Import". Diese Datei hat ebenfalls die oben genannten Tabellenblätter. Hier sind die benötigten Daten enthalten.
Wie kann ich die Daten aus den Tabellenblättern der Datei "Daten für Import" mittels Makro in die Datei "Masterdatei" ziehen?
Ich brauche hier ein Makro das Zeilen 3 bis 25 in der Datei "Daten für Import" mit der Funktion "Kopieren", "Inhalte Einfügen", "Werte" in die Datei "Masterdatei" einfügt. Am besten in einem Makro, sollte das nicht so einfach sein, dann gerne auch mit einem Makro/Tabellenblatt.
Ich würde mich über eine Rückmeldung sehr freuen.
Vielen Dank!!
Jürgen Reinecke

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Daten aus einer Datei in eine Master Datei einspie
06.07.2018 21:56:47
fcs
Hallo Jürgen,
hier ein entsprechendes Makro.
Die Namen der Blätter musst anpassen.
Gruß
Franz
Sub Daten_Importieren()
Dim wkbZiel As Workbook, wksZiel As Worksheet
Dim wkbQuelle As Workbook, wksQuelle As Worksheet, varQuelle
Dim wksAktiv As Object
Dim rngCopy As Range
Dim StatusCalc As Long
'Datei mit den Import-Daten auswählen
varQuelle = Application.GetOpenFilename(Filefilter:="Excel (*.xlsx),*.xlsx", _
Title:="Bitte Datei mit den Import-Daten auswählen", _
MultiSelect:=False)
If varQuelle = False Then Exit Sub
'Makrobremsen lösen
With Application
.ScreenUpdating = False
StatusCalc = .Calculation
.Calculation = xlCalculationManual
End With
Set wkbZiel = ActiveWorkbook 'Arbeitsmappe in das die Daten kopiert werden sollen
Set wksAktiv = ActiveSheet
Set wkbQuelle = Application.Workbooks.Open(Filename:=varQuelle, ReadOnly:=True)
For Each wksZiel In wkbZiel.Worksheets
Select Case wksZiel.Name
'Namen der Tabellenblätter deren Daten importiert werden sollen
Case "Tabelle1", "Tabelle2", "Tabelle3", "Tabelle4", "Tabelle5", _
"Tabelle6", "Tabelle7"
Set wksQuelle = wkbQuelle.Worksheets(wksZiel.Name)
With wksQuelle
Set rngCopy = .Range(.Rows(3), .Rows(25)) 'Zeilen komplett kopieren
'                    Set rngCopy = .Range(.Cells(3, 1), .Cells(25, 15)) 'Zellbereich kopieren
End With
rngCopy.Copy
wksZiel.Range("A3").PasteSpecial Paste:=xlPasteValues
Application.CutCopyMode = False
Case Else
'do nothing
End Select
Next wksZiel
wkbQuelle.Close savechanges:=False
'Makrobremsen zurücksetzen
With Application
.ScreenUpdating = True
.Calculation = StatusCalc
End With
wksAktiv.Activate
MsgBox "Import abgeschlossen", vbOKOnly, "Makro: Daten_Importieren"
End Sub

Anzeige
AW: Daten aus einer Datei in eine Master Datei einspie
09.07.2018 22:46:40
Jürgen
Hallo Franz,
sehe erst jetzt Deine Antwort.
Werde mich morgen mal dransetzen und versuchen das zu verstehen.
Dir erst einmal ganz lieben Dank für die Unterstützung.
Eventuell werde ich Dich nochmal anschreiben.
Gruß
Jürgen

305 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige