Microsoft Excel

Herbers Excel/VBA-Archiv

Sortierung mit Aggregat von Zahlen und Text


Betrifft: Sortierung mit Aggregat von Zahlen und Text von: Chris
Geschrieben am: 13.08.2018 10:16:12

Guten Tag,

ich stehe auf dem Schlauch bzgl. aufsteigender Sortierung von Zahlen/Text.
Habe eine Beispieldatei hochgeladen in der ich es mit der Aggregat-Formel probiere - Betonung liegt auf "PROBIERE".

https://www.herber.de/bbs/user/123289.xlsx

Ich bin der Meinung, dass ich die Tabelle "BrauchIchDas" für eine Sortierung benötige, aber ich bin kein Experte. Falls es eine Lösung gibt ohne Hilfstabelle dann wäre ich dafür offen.
Wichtig ist ggf. noch, dass "Tabelle1" (Quelle) durch ein Makro erweitert wird. Es wird immer die die erste Zeile nach der Überschrift angesprochen. D.h. alle Informationen werden dann eine Zeile nach unten verschoben (alt: Zeile 1 - neu: Zeile 2, alt: Zeile 2 - neu: Zeile 3 ...)

Im Voraus herzlichen Dank für eure Hilfe!

Gruß,
Chris

  

Betrifft: AW: eine Hilfstabelle bedarf es nicht ... von: neopa C
Geschrieben am: 13.08.2018 11:03:33

Hallo Chris,

... zunächst die Formel für reine Zahlenwerte, in A2:

=WENNFEHLER(AGGREGAT(15;6;INDEX(Tabelle1!$B:$B;2):INDEX(Tabelle1!$B:$B;ANZAHL2(Tabelle1!$B:$B))
/(INDEX(Tabelle1!$A:$A;2):INDEX(Tabelle1!$A:$A;ANZAHL2(Tabelle1!$B:$B))=A$1);ZEILE(A1));"")


und nach unten und danach in Spalte C und D kopiert.

Zunächst nachgefragt zu Deiner Sortierung der Textwerte in Spalte B. Eine "normale" Sortierung würde eine andere Reihenfolge ergeben. Nämlich zuerst 110-2, dann 110-3 und zuletzt 111-1. Wie soll sortiert werden? Wenn Deine Sortierungsvorgabe gelten soll, bedarf es weiterer Angaben Deinerseits zu den Daten. Sind diese immer Zahlenwerte getrennt durch ein "-" oder?

Weiter nachgefragt: Kann es je "Ü1" ein Mischmasch aus Texten und Zahlenwerten geben?

Gruß Werner
.. , - ...


  

Betrifft: AW: eine Hilfstabelle bedarf es nicht ... von: Chris
Geschrieben am: 13.08.2018 11:21:28

Hallo Werner,

vielen Dank für deine Hilfe, die Formel funktioniert für die Zahlenwerte tadellos!

Zu deinen Rückfragen bzgl. dem "Text":

Der Text soll aufsteigend sortiert werden (110-2, 110-3, 111-1).

Genau, die Zahlen sind mit "-" getrennt, das muss leider auch so bleiben.

Dafür gibt es aber keine Mischung von Text und Zahlen, d.h. für "B" wird es nur Text geben - also z.B. 111-1). Für A, C & D wiederum gibt es nur die normalen Zahlen.


Ich hoffe ich konnte deine Rückfragen präzise genug beantworten!

Gruß,
Chris


  

Betrifft: AW: eine Frage ergibt sich dooch noch ... von: neopa C
Geschrieben am: 13.08.2018 11:50:38

Hallo Chris,

... ist der Trennstrich zwischen den Ziffern immer an der vorletzten Stelle oder kann die Stelle variieren?

Gruß Werner
.. , - ...


  

Betrifft: AW: eine Frage ergibt sich dooch noch ... von: Chris
Geschrieben am: 13.08.2018 12:23:50

Hallo Werner,

die Stelle ist immer gleich, immer die Vorletzte!

Gruß,
Chris


  

Betrifft: AW: dann kann man auch wie Zahlen auswerten ... von: neopa C
Geschrieben am: 13.08.2018 12:34:14

Hallo Chris,

... folgende Formel in B2:

=WENNFEHLER(AGGREGAT(15;6;WECHSELN(INDEX(Tabelle1!$B:$B;2):INDEX(Tabelle1!$B:$B;
ANZAHL2(Tabelle1!$B:$B));"-";"")/(INDEX(Tabelle1!$A:$A;2):INDEX(Tabelle1!$A:$A;
ANZAHL2(Tabelle1!$B:$B))=B$1);ZEILE(B1));"")


und dieser Zelle das benutzerdefinierte Zahlenformat 0"-"0;; zuweisen und danach nach unten kopieren.

Gruß Werner
.. , - ...


  

Betrifft: AW: dann kann man auch wie Zahlen auswerten ... von: Chris
Geschrieben am: 13.08.2018 13:41:43

Hallo Werner,

vielen Dank nochmal für deine Hilfe, das klappt auch :-)

Gruß,
Chris


Beiträge aus dem Excel-Forum zum Thema "Sortierung mit Aggregat von Zahlen und Text"