Virtuelle Tastatur öffnen VBA

Habe folgenden Code gefunden, leider bekomme ich die Fehlermeldung "Konnte Tastatur nicht öffnen"
Nutze Windows 10.
Hat jemand eine Idee.....
'--------------------------------------------------------------------------
' Module : UserForm1
' Author : Case (Ralf Stolzenburg)
' Date : 25.04.2013
' Purpose : On Screen Keyboard - OSK - Bildschirmtastatur...
'--------------------------------------------------------------------------
Option Explicit


Private Sub CommandButton1_Click()
Shell "wmic Process where ""name='osk.exe'"" call terminate", vbHide
Unload Me
End Sub



Private Sub TextBox1_Enter()

TextBox1.Text = ""

ShellAndWait "cmd /c osk"

End Sub



Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)

Shell "wmic Process where ""name='osk.exe'"" call terminate", vbHide

End Sub

'--------------------------------------------------------------------------
' Module : UserForm1
' Procedure : ShellAndWait
' Author : Case (Ralf Stolzenburg)
' Date : 25.04.2013
' Purpose : ShellAndWait mit ausgeblendetem Dosfenster...
'--------------------------------------------------------------------------


Private Sub ShellAndWait(ByVal strPathName As String)
Dim WshShell As Object
On Error GoTo Fin
Set WshShell = CreateObject("WScript.Shell")
WshShell.Run strPathName, 0, True
Fin:
Set WshShell = Nothing
If Err.Number  0 Then MsgBox "Error: " & _
Err.Number & " " & Err.Description
End Sub

' UserForm nicht über das "X" schliessen lassen


Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = 0 Then Cancel = True
End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Thomas,
teste mal:

Option Explicit
Option Private Module

Private Declare PtrSafe Function GetCurrentProcess Lib "kernel32.dll" () As LongPtr
Private Declare PtrSafe Function IsWow64Process Lib "kernel32.dll" ( _
    ByVal hProcess As LongPtr, _
    ByRef Wow64Process As LongPtr) As Long
Private Declare PtrSafe Function ShellExecuteA Lib "shell32.dll" ( _
    ByVal Hwnd As LongPtr, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long
Private Declare PtrSafe Function Wow64EnableWow64FsRedirection Lib "kernel32.dll" ( _
    ByVal Enable As Boolean) As Boolean

Private Const SW_SHOWNORMAL As Long = 1&

Public Sub LoadScreenKeyboard()
    Dim lngptrIsWow64 As LongPtr, lngptrProcess As LongPtr
    lngptrProcess = GetCurrentProcess
    Call IsWow64Process(lngptrProcess, lngptrIsWow64)
    If lngptrIsWow64 = 0 Then
        Call ShellExecuteA(Application.Hwnd, "open", "osk.exe", _
            vbNullString, "C:\Windows\System32\", SW_SHOWNORMAL)
    Else
        Call Wow64EnableWow64FsRedirection(False)
        Call ShellExecuteA(Application.Hwnd, "open", "osk.exe", vbNullString, _
            "C:\Windows\System32\", SW_SHOWNORMAL)
        Call Wow64EnableWow64FsRedirection(True)
    End If
End Sub

Public Sub UnloadScreenKeyboard()
    Dim objWMI As Object, objProcessList As Object, objProcess As Object
    Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
    Set objProcessList = objWMI.ExecQuery("SELECT * FROM Win32_Process WHERE Name = 'osk.exe'")
    For Each objProcess In objProcessList
        Call objProcess.Terminate
    Next
    Set objProcessList = Nothing
    Set objWMI = Nothing
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Virtuelle Tastatur öffnen VBA

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread