Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1684to1688
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

PDF datein im Ordner u. Unterordner löschen

PDF datein im Ordner u. Unterordner löschen
02.04.2019 10:16:17
Stefan
Hallo Leute,
Ich brauche mal wieder eure Hilfe!
Ich suche einen Code der alle PDF Datein die älter als 1 Jahr sind im Ordner und allen Unterordnern löscht. Ich weiß so was hier schon gesehen zu haben aber ich finde es nicht mehr! Der Befehl soll bewusst mit Nachfrage per CMB Button ausgelöst werden.
Bsb. Aufbau der Ordner:
D:Liste/KDW/Abteilung/Essen/Fisch/Brot
Wir haben jetzt 2019 also alle PDF bis 31.12.2017 vom erstellungsdatum löschen!
Das Datum soll in eine Zeile eingetragen oder sogar vorgegeben werden.
Geht sowas?
MfG

13
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: PDF datein im Ordner u. Unterordner löschen
02.04.2019 10:57:19
Nepumuk
Hallo Stefan,
teste mal:
Option Explicit

Public Sub DeletePDF()
    Const FOLDER_PATH As String = "D:Liste\KDW\Abteilung\Essen\Fisch\Brot\"
    Dim astrFolders() As String, strReturn As String
    Dim strFileName As String
    Dim dtmDeleteBeforeDate As Date
    Dim ialngFolders As Long
    Do
        strReturn = InputBox("Bitte Datum im Format TT.MM.JJJJ eingeben.", "Eingabe")
        If StrPtr(strReturn) = 0 Then Exit Sub
        If strReturn Like "##.##.####" Then
            If IsDate(strReturn) Then
                dtmDeleteBeforeDate = CDate(strReturn)
                Exit Do
            Else
                Call MsgBox("Bitte ein gültiges Datum eingeben.", vbExclamation, "Hinweis")
            End If
        Else
            Call MsgBox("Bitte das Format des Datums beachten.", vbExclamation, "Hinweis")
        End If
    Loop
    astrFolders = GetFolders(FOLDER_PATH)
    For ialngFolders = LBound(astrFolders) To UBound(astrFolders)
        strFileName = Dir$(Pathname:=astrFolders(ialngFolders) & "*.pdf")
        Do Until strFileName = vbNullString
            If FileDateTime(Pathname:=astrFolders(ialngFolders) & strFileName) <= _
                dtmDeleteBeforeDate Then Call Kill(Pathname:=astrFolders(ialngFolders) & strFileName)
            strFileName = Dir$
        Loop
    Next
End Sub

Private Function GetFolders(ByVal pvstrPath As String) As String()
    Dim astrFolders() As String
    Dim strFolder As String, strPath As String
    Dim ialngIndex1 As Long, ialngIndex2 As Long
    Redim Preserve astrFolders(ialngIndex1)
    astrFolders(ialngIndex1) = pvstrPath
    ialngIndex1 = 1
    ialngIndex2 = 1
    strPath = pvstrPath
    Do
        strFolder = Dir$(Pathname:=strPath & "*", Attributes:=vbDirectory)
        Do Until strFolder = vbNullString
            If strFolder <> "." And strFolder <> ".." Then
                If GetAttr(strPath & strFolder) And vbDirectory Then
                    Redim Preserve astrFolders(0 To ialngIndex1)
                    astrFolders(ialngIndex1) = strPath & strFolder & "\"
                    ialngIndex1 = ialngIndex1 + 1
                End If
            End If
            strFolder = Dir$
        Loop
        If ialngIndex1 = ialngIndex2 Then Exit Do
        strPath = astrFolders(ialngIndex2)
        ialngIndex2 = ialngIndex2 + 1
    Loop
    GetFolders = astrFolders
End Function

Gruß
Nepumuk
Anzeige
AW: PDF datein im Ordner u. Unterordner löschen
02.04.2019 11:20:21
Stefan
Hallo Nepumuk,
Danke für deine Mühe ist ja doch viel Text bei rausgekommen :-))
Ich kann ihn jetzt nicht testen, da unterwegs. Mir ist was mit dem datum aufgefallen aber das ist meine schuld.
Ich meinte, dass alle PDF vom 01.01.-31.12.2017, danch 2018, 2019 usw. gelöscht werden. Und wie man das mit einer Eingabe lösen kann. In deinen Code Wüste ich nicht welches datum gemeint wäre?
Aber sonnst großes Danke schon mal
Stefan
Hab den haken für offen vergessen :)) owt
02.04.2019 11:22:46
Stefan
.
AW: PDF datein im Ordner u. Unterordner löschen
02.04.2019 12:14:20
Nepumuk
Hallo Stefan,
du gibst z.B. den 31.12.2017 ein. Es werden alle PDF's mit dem Datum vor dem 1.1.2018 gelöscht.
Gruß
Nepumuk
Nepumuk Danke für Aufklärung, Prima !!! Owt
02.04.2019 12:31:07
Stefan
.
Anzeige
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 11:00:47
Stefan
Hallo Nepumuk,
bin heute 06.04. erst zum Testen deines Codes gekommen, leider läuft er nicht.
Nach der Datumseingabe passiert nichts mehr ?
Hast du noch eine Idee? Solche Programmierungen sind zu hoch für mich !
Beste Grüße
Stefan
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 11:19:07
Nepumuk
Hallo Stefan,
ich kann dir nicht sagen warum es bei dir nicht läuft. Ich habe es natürlich getestet und bei mir hat es einwandfrei funktioniert. Hast du am Code irgendwas geändert?
Gruß
Nepumuk
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 11:48:22
Stefan
Hi,
ne garnix geändert, so übernommen, ist ja wieder komisch mit excel ?!
Wo hast du denn den Code drinne im Modul oder in der Tabelle ?
Beste Grüße
Anzeige
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 12:37:36
Nepumuk
Hallo Stefan,
in einem Modul. Passt den der Pfad überhaupt?
Gruß
Nepumuk
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 12:54:21
Stefan
Hi,
also hab nochmal geschaut, hab es auch im Modul, da viel mir jetzt auf, da die PDF im Letzten Ordner gelöscht wird ! das ist schon mal super. in allen Unterordnern aber bleibt die PDF vorhanden.
Ich denke das habe ich blöde erklärt. Ich habe in der Liste diverse Unterordner, in denen PDF's abgelegt werden.
"C:Liste\didiverse Unterordner\diverse Unterordner\diverse Unterordner\"
der Aufbau gibt das nicht anders her.
geht da was ?
Beste Grüße
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 13:39:44
Nepumuk
Hallo Stefan,
kann ich nicht nachvollziehen, ich habe natürlich auch mit Unterordern getestet.
Ich lass die Frage offen.
Gruß
Nepumuk
Anzeige
AW: PDF datein im Ordner u. Unterordner löschen
06.04.2019 13:47:21
Stefan
Hi,
Glaub ich dir ungesehen, typisch Excel, Danke Trotzdem !!!
AW: Nepumuk hab den Fehler, Danke dir !!!
06.04.2019 14:28:32
Stefan
.

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige