Herbers Excel-Forum - das Archiv
SVERWEIS aber wie?
- SVERWEIS aber wie? von Stefanie vom 19.09.2019 19:23:17
- AW: SVERWEIS aber wie? - von Hajo_Zi am 19.09.2019 19:35:09
- AW: SVERWEIS aber wie? - von Stefanie am 19.09.2019 19:52:08
- AW: SVERWEIS aber wie? - von Hajo_Zi am 19.09.2019 19:55:18
- AW: SVERWEIS aber wie? - von Stefanie am 19.09.2019 20:02:47
- AW: SVERWEIS aber wie? - von Rolf am 19.09.2019 20:07:46
- AW: SVERWEIS aber wie? - von Frank Furter am 19.09.2019 20:10:09
- AW: SVERWEIS aber wie? - von Stefanie am 19.09.2019 20:21:09
- AW: SVERWEIS aber wie? - von Stefanie am 19.09.2019 20:16:04
- AW: Gern geschehen - von Rolf am 19.09.2019 20:20:46
- Farben rauspicken - von WF am 19.09.2019 20:23:59
- Nach Sichtung aller Lösungen ... - von Luc:-? am 20.09.2019 00:49:58
Betrifft: SVERWEIS aber wie?
von: Stefanie
Guten Abend zusammen,
ich habe in einer Beispieldatei in "Spalte A" mehrere Nummern und darunter immer an anderer Stelle "Farbe" stehen!
In "Spalte F" neben der Farbe steht "Auswahl" und unter Auswahl der Farbton.
In Zellen "H7 bis H9" habe ich die Nummern stehen die sich in den Zellen in "Spalte A" wieder finden.
Jetzt benötige ich eine Formel in den "Zellen I7 bis I9" die mir den Farbton aus "Spalte F" eintragen!
Meine Versuche mit dem SVERWEIS sind bislang alle fehlgeschlagen so das ich gerne eure Hilfe in Anspruch nehmen würde!
LG
Steffi
https://www.herber.de/bbs/user/132124.xlsx
Betrifft: AW: SVERWEIS aber wie?
von: 1713966.html
Geschrieben am: 19.09.2019 19:35:09
Hallo Steffi,
es ist die falsche Datei, ich konnte Deine Formel nicht finden.
Betrifft: AW: SVERWEIS aber wie?
von: 1713969.html
Hallo Hajo,
danke für deine Hilfe... hatte die Formel absichtlich rausgelassen, da sie ja nicht zum gewünschten Erfolg führt :-)
Ich habe in Zelle I7 nachfolgende Formel angewendet...
WENN(ISTFEHLER(SVERWEIS($H7;$A$6:$F$38;6;FALSCH));"";SVERWEIS($H7;$A$6:$F$38;6;FALSCH))
Zum einen möchte ich den Fehler vermeiden, falls die nummer gar nicht gefunden wird und leider weiss ich nicht wie ich Excel jetzt sage, das wenn er die Nummer gefunden hat, weiter unten nach Farbe schaut und dann nach rechts in der sechsten Spalte den Farbton ausgibt...
LG
Steffi
Betrifft: AW: SVERWEIS aber wie?
von: 1713970.html
Hallo Steffi,
dann hatte ich es wohl falsch gelesen das Du den Fehler in Deinet Formel Wissen wolltest.
Welchen Grund sollte ich haben Deine Formel in Deine Dateio einzutragen, wenn Du das schon nicht wolltest.
Viel Erfolg noch.
Gruß Hajo
Betrifft: AW: SVERWEIS aber wie?
von: 1713973.html
Geschrieben am: 19.09.2019 20:02:47
Hallo Hajo,
guter Hinweis...
Vielen Dank und trotzdem nen schönen Abend
Betrifft: AW: SVERWEIS aber wie?
von: 1713974.html
Geschrieben am: 19.09.2019 20:07:46
Hallo Stefanie,
probier mal
=WENNFEHLER(INDEX(INDIREKT("F"&VERGLEICH($H7;A:A;0)&":F100");VERGLEICH("Auswahl"; INDIREKT("F"&VERGLEICH($H7;A:A;0)&":F100");0)+1);"")
in I7 eintragen und runterziehen.
Gruß Rolf
Betrifft: AW: SVERWEIS aber wie?
von: 1713976.html
Hallo, ich würde so tun..:
=WENNFEHLER(INDEX(F:F;VERGLEICH(H7;A:A;0)+VERGLEICH($I$6;$A$100:INDEX(A:A;VERGLEICH(H7;A:A;0););0)); "")
| Arbeitsblatt mit dem Namen 'Tabelle1' | |||
| H | I | J | |
| 6 | Nummer | Farbe | |
| 7 | 11111 | Grün | Grün |
| 8 | 22222 | Gelb | Gelb |
| 9 | 33333 | Rot | Rot |
| Zelle | Formel |
| J7 | =WENNFEHLER(INDEX(F:F;VERGLEICH(H7;A:A;0)+VERGLEICH($I$6;$A$100:INDEX(A:A;VERGLEICH(H7;A:A;0););0));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Betrifft: AW: SVERWEIS aber wie?
von: 1713982.html
Geschrieben am: 19.09.2019 20:21:09
Guten Abend Frank Furter,
puuuuh, auch das funktioniert super...
Gibt es in Excel etwas das ihr nicht hinbekommt?
Vielen dank und schönen Abend
LG
Steffi
Betrifft: AW: SVERWEIS aber wie?
von: 1713979.html
Geschrieben am: 19.09.2019 20:16:04
Hallo Rolf,
was soll ich sagen... Perfekt! Vielen Dank dafür!
Da werde ich mich mal etwas mehr in die Materie einarbeiten :-)
Danke dir nochmals für deine Hilfe und wünsche dir einen schönen Abend.
LG
Steffi
Betrifft: AW: Gern geschehen
von: 1713981.html
Geschrieben am: 19.09.2019 20:20:46
...Dir auch 'nen schönen Abend!
Gruß Rolf
Betrifft: Farben rauspicken
von: 1713983.html
Geschrieben am: 19.09.2019 20:23:59
Hi,
in I7 die Arrayformel:
{=INDEX(F:F;MIN(WENN(INDEX(F:F;VERGLEICH(H7;A:A;0)):F$999<>0;ZEILE(X$1:X$99)))+VERGLEICH(H7;A:A;0))}
runterkopieren
Voraussetzung: direkt über der Farbe steht immer "Auswahl" oder was anderes.
WF
Betrifft: Nach Sichtung aller Lösungen ...
von: 1714013.html
Geschrieben am: 20.09.2019 00:49:58
…und fairerweise ihrer Normierung auf gleichen Leistungsumfang und annähernd gleiche Notation, Stefanie & all,
komme ich zu dem Schluss, dass FrankF's Fml insofern am günstigsten sein könnte, da sie die wenigsten Fktsaufrufe benötigt. Nur scheint sie das zugrundelegende Prinzip nicht so konsequent zu verfolgen, dass es nicht bei deutlich mehr Daten doch zu einem Fehler kommen könnte. Günstiger wäre mE ein durchgängig gleich ermittelter StartPkt, was so erreicht wdn könnte:
=WENNFEHLER(INDEX(A:F;VERGLEICH(H7;A:A;0)+VERGLEICH(I$6;INDEX(A:A;VERGLEICH(H7;A:A;0)):A$38;0);6);"")
Da hier gleiche FmlTeile auftreten, könnte Schreib-(evtl auch Rechen-)Aufwand gespart wdn, indem diese Teile nur 1× notiert wdn. Dafür kann eine UDF mit MerkFunktion benutzt wdn …
=WENNFEHLER(INDEX(A:F; Rmd(VERGLEICH(H7; A:A;0))+VERGLEICH(I$6;INDEX(A:A;Rmd()):A$38;0);6);"")
…oder man legt für das Argument der UDF eine benannte Fml an, definiert also einen Namen für diese TeilFml, zB Auswahl: =VERGLEICH(H7;A:A;0) …
…und ersetzt dann die UDF-Nennungen in der darüber stehenden ZellFml komplett (mit ihrem evtl Argument) durch diesen Namen, was dann so aussähe:
=WENNFEHLER(INDEX(A:F;Auswahl+VERGLEICH(I$6;INDEX(A:A;Auswahl):A$38;0);6);"")
(A$38 steht für die EndZelle in Spalte A!) Das wäre dann eine Fkt weniger in der reinen ZellFml.
Morhn, Luc :-?
„Der beste Beweis für intelligentes Leben im Universum ist, dass noch niemand versucht hat, Kontakt mit uns aufzunehmen.“ H.Lesch, 2018, Sonneberg
Deshalb Intelligenz steigern mit …